[gentoo-commits] gentoo-x86 commit in app-misc/beagle: ChangeLog beagle-0.2.18.ebuild

[Samuli Suominen (drac)]

drac        07/11/22 21:07:46

  Modified:             ChangeLog
  Added:                beagle-0.2.18.ebuild
  Log:
  Version bump, closing bug #190707, for #196755 straight to stable for amd64.
  (Portage version: 2.1.3.19, RepoMan options: --force)

Revision  Changes    Path
1.61                 app-misc/beagle/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/beagle/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/beagle/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/beagle/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/beagle/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	24 Aug 2007 18:58:39 -0000	1.60
+++ ChangeLog	22 Nov 2007 21:07:45 -0000	1.61
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/beagle
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/beagle/ChangeLog,v 1.60 2007/08/24 18:58:39 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/beagle/ChangeLog,v 1.61 2007/11/22 21:07:45 drac Exp $
+
+*beagle-0.2.18 (22 Nov 2007)
+
+  22 Nov 2007; Samuli Suominen <drac@g.o> +beagle-0.2.18.ebuild:
+  Version bump, closing bug #190707, for #196755 straight to stable for amd64.
 
   24 Aug 2007; Tobias Scherbaum <dertobi123@g.o>
   beagle-0.2.17.ebuild:



1.1                  app-misc/beagle/beagle-0.2.18.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/beagle/beagle-0.2.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/beagle/beagle-0.2.18.ebuild?rev=1.1&content-type=text/plain

Index: beagle-0.2.18.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/beagle/beagle-0.2.18.ebuild,v 1.1 2007/11/22 21:07:45 drac Exp $

EAPI=1

inherit gnome.org eutils autotools mono

DESCRIPTION="search tool that ransacks your personal information space to find whatever you're looking for"
HOMEPAGE="http://www.beagle-project.org"

LICENSE="MIT Apache-1.1"
SLOT="0"
KEYWORDS="amd64 ~ppc ~x86"
IUSE="chm doc eds galago gtk ole pdf python thunderbird +xscreensaver"

RDEPEND=">=dev-lang/mono-1.1.18
	app-arch/zip
	sys-devel/gettext
	>=x11-libs/gtk+-2.6
	>=dev-libs/gmime-2.2.1
	>=dev-dotnet/gtk-sharp-2.8
	>=gnome-base/librsvg-2
	>=media-libs/libexif-0.6
	>=dev-libs/libxml2-2.6.19
	x11-libs/libX11
	x11-libs/libXt
	>=dev-db/sqlite-3.3.1
	gtk? ( >=dev-dotnet/gconf-sharp-2.8
		>=dev-dotnet/glade-sharp-2.8
		>=dev-dotnet/gnome-sharp-2.8 )
	eds? ( >=dev-dotnet/evolution-sharp-0.13.3
		>=dev-dotnet/gconf-sharp-2.3 )
	ole? ( >=app-text/wv-1.2.0
		>=dev-dotnet/gsf-sharp-0.6
		>=app-office/gnumeric-1.4.3-r3 )
	python? ( >=dev-python/pygtk-2.6 )
	pdf? ( >=app-text/poppler-0.5.1 )
	chm? ( app-doc/chmlib )
	galago? ( >=dev-dotnet/galago-sharp-0.5 )
	thunderbird? ( >=mail-client/mozilla-thunderbird-1.5 )
	xscreensaver? ( x11-libs/libXScrnSaver )"
DEPEND="${RDEPEND}
	doc? ( dev-util/gtk-doc )
	dev-util/pkgconfig
	x11-proto/xproto
	xscreensaver? ( x11-proto/scrnsaverproto )"

pkg_setup() {
	local fail="Re-emerge dev-libs/gmime with USE mono."

	if ! built_with_use dev-libs/gmime mono; then
		eerror "${fail}"
		die "${fail}"
	fi

	enewgroup beagleindex
	enewuser beagleindex -1 -1 /var/lib/cache/beagle beagleindex
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Multilib fix
	sed -i -e 's:prefix mono`/lib:libdir mono`:' \
		"${S}"/configure.in || die "sed failed"

	epatch "${FILESDIR}"/${PN}-0.2.7-crawltweek.patch
	epatch "${FILESDIR}"/${PN}-log-level-warn.patch

	eautoreconf
}

src_compile() {
	econf --enable-libbeagle --enable-sqlite3 \
		$(use_enable doc gtk-doc) \
		$(use_enable thunderbird) \
		$(use_enable eds evolution) \
		$(use_enable gtk gui) \
		$(use_enable python) \
		$(use_enable ole gsf-sharp) \
		$(use_enable xscreensaver xss)

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	dodir /usr/share/beagle
	insinto /usr/share/beagle
	doins mozilla-extension/beagle.xpi

	dodoc AUTHORS NEWS README

	sed -i -e 's/CRAWL_ENABLED="yes"/CRAWL_ENABLED="no"/' "${D}"/etc/beagle/crawl-*

	insinto /etc/beagle
	doins "${FILESDIR}"/crawl-portage

	keepdir /usr/$(get_libdir)/beagle/Backends
	diropts -o beagleindex -g beagleindex
	keepdir /var/lib/cache/beagle/indexes
}

pkg_postinst() {
	elog "If available, Beagle greatly benefits from using certain operating"
	elog "system features such as Extended Attributes and inotify."
	echo
	elog "If you want static queryables such as the portage tree and system"
	elog "documentation you will need to edit the /etc/beagle/crawl-* files"
	elog "and change CRAWL_ENABLE from 'no' to 'yes'."
	echo
	elog "For more info on how to create the optimal beagle environment, and"
	elog "basic usage info, see the Gentoo page of the Beagle website:"
	elog "http://www.beagle-project.org/Gentoo_Installation"
}



-- 
gentoo-commits@g.o mailing list