[gentoo-commits] gentoo-x86 commit in app-antivirus/clamav: ChangeLog clamav-0.92_rc2.ebuild

[Thomas Raschbacher (lordvan)]

lordvan     07/10/10 08:47:42

  Modified:             ChangeLog
  Added:                clamav-0.92_rc2.ebuild
  Log:
  added 0.92 rc2
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.255                app-antivirus/clamav/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.255&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?rev=1.255&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/ChangeLog?r1=1.254&r2=1.255

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v
retrieving revision 1.254
retrieving revision 1.255
diff -u -r1.254 -r1.255
--- ChangeLog	29 Aug 2007 10:27:33 -0000	1.254
+++ ChangeLog	10 Oct 2007 08:47:41 -0000	1.255
@@ -1,6 +1,12 @@
 # ChangeLog for app-antivirus/clamav
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.254 2007/08/29 10:27:33 corsair Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/ChangeLog,v 1.255 2007/10/10 08:47:41 lordvan Exp $
+
+*clamav-0.92_rc2 (10 Oct 2007)
+
+  10 Oct 2007; Thomas Raschbacher <lordvan@g.o>
+  +clamav-0.92_rc2.ebuild:
+  added 0.92rc2
 
   29 Aug 2007; Markus Rothe <corsair@g.o> clamav-0.91.2.ebuild:
   Stable on ppc64; bug #189912



1.1                  app-antivirus/clamav/clamav-0.92_rc2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/clamav-0.92_rc2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-antivirus/clamav/clamav-0.92_rc2.ebuild?rev=1.1&content-type=text/plain

Index: clamav-0.92_rc2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-antivirus/clamav/clamav-0.92_rc2.ebuild,v 1.1 2007/10/10 08:47:41 lordvan Exp $

inherit autotools eutils flag-o-matic fixheadtails

MY_P="${P/_/}" # for rc's
DESCRIPTION="Clam Anti-Virus Scanner"
HOMEPAGE="http://www.clamav.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="bzip2 crypt logrotate mailwrapper milter nls selinux"

DEPEND="virtual/libc
	bzip2? ( app-arch/bzip2 )
	crypt? ( >=dev-libs/gmp-4.1.2 )
	milter? ( || ( mail-filter/libmilter mail-mta/sendmail ) )
	nls? ( sys-devel/gettext )
	dev-libs/gmp
	>=sys-libs/zlib-1.2.1-r3
	>=sys-apps/sed-4"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-clamav )
	logrotate? ( app-admin/logrotate )
	sys-apps/grep"
PROVIDE="virtual/antivirus"

S=${WORKDIR}/${MY_P}
pkg_setup() {
	if use milter; then
		if [ ! -e /usr/lib/libmilter.a ] ; then
			ewarn "In order to enable milter support, clamav needs sendmail with enabled milter"
			ewarn "USE flag. Either recompile sendmail with milter USE flag enabled, or disable"
			ewarn "this flag for clamav as well to disable milter support."
			die "need milter-enabled sendmail"
		fi
	fi
	enewgroup clamav
	enewuser clamav -1 -1 /dev/null clamav
}

src_unpack() {
	unpack "${A}"
	cd "${S}"
	echo $S
	epatch "${FILESDIR}"/${PN}-0.90-compat.patch
	epatch "${FILESDIR}"/${PN}-0.90-nls.patch
	eautoreconf
}

src_compile() {
	has_version =sys-libs/glibc-2.2* && filter-lfs-flags

	local myconf

	# we depend on fixed zlib, so we can disable this check to prevent redundant
	# warning (bug #61749)
	myconf="${myconf} --disable-zlib-vcheck"
	# use id utility instead of /etc/passwd parsing (bug #72540)
	myconf="${myconf} --enable-id-check"
	use milter && {
		myconf="${myconf} --enable-milter"
		use mailwrapper && \
			myconf="${myconf} --with-sendmail=/usr/sbin/sendmail.sendmail"
	}

	ht_fix_file configure
	econf ${myconf} \
		$(use_enable bzip2) \
		$(use_enable nls) \
		--disable-experimental \
		--with-dbdir=/var/lib/clamav || die
	emake || die
}

src_install() {
	make DESTDIR=${D} install || die
	dodoc AUTHORS BUGS NEWS README ChangeLog FAQ
	newconfd ${FILESDIR}/clamd.conf clamd
	newinitd ${FILESDIR}/clamd.rc clamd
	dodoc ${FILESDIR}/clamav-milter.README.gentoo

	dodir /var/run/clamav
	keepdir /var/run/clamav
	fowners clamav:clamav /var/run/clamav
	dodir /var/log/clamav
	keepdir /var/log/clamav
	fowners clamav:clamav /var/log/clamav

	# Change /etc/clamd.conf to be usable out of the box
	sed -i -e "s:^\(Example\):\# \1:" \
		-e "s:.*\(PidFile\) .*:\1 /var/run/clamav/clamd.pid:" \
		-e "s:.*\(LocalSocket\) .*:\1 /var/run/clamav/clamd.sock:" \
		-e "s:.*\(User\) .*:\1 clamav:" \
		-e "s:^\#\(LogFile\) .*:\1 /var/log/clamav/clamd.log:" \
		-e "s:^\#\(LogTime\).*:\1 yes:" \
		${D}/etc/clamd.conf

	# Do the same for /etc/freshclam.conf
	sed -i -e "s:^\(Example\):\# \1:" \
		-e "s:.*\(PidFile\) .*:\1 /var/run/clamav/freshclam.pid:" \
		-e "s:.*\(DatabaseOwner\) .*:\1 clamav:" \
		-e "s:^\#\(UpdateLogFile\) .*:\1 /var/log/clamav/freshclam.log:" \
		-e "s:^\#\(NotifyClamd\).*:\1 /etc/clamd.conf:" \
		-e "s:^\#\(ScriptedUpdates\).*:\1 yes:" \
		${D}/etc/freshclam.conf

	if use milter ; then
		echo "START_MILTER=no" \
			>> ${D}/etc/conf.d/clamd
		echo "MILTER_SOCKET=\"/var/run/clamav/clmilter.sock\"" \
			>>${D}/etc/conf.d/clamd
		echo "MILTER_OPTS=\"-m 10 --timeout=0\"" \
			>>${D}/etc/conf.d/clamd
	fi

	if use logrotate ; then
		diropts ""
		dodir /etc/logrotate.d
		insopts -m0644
		insinto /etc/logrotate.d
		newins ${FILESDIR}/${PN}.logrotate ${PN}
	fi
}

pkg_postinst() {
	echo
	if use milter ; then
		elog "For simple instructions how to setup the clamav-milter"
		elog "read /usr/share/doc/${PF}/clamav-milter.README.gentoo.gz"
		echo
	fi
	ewarn "Warning: clamd and/or freshclam have not been restarted."
	ewarn "You should restart them to start using new version: /etc/init.d/clamd restart"
	echo
	ewarn "The soname for libclamav has changed after clamav-0.90."
	ewarn "If you have upgraded from that or earlier version, it is recommended to run:"
	ewarn
	ewarn "revdep-rebuild --library libclamav.so.1"
	ewarn
	ewarn "This will fix linking errors caused by this change."
	echo
}



-- 
gentoo-commits@g.o mailing list