[gentoo-commits] gentoo-x86 commit in sys-block/tw_cli: ChangeLog tw_cli-9.5.0.1.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/03/12 08:16:03

  Modified:             ChangeLog
  Added:                tw_cli-9.5.0.1.ebuild
  Log:
  Version bump. If you use a 9690SA card, you are STRONGLY recommended to use the Update9690 app from upstream to resolve a data-loss bug. Upstream has removed the tw_sched utility as of this release, and finalized the FreeBSD version of the tw_cli tool.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.25                 sys-block/tw_cli/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-block/tw_cli/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-block/tw_cli/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-block/tw_cli/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-block/tw_cli/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -p -w -b -B -u -u -r1.24 -r1.25
--- ChangeLog	27 Feb 2008 01:21:51 -0000	1.24
+++ ChangeLog	12 Mar 2008 08:16:02 -0000	1.25
@@ -1,6 +1,14 @@
 # ChangeLog for sys-block/tw_cli
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-block/tw_cli/ChangeLog,v 1.24 2008/02/27 01:21:51 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-block/tw_cli/ChangeLog,v 1.25 2008/03/12 08:16:02 robbat2 Exp $
+
+*tw_cli-9.5.0.1 (12 Mar 2008)
+
+  12 Mar 2008; Robin H. Johnson <robbat2@g.o> +tw_cli-9.5.0.1.ebuild:
+  Version bump. If you use a 9690SA card, you are STRONGLY recommended to use
+  the Update9690 app from upstream to resolve a data-loss bug. Upstream has
+  removed the tw_sched utility as of this release, and finalized the FreeBSD
+  version of the tw_cli tool.
 
   27 Feb 2008; Robin H. Johnson <robbat2@g.o> tw_cli-9.4.0.ebuild,
   tw_cli-9.4.0.1.ebuild, tw_cli-9.4.1.2.ebuild, tw_cli-9.4.2.ebuild,



1.1                  sys-block/tw_cli/tw_cli-9.5.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-block/tw_cli/tw_cli-9.5.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-block/tw_cli/tw_cli-9.5.0.1.ebuild?rev=1.1&content-type=text/plain

Index: tw_cli-9.5.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-block/tw_cli/tw_cli-9.5.0.1.ebuild,v 1.1 2008/03/12 08:16:02 robbat2 Exp $

DESCRIPTION="3ware SATA+PATA RAID controller Command Line Interface tool"
HOMEPAGE="http://www.3ware.com/kb/article.aspx?id=14847"
LICENSE="3ware"
SLOT="0"
# binary packages
KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
IUSE=""
# stripping seems to break this sometimes
RESTRICT="fetch strip mirror"
# binary packages
DEPEND=""
RDEPEND="virtual/libc"

# Upstream has _FUN_ naming these
# We are mostly prepared for the FreeBSD binaries at this point
# They just aren't yet enabled here
PN_KERNEL="${ARCH/*fbsd-*/freebsd}"
[ "${PN_KERNEL}" != 'freebsd' ] && PN_KERNEL='linux'
PN_ARCH="${ARCH/*-}"
PN_ARCH="${PN_ARCH/amd64/x86_64}"

# The naming of <=9.5.0 for freebsd was weird,
# but 9.5.0.1 has it sanely.
MY_P="${PN}-${PN_KERNEL}-${PN_ARCH}-${PV}"

# Upstream actually only releases newer versions for new hardware
# and doesn't release new major versions for old hardware
# however their backwards compatibility is excellent.
# I personally test tw_cli on two cards: 6200 (amd64) and 7006-2 (x86)
# - Robin H. Johnson <robbat2@g.o> - 23 Nov 2006
#HW_VARIANT="Escalade7000Series" - for versions 9.3.0.*
#HW_VARIANT="Escalade9650SE-Series" # for versions 9.4.0*
HW_VARIANT="Escalade9690SA-Series" # for versions 9.5.0*
# package has different tarballs for x86 and amd64
SRC_URI_BASE="http://www.3ware.com/download/${HW_VARIANT}/${PV}"
SRC_URI_x86="${SRC_URI_BASE}/${PN}-linux-x86-${PV}.tgz"
SRC_URI_amd64="${SRC_URI_BASE}/${PN}-linux-x86_64-${PV}.tgz"
SRC_URI_x86_fbsd="${SRC_URI_BASE}/${PN}-freebsd-x86-${PV}.tgz"
#SRC_URI_amd64_fbsd="${SRC_URI_BASE}/${PN}-x86_64-freebsd-${PV}.tgz"
SRC_URI="x86?   ( ${SRC_URI_x86} )
		 amd64? ( ${SRC_URI_amd64} )
		 x86-fbsd? ( ${SRC_URI_x86_fbsd} )"
		#amd64-fbsd? ( ${SRC_URI_amd64_fbsd} )
LICENSE_URL="http://www.3ware.com/support/windows_agree.asp?path=/download/${HW_VARIANT}/${PV}/${MY_P}.tgz"

S="${WORKDIR}"

src_unpack() {
	unpack ${MY_P}.tgz
}

supportedcards() {
	elog "This binary supports should support ALL cards, including, but not"
	elog "limited to the following series:"
	elog ""
	elog "PATA: 6xxx, 72xx, 74xx, 78xx, 7000, 7500, 7506"
	elog "SATA: 8006, 8500, 8506, 9500S, 9550SX, 9590SE,"
	elog "      9550SXU, 9650SE, 9650SE-{24M8,4LPME},"
	elog "      9690SA"
	elog ""
	elog "Release notes for this version are available at:"
	elog "${SRC_URI_BASE}/${PV}_Release_Notes_Web.pdf"
}

pkg_setup() {
	supportedcards
}

pkg_nofetch() {
	einfo "Please agree to the license at URL"
	einfo ""
	einfo "\t${LICENSE_URL}"
	einfo ""
	einfo "And then use the following URL to download the"
	einfo "correct tarball into ${DISTDIR}"
	einfo ""
	einfo "x86 - ${SRC_URI_x86}"
	einfo "amd64 - ${SRC_URI_amd64}"
	einfo "x86-fbsd - ${SRC_URI_x86_fbsd}"
	#einfo "amd64-fbsd - ${SRC_URI_amd64_fbsd}"
	einfo ""
	supportedcards
}

src_install() {
	into /
	dosbin tw_cli
	into /usr
	newman tw_cli.8.nroff tw_cli.8
	dohtml *.html
}



-- 
gentoo-commits@l.g.o mailing list