[gentoo-commits] gentoo-x86 commit in media-plugins/alsa-plugins: ChangeLog alsa-plugins-1.0.16_rc1.ebuild

[Tony Vroon (chainsaw)]

chainsaw    08/01/31 14:38:19

  Modified:             ChangeLog
  Added:                alsa-plugins-1.0.16_rc1.ebuild
  Log:
  Version bump, for bug #207427.
  (Portage version: 2.1.4)

Revision  Changes    Path
1.66                 media-plugins/alsa-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	24 Oct 2007 20:16:21 -0000	1.65
+++ ChangeLog	31 Jan 2008 14:38:19 -0000	1.66
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/alsa-plugins
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.65 2007/10/24 20:16:21 armin76 Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.66 2008/01/31 14:38:19 chainsaw Exp $
+
+*alsa-plugins-1.0.16_rc1 (31 Jan 2008)
+
+  31 Jan 2008; Tony Vroon <chainsaw@g.o>
+  +alsa-plugins-1.0.16_rc1.ebuild:
+  Version bump, for bug #207427.
 
   24 Oct 2007; Raúl Porcel <armin76@g.o> alsa-plugins-1.0.14.ebuild:
   alpha/ia64 stable wrt #189155



1.1                  media-plugins/alsa-plugins/alsa-plugins-1.0.16_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.16_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.16_rc1.ebuild?rev=1.1&content-type=text/plain

Index: alsa-plugins-1.0.16_rc1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.16_rc1.ebuild,v 1.1 2008/01/31 14:38:19 chainsaw Exp $

WANT_AUTOMAKE=latest
WANT_AUTOCONF=latest

inherit libtool autotools eutils flag-o-matic

MY_P="${P/_/}"

DESCRIPTION="ALSA extra plugins"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/plugins/${MY_P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="debug ffmpeg jack libsamplerate pulseaudio speex"

RDEPEND=">=media-libs/alsa-lib-${PV}
	ffmpeg? ( media-video/ffmpeg )
	jack? ( >=media-sound/jack-audio-connection-kit-0.98 )
	libsamplerate? ( media-libs/libsamplerate )
	pulseaudio? ( media-sound/pulseaudio )
	speex? ( media-libs/speex )
	!media-plugins/alsa-jack"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${PN}-1.0.14_rc1-automagic.patch"
	epatch "${FILESDIR}/${PN}-1.0.14_rc1-init-ffmpeg.patch"

	# For some reasons the polyp/pulse plugin does fail with alsaplayer with a
	# failed assert. As the code works just fine with asserts disabled, for now
	# disable them waiting for a better solution.
	sed -i -e '/AM_CFLAGS/s:-Wall:-DNDEBUG -Wall:' \
		"${S}/pulse/Makefile.am"

	eautoreconf
	elibtoolize
}

src_compile() {
	use debug || append-flags -DNDEBUG

	# D-Bus is used for Maemo SDK, that standing to the
	# changelog is related to n770... disable it until
	# someone ask for it explicitely, to be on the safe
	# side.
	econf \
		$(use_enable ffmpeg avcodec) \
		$(use_enable jack) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable pulseaudio) \
		$(use_with speex speex lib) \
		--disable-dbus \
		--disable-dependency-tracking \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install

	cd "${S}/doc"
	dodoc upmix.txt vdownmix.txt README-pcm-oss
	use jack && dodoc README-jack
	use libsamplerate && dodoc samplerate.txt
	use pulseaudio && dodoc README-pulse
	use ffmpeg && dodoc lavcrate.txt a52.txt
}



-- 
gentoo-commits@l.g.o mailing list