[gentoo-commits] gentoo-x86 commit in dev-vcs/gitolite-gentoo: ChangeLog gitolite-gentoo-1.5.8.1.ebuild

[Christian Ruppert (idl0r)]

idl0r       11/01/16 16:01:05

  Modified:             ChangeLog
  Added:                gitolite-gentoo-1.5.8.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha15/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  dev-vcs/gitolite-gentoo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	3 Jan 2011 05:14:33 -0000	1.5
+++ ChangeLog	16 Jan 2011 16:01:05 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/gitolite-gentoo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v 1.5 2011/01/03 05:14:33 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/ChangeLog,v 1.6 2011/01/16 16:01:05 idl0r Exp $
+
+*gitolite-gentoo-1.5.8.1 (16 Jan 2011)
+
+  16 Jan 2011; Christian Ruppert <idl0r@g.o>
+  +gitolite-gentoo-1.5.8.1.ebuild:
+  Version bump
 
 *gitolite-gentoo-1.5.8 (03 Jan 2011)
 



1.1                  dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.8.1.ebuild?rev=1.1&content-type=text/plain

Index: gitolite-gentoo-1.5.8.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite-gentoo/gitolite-gentoo-1.5.8.1.ebuild,v 1.1 2011/01/16 16:01:05 idl0r Exp $

EAPI=3

inherit eutils perl-module

DESCRIPTION="Highly flexible server for git directory version tracker, Gentoo fork"
HOMEPAGE="http://git.overlays.gentoo.org/gitweb/?p=proj/gitolite-gentoo.git;a=summary"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="contrib vim-syntax"

DEPEND="dev-lang/perl
	>=dev-vcs/git-1.6.2"
RDEPEND="${DEPEND}
	!dev-vcs/gitolite
	dev-perl/Net-SSH-AuthorizedKeysFile
	vim-syntax? ( app-vim/gitolite-syntax )"

pkg_setup() {
	enewgroup git
	enewuser git -1 /bin/bash /var/lib/gitolite git
}

src_prepare() {
	rm -rf Makefile doc/COPYING contrib/{autotoc,gitweb,vim}

	echo "${PF}-gentoo" > conf/VERSION
}

src_install() {
	dodir /usr/share/gitolite/{conf,hooks} /usr/bin || die

	./src/gl-system-install "${D}"/usr/bin \
		"${D}"/usr/share/gitolite/conf "${D}"/usr/share/gitolite/hooks || die
	sed -i -e "s:${D}::g" "${D}/usr/bin/gl-setup" \
		"${D}/usr/share/gitolite/conf/example.gitolite.rc" || die

	rm "${D}/usr/bin/gitolite.pm"
	insinto "${VENDOR_LIB}"
	doins src/gitolite.pm || die

	dodoc README.mkd doc/*

	if use contrib; then
		insinto /usr/share/doc/${PF}
		doins -r contrib/ || die
	fi

	keepdir /var/lib/gitolite
	fowners git:git /var/lib/gitolite
	fperms 750 /var/lib/gitolite
}