[gentoo-commits] gentoo-x86 commit in sci-electronics/gnucap: ChangeLog gnucap-0.35.20080324.ebuild

[Denis Dupeyron (calchan)]

calchan     08/03/29 17:53:17

  Modified:             ChangeLog
  Added:                gnucap-0.35.20080324.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.40                 sci-electronics/gnucap/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/gnucap/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/gnucap/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/gnucap/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/gnucap/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	15 Mar 2008 16:45:57 -0000	1.39
+++ ChangeLog	29 Mar 2008 17:53:16 -0000	1.40
@@ -1,6 +1,12 @@
 # ChangeLog for sci-electronics/gnucap
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gnucap/ChangeLog,v 1.39 2008/03/15 16:45:57 calchan Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gnucap/ChangeLog,v 1.40 2008/03/29 17:53:16 calchan Exp $
+
+*gnucap-0.35.20080324 (29 Mar 2008)
+
+  29 Mar 2008; Denis Dupeyron <calchan@g.o>
+  +gnucap-0.35.20080324.ebuild:
+  Version bump.
 
 *gnucap-0.35.20080211 (15 Mar 2008)
 



1.1                  sci-electronics/gnucap/gnucap-0.35.20080324.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/gnucap/gnucap-0.35.20080324.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/gnucap/gnucap-0.35.20080324.ebuild?rev=1.1&content-type=text/plain

Index: gnucap-0.35.20080324.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gnucap/gnucap-0.35.20080324.ebuild,v 1.1 2008/03/29 17:53:16 calchan Exp $

inherit multilib

SNAPSHOTDATE="${P##*.}"
MY_PV="${PN}-${SNAPSHOTDATE:0:4}-${SNAPSHOTDATE:4:2}-${SNAPSHOTDATE:6:2}"

DESCRIPTION="GNUCap is the GNU Circuit Analysis Package"
SRC_URI="http://www.gnucap.org/devel/${MY_PV}.tar.gz
	http://www.gnucap.org/devel/${MY_PV}-models-bsim.tar.gz
	http://www.gnucap.org/devel/${MY_PV}-models-ngspice17.tar.gz
	http://www.gnucap.org/devel/${MY_PV}-models-spice3f5.tar.gz"
HOMEPAGE="http://www.gnucap.org/"

IUSE="doc examples"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DEPEND="doc? ( virtual/tetex )"

S="${WORKDIR}/${MY_PV}"

src_unpack() {
	unpack ${A} || die "Failed to unpack!"
	cd "${S}"

	# No need to install COPYING and INSTALL
	sed -i \
		-e 's: COPYING INSTALL::' \
		-e 's:COPYING history INSTALL:history:' \
		doc/Makefile.in || die "sed failed"

	if ! use doc ; then
		sed -i \
			-e 's:SUBDIRS = doc examples man:SUBDIRS = doc examples:' \
			Makefile.in || die "sed failed"
	fi

	if ! use examples ; then
		sed -i \
			-e 's:SUBDIRS = doc examples:SUBDIRS = doc:' \
			Makefile.in || die "sed failed"
	fi

	sed -i -e "s:CFLAGS = -O2 -g:CFLAGS +=:" \
		-e "s:CCFLAGS = \$(CFLAGS):CCFLAGS += \$(CFLAGS):" \
		-e "s:../Gnucap:${S}/src:" \
		models-*/Make2 || die "sed failed"
}

src_compile () {
	econf --disable-dependency-tracking || die "Configuration failed"
	emake || die "Compilation failed"
	for PLUGIN_DIR in models-* ; do
		cd "${S}/${PLUGIN_DIR}"
		emake || die "Compilation failed in ${PLUGIN_DIR}"
	done
}

src_install () {
	emake DESTDIR="${D}" install || die "Installation failed"
	insopts -m0755
	for PLUGIN_DIR in models-* ; do
		insinto /usr/$(get_libdir)/gnucap/${PLUGIN_DIR}
		cd "${S}/${PLUGIN_DIR}"
		for PLUGIN in */*.so ; do
			newins ${PLUGIN} ${PLUGIN##*/} \
			|| die "Installation of ${PLUGIN_DIR}/${PLUGIN} failed"
		done
	done
}



-- 
gentoo-commits@l.g.o mailing list