[gentoo-commits] gentoo-x86 commit in app-i18n/ibus: ChangeLog ibus-1.1.0.20090531.ebuild

[Matsuu Takuto (matsuu)]

matsuu      09/05/31 13:24:52

  Modified:             ChangeLog
  Added:                ibus-1.1.0.20090531.ebuild
  Log:
  Version bumped.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.30                 app-i18n/ibus/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	11 May 2009 14:44:59 -0000	1.29
+++ ChangeLog	31 May 2009 13:24:52 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for app-i18n/ibus
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.29 2009/05/11 14:44:59 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.30 2009/05/31 13:24:52 matsuu Exp $
+
+*ibus-1.1.0.20090531 (31 May 2009)
+
+  31 May 2009; MATSUU Takuto <matsuu@g.o>
+  +ibus-1.1.0.20090531.ebuild:
+  Version bumped.
 
 *ibus-1.1.0.20090508 (11 May 2009)
 



1.1                  app-i18n/ibus/ibus-1.1.0.20090531.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ibus-1.1.0.20090531.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-i18n/ibus/ibus-1.1.0.20090531.ebuild?rev=1.1&content-type=text/plain

Index: ibus-1.1.0.20090531.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.1.0.20090531.ebuild,v 1.1 2009/05/31 13:24:52 matsuu Exp $

EAPI="1"
inherit autotools eutils multilib python

DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
HOMEPAGE="http://code.google.com/p/ibus/"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
#IUSE="doc nls qt4"
IUSE="doc nls"

RDEPEND=">=dev-libs/glib-2.18
	>=x11-libs/gtk+-2
	>=gnome-base/gconf-2.12
	>=gnome-base/librsvg-2
	sys-apps/dbus
	app-text/iso-codes
	x11-libs/libX11
	>=dev-lang/python-2.5
	>=dev-python/pygobject-2.14
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.9 )
	nls? ( >=sys-devel/gettext-0.16.1 )"
RDEPEND="${RDEPEND}
	dev-python/pygtk
	>=dev-python/dbus-python-0.83
	dev-python/pyxdg"
#	qt4? (
#		>=x11-libs/qt-core-4.4:4
#		>=x11-libs/qt-dbus-4.4:4
#	)

pkg_setup() {
	# An arch specific config directory is used on multilib systems
	has_multilib_profile && GTK2_CONFDIR="/etc/gtk-2.0/${CHOST}"
	GTK2_CONFDIR=${GTK2_CONFDIR:=/etc/gtk-2.0/}
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	mv py-compile py-compile.orig || die
	ln -s "$(type -P true)" py-compile || die
	sed -i -e '/QMAKE/s/$/ "CONFIG+=nostrip"/' client/qt4/Makefile.am || die
	eautomake
}

src_compile() {
	# qt4-immodule won't work
	# http://code.google.com/p/ibus/issues/detail?id=341
	econf \
		$(use_enable doc gtk-doc) \
		$(use_enable nls) || die
#		$(use_enable qt4 qt4-immodule)
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	local qt_im_module="xim"
#	use qt4 && qt_im_module="ibus"

	elog "To use ibus, you should:"
	elog "1. Get input engines from sunrise overlay."
	elog "   Run \"emerge -s ibus-\" in your favorite terminal"
	elog "   for a list of packages we already have."
	elog
	elog "2. Setup ibus:"
	elog
	elog "   $ ibus-setup"
	elog
	elog "3. Set the following in your user startup scripts"
	elog "   such as .xinitrc, .xsession or .xprofile:"
	elog
	elog "   export XMODIFIERS=\"@im=ibus\""
	elog "   export GTK_IM_MODULE=\"ibus\""
	elog "   export QT_IM_MODULE=\"${qt_im_module}\""
	elog "   ibus-daemon -d -x"

	[ "${ROOT}" = "/" -a -x /usr/bin/gtk-query-immodules-2.0 ] && \
		gtk-query-immodules-2.0 > "${ROOT}/${GTK2_CONFDIR}/gtk.immodules"

	python_mod_optimize /usr/share/${PN}
}

pkg_postrm() {
	[ "${ROOT}" = "/" -a -x /usr/bin/gtk-query-immodules-2.0 ] && \
		gtk-query-immodules-2.0 > "${ROOT}/${GTK2_CONFDIR}/gtk.immodules"

	python_mod_cleanup /usr/share/${PN}
}