[gentoo-commits] gentoo-x86 commit in net-mail/dovecot: ChangeLog dovecot-1.0.8.ebuild

[Wolfram Schlich (wschlich)]

wschlich    07/12/08 11:35:03

  Modified:             ChangeLog
  Added:                dovecot-1.0.8.ebuild
  Log:
  version bump, add managesieve patch, small cleanups
  (Portage version: 2.1.4_rc8)

Revision  Changes    Path
1.127                net-mail/dovecot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-mail/dovecot/ChangeLog?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-mail/dovecot/ChangeLog?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-mail/dovecot/ChangeLog?r1=1.126&r2=1.127

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/dovecot/ChangeLog,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- ChangeLog	6 Nov 2007 19:11:58 -0000	1.126
+++ ChangeLog	8 Dec 2007 11:35:02 -0000	1.127
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/dovecot
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/dovecot/ChangeLog,v 1.126 2007/11/06 19:11:58 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/dovecot/ChangeLog,v 1.127 2007/12/08 11:35:02 wschlich Exp $
+
+*dovecot-1.0.8 (08 Dec 2007)
+
+  08 Dec 2007; Wolfram Schlich <wschlich@g.o> +dovecot-1.0.8.ebuild:
+  version bump, add managesieve patch, small cleanups
 
   06 Nov 2007; Raúl Porcel <armin76@g.o> dovecot-1.0.5.ebuild:
   alpha/sparc stable wrt #197388



1.1                  net-mail/dovecot/dovecot-1.0.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-mail/dovecot/dovecot-1.0.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-mail/dovecot/dovecot-1.0.8.ebuild?rev=1.1&content-type=text/plain

Index: dovecot-1.0.8.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/dovecot/dovecot-1.0.8.ebuild,v 1.1 2007/12/08 11:35:02 wschlich Exp $

inherit autotools eutils ssl-cert

MY_P="${P/_/.}"
S="${WORKDIR}/${MY_P}"
SIEVE="dovecot-sieve-1.0.2"
SIEVE_S="${WORKDIR}/${SIEVE}"
MANAGESIEVE="dovecot-1.0.7-MANAGESIEVE-v9"

