[gentoo-commits] gentoo-x86 commit in games-sports/ultimatestunts: ChangeLog ultimatestunts-0.7.4.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    08/02/24 07:32:49

  Modified:             ChangeLog
  Added:                ultimatestunts-0.7.4.ebuild
  Log:
  version bump
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.18                 games-sports/ultimatestunts/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/ultimatestunts/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/ultimatestunts/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/ultimatestunts/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-sports/ultimatestunts/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	19 Oct 2007 16:11:06 -0000	1.17
+++ ChangeLog	24 Feb 2008 07:32:48 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for games-sports/ultimatestunts
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-sports/ultimatestunts/ChangeLog,v 1.17 2007/10/19 16:11:06 mr_bones_ Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-sports/ultimatestunts/ChangeLog,v 1.18 2008/02/24 07:32:48 mr_bones_ Exp $
+
+*ultimatestunts-0.7.4 (24 Feb 2008)
+
+  24 Feb 2008; Michael Sterrett <mr_bones_@g.o>
+  +files/ultimatestunts-0.7.4-paths.patch, +ultimatestunts-0.7.4.ebuild:
+  version bump
 
 *ultimatestunts-0.7.3 (19 Oct 2007)
 



1.1                  games-sports/ultimatestunts/ultimatestunts-0.7.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/ultimatestunts/ultimatestunts-0.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-sports/ultimatestunts/ultimatestunts-0.7.4.ebuild?rev=1.1&content-type=text/plain

Index: ultimatestunts-0.7.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-sports/ultimatestunts/ultimatestunts-0.7.4.ebuild,v 1.1 2008/02/24 07:32:48 mr_bones_ Exp $

inherit autotools eutils versionator games

MY_P=${PN}-srcdata-$(replace_all_version_separators)1
DESCRIPTION="Remake of the famous Stunts game"
HOMEPAGE="http://www.ultimatestunts.nl/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

RDEPEND="media-libs/libsdl
	media-libs/sdl-image
	media-libs/openal
	media-libs/freealut
	virtual/opengl
	virtual/glu
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	dev-util/cvs
	sys-devel/gettext"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	games_pkg_setup
	if ! built_with_use media-libs/libsdl opengl ; then
		die "Please emerge libsdl with USE=opengl"
	fi
	if ! built_with_use media-libs/openal vorbis ; then
		die "Please emerge openal with USE=vorbis"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	find "${S}" -type d -name CVS -exec rm -rf '{}' +
	epatch "${FILESDIR}"/${P}-paths.patch
	autopoint -f || die "autopoint failed"
	sed -i \
		-e 's:$(datadir)/locale:@top_srcdir@/data/lang:' \
		po/Makefile.in.in \
		|| die "sed failed"
	AT_M4DIR=m4 eautoreconf
}

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		|| die
	emake -C trackedit libtrackedit.a || die "emake failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	newicon data/cars/diablo/steer.png ${PN}.png
	make_desktop_entry ustunts "Ultimate Stunts"
	dodoc AUTHORS README
	prepgamesdirs
}



-- 
gentoo-commits@l.g.o mailing list