[gentoo-commits] gentoo-x86 commit in net-proxy/ziproxy: ChangeLog ziproxy-2.4.3.ebuild

[Alin Nastac (mrness)]

mrness      07/12/30 13:17:35

  Modified:             ChangeLog
  Added:                ziproxy-2.4.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.15                 net-proxy/ziproxy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	18 Nov 2007 02:10:43 -0000	1.14
+++ ChangeLog	30 Dec 2007 13:17:34 -0000	1.15
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/ziproxy
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v 1.14 2007/11/18 02:10:43 sbriesen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v 1.15 2007/12/30 13:17:34 mrness Exp $
+
+*ziproxy-2.4.3 (30 Dec 2007)
+
+  30 Dec 2007; Alin Năstac <mrness@g.o> +ziproxy-2.4.3.ebuild:
+  Version bump.
 
   18 Nov 2007; Stefan Briesenick <sbriesen@g.o>
   -files/ziproxy-2.2.confd, -files/ziproxy-2.2.initd, -ziproxy-2.2.2.ebuild:



1.1                  net-proxy/ziproxy/ziproxy-2.4.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ziproxy-2.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ziproxy-2.4.3.ebuild?rev=1.1&content-type=text/plain

Index: ziproxy-2.4.3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ziproxy-2.4.3.ebuild,v 1.1 2007/12/30 13:17:34 mrness Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit eutils

DESCRIPTION="A forwarding, non-caching, compressing web proxy server"
HOMEPAGE="http://ziproxy.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="jpeg2k xinetd"

DEPEND="media-libs/giflib
	media-libs/libpng
	media-libs/jpeg
	sys-libs/zlib
	jpeg2k? ( media-libs/jasper )"
RDEPEND="${DEPEND}
	xinetd? ( virtual/inetd )"

pkg_setup() {
	enewgroup ziproxy
	enewuser ziproxy -1 -1 -1 ziproxy
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# fix sample config file
	sed -i -e "s:/usr/local/ziproxy/\(ziproxy.passwd\):/etc/\1:g" \
		-e "s:/var/ziproxy/:/var/lib/ziproxy/:g" etc/ziproxy.conf

	# fix sample xinetd config
	sed -i -e "s:/usr/bin/:/usr/sbin/:g" \
		-e "s:\(.*port.*\):\1\n\ttype\t\t\t= UNLISTED:g" \
		-e "s:root:ziproxy:g" etc/xinetd.d/ziproxy
}

src_compile() {
	local myconf="--enable-shared-confuse --with-cfgfile=/etc/ziproxy.conf" # --enable-testprogs
	use jpeg2k && myconf="${myconf} --with-jasper"  # use_with doesn't work
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodir /usr/sbin
	mv -f "${D}usr/bin/ziproxy" "${D}usr/sbin/ziproxy"

	newbin stats.awk ${PN}_stats.awk
	dobin src/tools/ziproxy_genhtml_stats.sh

	newinitd "${FILESDIR}/${PN}-${PV%.*}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}-${PV%.*}.confd" ${PN}

	dodoc ChangeLog CREDITS README README.tools
	use jpeg2k && dodoc JPEG2000.txt

	insinto /etc
	doins etc/ziproxy.conf

	insinto /var/lib/ziproxy/error
	doins var/ziproxy/error/*.html

	if use xinetd; then
		insinto /etc/xinetd.d
		doins etc/xinetd.d/ziproxy
	fi

	diropts -m0750 -o ziproxy -g ziproxy
	keepdir /var/log/ziproxy
}



-- 
gentoo-commits@g.o mailing list