[gentoo-commits] gentoo-x86 commit in www-apps/twiki: ChangeLog twiki-4.3.1.ebuild twiki-4.2.4.ebuild

[Alex Legler (a3li)]

a3li        09/08/01 10:18:37

  Modified:             ChangeLog
  Added:                twiki-4.3.1.ebuild
  Removed:              twiki-4.2.4.ebuild
  Log:
  Non-maintainer commit: Version bump for security bug 268159. Removing vulnerable versions.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 www-apps/twiki/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	28 Dec 2008 21:09:26 -0000	1.46
+++ ChangeLog	1 Aug 2009 10:18:37 -0000	1.47
@@ -1,6 +1,13 @@
 # ChangeLog for www-apps/twiki
-# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v 1.46 2008/12/28 21:09:26 wrobel Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v 1.47 2009/08/01 10:18:37 a3li Exp $
+
+*twiki-4.3.1 (01 Aug 2009)
+
+  01 Aug 2009; Alex Legler <a3li@g.o> -twiki-4.2.4.ebuild,
+  +twiki-4.3.1.ebuild:
+  Non-maintainer commit: Version bump for security bug 268159. Removing
+  vulnerable version
 
 *twiki-4.2.4 (28 Dec 2008)
 



1.1                  www-apps/twiki/twiki-4.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/twiki-4.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/twiki-4.3.1.ebuild?rev=1.1&content-type=text/plain

Index: twiki-4.3.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/twiki-4.3.1.ebuild,v 1.1 2009/08/01 10:18:37 a3li Exp $

WEBAPP_NO_AUTO_INSTALL="yes"

inherit webapp

MY_PN="TWiki"

DESCRIPTION="A Web Based Collaboration Platform"
HOMEPAGE="http://twiki.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}.tgz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
RESTRICT="fetch"
IUSE=""

S="${WORKDIR}"

RDEPEND=">=app-text/rcs-5.7
	sys-apps/diffutils
	>=dev-lang/perl-5.8
	dev-perl/Algorithm-Diff
	dev-perl/CGI-Session
	dev-perl/Digest-SHA1
	dev-perl/HTML-Parser
	dev-perl/locale-maketext-lexicon
	dev-perl/Text-Diff
	dev-perl/URI
	virtual/cron
	>=virtual/perl-CGI-3.20
	virtual/perl-digest-base
	virtual/perl-File-Spec
	virtual/perl-libnet
	virtual/perl-Time-Local"

need_httpd_cgi

pkg_nofetch() {
	einfo "Please download ${MY_PN}_${PV}.tgz from:"
	einfo "http://twiki.org/cgi-bin/view/Codev/DownloadTWiki"
	einfo "and move it to ${DISTDIR}"
}

src_install() {
	webapp_src_preinst

	dodoc AUTHORS COPYRIGHT readme.txt
	dohtml T*.html INSTALL.html
	rm -f readme.txt T*.html INSTALL.html

	mv bin/LocalLib.cfg{.txt,}

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	for f in $(find data pub); do
		webapp_serverowned "${MY_HTDOCSDIR}"/${f}
	done

	for f in bin/setlib.cfg bin/LocalLib.cfg; do
		webapp_configfile "${MY_HTDOCSDIR}"/${f}
	done

	webapp_hook_script "${FILESDIR}"/reconfig
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt

	webapp_src_install
}

pkg_postinst() {
	ewarn
	ewarn "If you are upgrading from an older version of TWiki, back up your"
	ewarn "data/ and pub/ directories and any local changes before upgrading!"
	ewarn
	ewarn "You are _strongly_ encouraged to to read the upgrade guide:"
	ewarn "http://twiki.org/cgi-bin/view/TWiki/TWikiDocumentation"
	ewarn
	webapp_pkg_postinst
}