SRC_URI="http://dovecot.org/releases/1.0/${MY_P}.tar.gz
sieve? ( http://dovecot.org/releases/sieve/${SIEVE}.tar.gz )
managesieve? ( http://sinas.rename-it.nl/~sirius/${MANAGESIEVE}.diff.gz )"

DESCRIPTION="An IMAP and POP3 server written with security primarily in mind"
HOMEPAGE="http://www.dovecot.org/"

SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"

IUSE="debug doc ipv6 kerberos ldap managesieve mbox mysql pop3d pam postgres sieve ssl suid vpopmail"

# Developer documentation, controlled by the doc USE flag
DEVDOCS="auth-protocol index multiaccess securecoding"

DEPEND=">=sys-apps/sed-4
	kerberos? ( virtual/krb5 )
	ldap? ( net-nds/openldap )
	pam? ( virtual/pam )
	ssl? ( dev-libs/openssl )
	postgres? ( dev-db/postgresql )
	mysql? ( virtual/mysql )
	vpopmail? ( net-mail/vpopmail )"

RDEPEND="${DEPEND}
	>=net-mail/mailbase-0.00-r8"

src_unpack() {
	unpack ${A}
	cd "${S}"
	use managesieve && epatch "${DISTDIR}"/${MANAGESIEVE}.diff.gz
}

pkg_setup() {
	if ! use sieve && use managesieve; then
		eerror "managesieve USE flag selected but sieve USE flag unselected" 
		die "USE flag problem"
	fi
	# Add user and group for login process (same as for fedora/redhat)
	enewgroup dovecot 97
	enewuser dovecot 97 -1 /dev/null dovecot
}

src_compile() {
	use managesieve && eautoreconf
	local myconf=
	use ssl && myconf="${myconf} --with-ssl=openssl" \
		|| myconf="${myconf} --without-ssl"
	econf \
		--localstatedir=/var \
		--sysconfdir=/etc/dovecot \
		--enable-header-install \
		--with-ioloop=best \
		--with-poll=best \
		$(use_enable debug) \
		$(use_enable ipv6) \
		$(use_with kerberos gssapi) \
		$(use_with ldap) \
		$(use_with mysql) \
		$(use_with pam) \
		$(use_with pop3d) \
		$(use_with postgres pgsql) \
		$(use_with vpopmail) \
		${myconf} \
		|| die "configure failed"
	emake || die "make failed"

	if use sieve; then
		einfo "Building sieve"
		cd "${SIEVE_S}"
		econf --with-dovecot="${S}" || die "configure failed (sieve)"
		emake || die "make failed (sieve)"
	fi
}

src_install () {
	make DESTDIR="${D}" install || die "make install failed"
	use suid && fperms u+s /usr/libexec/dovecot/deliver

	rm -f "${D}"/etc/dovecot/dovecot-{ldap,sql}-example.conf

	newinitd "${FILESDIR}"/dovecot.init dovecot

	# Documentation
	rm -rf "${D}"/usr/share/doc/dovecot
	dodoc AUTHORS NEWS README TODO dovecot-example.conf
	use managesieve && dodoc README.managesieve
	if use doc; then
		dodoc doc/*.txt
	else
		local x= n=
		for x in doc/*.txt; do
			n=$(basename "${x}" .txt)
			[[ " ${DEVDOCS} " != *" ${n} "* ]] && dodoc "${x}"
		done
	fi

	# Create the dovecot.conf file from the dovecot-example.conf file that
	# the dovecot folks nicely left for us....
	local conf="${D}/etc/dovecot/dovecot.conf"
	mv "${D}"/etc/dovecot/dovecot-example.conf "${D}"/etc/dovecot/dovecot.conf

	# .maildir is the Gentoo default, but we need to support mbox to
	local mail_location="maildir:~/.maildir"
	if use mbox; then
		mail_location="mbox:/var/spool/mail/%u:INDEX=/var/dovecot/%u"
		keepdir /var/dovecot
		sed -i -e 's|#mail_extra_groups =|mail_extra_groups = mail|' "${conf}"
	fi
	sed -i -e \
		"s|#mail_location =|mail_location = ${mail_location}|" "${conf}" \
		|| die "failed to update mail location settings in dovecot.conf"

	# We're using pam files (imap and pop3) provided by mailbase
	if use pam; then
		sed -i -e '/passdb pam/, /^[ \t]*}/ s|#args = dovecot|args = "\*"|' \
			"${conf}" || die "failed to update PAM settings in dovecot.conf"
	fi

	# Listen on ipv6 and ipv4
	if use ipv6; then
		sed -i -e 's/^#listen = \*/listen = \[::\]/g' "${conf}" \
			|| die "failed to update listen settings in dovecot.conf"
	fi

	# Update ssl cert locations
	if use ssl; then
		sed -i -e 's,^#ssl_cert_file =.*,ssl_cert_file = /etc/ssl/dovecot/server.pem,' \
			-e 's,^#ssl_key_file =.*,ssl_key_file = /etc/ssl/dovecot/server.key,' \
			"${conf}" || die "failed to update SSL settings in dovecot.conf"

		# Let's not make a new certificate if we already have one
		if ! [[ -e "${ROOT:-/}"etc/ssl/dovecot/server.pem && \
			-e "${ROOT:-/}"etc/ssl/dovecot/server.key ]]; then
			SSL_ORGANIZATION="${SSL_ORGANIZATION:-Dovecot IMAP Server}"
			insinto "${ROOT:-/}"etc/ssl/dovecot
			docert server
			fowners dovecot:mail /etc/ssl/dovecot/server.{key,pem}
		fi
	fi

	# Install SQL configuration
	if use mysql || use postgres; then
		cp doc/dovecot-sql-example.conf "${D}"/etc/dovecot/dovecot-sql.conf
		fperms 600 /etc/dovecot/dovecot-sql.conf
		sed -i -e '/db sql/,/args/ s|=|= /etc/dovecot-sql.conf|' "${conf}" \
			|| die "failed to update SQL settings in dovecot-sql.conf"
		dodoc doc/dovecot-sql-example.conf
	fi

	# Install LDAP configuration
	if use ldap; then
		cp doc/dovecot-ldap-example.conf "${D}"/etc/dovecot/dovecot-ldap.conf
		fperms 600 /etc/dovecot/dovecot-ldap.conf
		sed -i -e '/db ldap/,/args/ s|=|= /etc/dovecot-ldap.conf|' "${conf}" \
			|| die "failed to update LDAP settings in dovecot-ldap.conf"
		dodoc doc/dovecot-ldap-example.conf
	fi

	# Install sieve plugin
	if use sieve; then
		make -C "${SIEVE_S}" DESTDIR="${D}" install \
			|| die "make install failed (sieve)"
	fi

	dodir /var/run/dovecot
	fowners root:0 /var/run/dovecot
	fperms 0700 /var/run/dovecot
	keepdir /var/run/dovecot/login
	fowners root:dovecot /var/run/dovecot/login
	fperms 0750 /var/run/dovecot/login
}

get_config_var() {
	local varname=${1}
	if [[ -z ${varname} ]]; then
		die "${FUNCNAME}: variable name missing"
	fi
	sed -n 's/^[[:space:]]\?'"${varname}"'[[:space:]]*="*\([^#"]\+\)"*/\1/p' \
		"${ROOT:-/}"etc/dovecot/dovecot.conf
}

pkg_postinst() {
	# Touch ssl certs so that they are modified outisde of src_install
	# We do this so portage does't unmerge them - silly portage
	if use ssl; then
		touch "${ROOT:-/}"/etc/ssl/dovecot/server.{key,pem}
	fi

	elog "The Dovecot configuration has vastly changed since 0.99."
	elog "You are encouraged to start afresh with a new configuration file."
	elog "see http://wiki.dovecot.org/ for configuration examples."

	if [[ -e "${ROOT:-/}"etc/dovecot.conf ]]; then
		ewarn
		ewarn "The Dovecot configuration now resides in ${ROOT:-/}etc/dovecot"
	fi

	local base_dir="$(get_config_var base_dir)"
	base_dir="${base_dir:-/var/run/dovecot}"
	if use ssl \
		&& [[ ! -e "${ROOT:-/}${base_dir}/login/ssl-parameters.dat" ]]; then
		elog
		elog "Dovecot requires DH SSL Parameters if you use SSL connections"
		elog "These take some time to make, and dovecot will create them before"
		elog "it allows any SSL connections."
		elog "You can create them now before starting dovecot like so"
		elog "   emerge --config =${PF}"
	fi
}

pkg_config() {
	local base_dir="$(get_config_var base_dir)"
	base_dir="${base_dir:-/var/run/dovecot}"

	if use ssl; then
		einfo "Regenerating SSL parameters. This will take some time."
		"${ROOT:-/}"usr/libexec/dovecot/ssl-build-param "${base_dir}/login/ssl-parameters.dat"
	fi
}



-- 
gentoo-commits@g.o mailing list