[gentoo-commits] gentoo-x86 commit in mail-client/evolution: evolution-3.2.3-r1.ebuild ChangeLog evolution-3.2.2.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/04/20 05:51:19

  Modified:             ChangeLog
  Added:                evolution-3.2.3-r1.ebuild
  Removed:              evolution-3.2.2.ebuild
  Log:
  Improve glib-2.32 fix (bug #412239, thanks to Dmitry K). Fix crash and build failure with gtkhtml-4.4. Drop old.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.360                mail-client/evolution/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.360&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.360&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?r1=1.359&r2=1.360

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v
retrieving revision 1.359
retrieving revision 1.360
diff -u -r1.359 -r1.360
--- ChangeLog	19 Apr 2012 20:38:13 -0000	1.359
+++ ChangeLog	20 Apr 2012 05:51:19 -0000	1.360
@@ -1,6 +1,15 @@
 # ChangeLog for mail-client/evolution
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.359 2012/04/19 20:38:13 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.360 2012/04/20 05:51:19 tetromino Exp $
+
+*evolution-3.2.3-r1 (20 Apr 2012)
+
+  20 Apr 2012; Alexandre Rostovtsev <tetromino@g.o>
+  -evolution-3.2.2.ebuild, +evolution-3.2.3-r1.ebuild,
+  files/evolution-3.2.3-g_thread_init.patch,
+  +files/evolution-3.2.3-gtkhtml-4.4.patch:
+  Improve glib-2.32 fix (bug #412239, thanks to Dmitry K). Fix crash and build
+  failure with gtkhtml-4.4. Drop old.
 
   19 Apr 2012; Brent Baude <ranger@g.o> evolution-2.32.3-r1.ebuild:
   Marking evolution-2.32.3-r1 ppc64 stable for bug 410611



1.1                  mail-client/evolution/evolution-3.2.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-3.2.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-3.2.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: evolution-3.2.3-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-3.2.3-r1.ebuild,v 1.1 2012/04/20 05:51:19 tetromino Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="python? 2:2.5"

inherit autotools eutils flag-o-matic gnome2 python

DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="GPL-2 LGPL-2 OPENLDAP"
SLOT="2.0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="clutter connman crypt doc +gnome-online-accounts gstreamer kerberos ldap map networkmanager python ssl"

# We need a graphical pinentry frontend to be able to ask for the GPG
# password from inside evolution, bug 160302
PINENTRY_DEPEND="|| ( app-crypt/pinentry[gtk] app-crypt/pinentry-qt app-crypt/pinentry[qt4] )"

# contacts-map plugin requires libchaimplain and geoclue
# glade-3 support is for maintainers only per configure.ac
# mono plugin disabled as it's incompatible with 2.8 and lacks maintainance (see bgo#634571)
# pst is not mature enough and changes API/ABI frequently
COMMON_DEPEND=">=dev-libs/glib-2.28:2
	>=x11-libs/cairo-1.9.15[glib]
	>=x11-libs/gtk+-3.0.2:3
	>=gnome-base/gnome-desktop-2.91.3:3
	>=gnome-base/gsettings-desktop-schemas-2.91.92
	>=dev-libs/libgweather-2.90.0:2
	>=media-libs/libcanberra-0.25[gtk3]
	>=x11-libs/libnotify-0.7
	>=gnome-extra/evolution-data-server-${PV}[gnome-online-accounts?,weather]
	>=gnome-extra/gtkhtml-4.1.2:4.0
	>=gnome-base/gconf-2:2
	dev-libs/atk
	>=dev-libs/libxml2-2.7.3:2
	>=net-libs/libsoup-gnome-2.31.2:2.4
	>=x11-misc/shared-mime-info-0.22
	>=x11-themes/gnome-icon-theme-2.30.2.1
	>=dev-libs/libgdata-0.9.1

	x11-libs/libSM
	x11-libs/libICE

	clutter? (
		>=media-libs/clutter-1.0.0:1.0
		>=media-libs/clutter-gtk-0.90:1.0
		x11-libs/mx:1.0 )
	connman? ( net-misc/connman )
	crypt? ( || (
		( >=app-crypt/gnupg-2.0.1-r2 ${PINENTRY_DEPEND} )
		=app-crypt/gnupg-1.4* ) )
	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.1.1 )
	gstreamer? (
		>=media-libs/gstreamer-0.10:0.10
		>=media-libs/gst-plugins-base-0.10:0.10 )
	kerberos? ( virtual/krb5 )
	ldap? ( >=net-nds/openldap-2 )
	map? (
		>=app-misc/geoclue-0.11.1
		media-libs/libchamplain:0.10 )
	networkmanager? ( >=net-misc/networkmanager-0.7 )
	ssl? (
		>=dev-libs/nspr-4.6.1
		>=dev-libs/nss-3.11 )"
DEPEND="${COMMON_DEPEND}
	>=dev-util/pkgconfig-0.16
	>=dev-util/intltool-0.40.0
	>=sys-devel/gettext-0.17
	sys-devel/bison
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.9.1
	app-text/docbook-xml-dtd:4.1.2
	>=gnome-base/gnome-common-2.12
	>=dev-util/gtk-doc-am-1.9
	doc? ( >=dev-util/gtk-doc-1.9 )"
# eautoreconf needs:
#	>=gnome-base/gnome-common-2.12
#	>=dev-util/gtk-doc-am-1.9
RDEPEND="${COMMON_DEPEND}
	!<gnome-extra/evolution-exchange-2.32"

# contact maps require clutter
# NM and connman support cannot coexist
REQUIRED_USE="map? ( clutter )
	connman? ( !networkmanager )
	networkmanager? ( !connman )"

pkg_setup() {
	ELTCONF="--reverse-deps"
	DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
	# image-inline plugin needs a gtk+:3 gtkimageview, which does not exist yet
	G2CONF="${G2CONF}
		--without-glade-catalog
		--without-kde-applnk-path
		--enable-plugins=experimental
		--disable-image-inline
		--disable-mono
		--disable-pst-import
		--enable-canberra
		--enable-weather
		$(use_enable ssl nss)
		$(use_enable ssl smime)
		$(use_enable networkmanager nm)
		$(use_enable connman)
		$(use_enable gnome-online-accounts goa)
		$(use_enable gstreamer audio-inline)
		$(use_enable map contact-maps)
		$(use_enable python)
		$(use_with clutter)
		$(use_with ldap openldap)
		$(use_with kerberos krb5 ${EPREFIX}/usr)"

	# dang - I've changed this to do --enable-plugins=experimental.  This will
	# autodetect new-mail-notify and exchange, but that cannot be helped for the
	# moment.  They should be changed to depend on a --enable-<foo> like mono
	# is.  This cleans up a ton of crap from this ebuild.

	# Use NSS/NSPR only if 'ssl' is enabled.
	if use ssl ; then
		G2CONF="${G2CONF} --enable-nss=yes"
	else
		G2CONF="${G2CONF}
			--without-nspr-libs
			--without-nspr-includes
			--without-nss-libs
			--without-nss-includes"
	fi

	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# https://bugzilla.gnome.org/show_bug.cgi?id=663077, requires eautoreconf
	epatch "${FILESDIR}/${PN}-3.2.1-reorder-mx-clutter-gtk.patch"
	# Fix build failure with glib-2.32
	epatch "${FILESDIR}/${P}-gmodule-explicit.patch"
	epatch "${FILESDIR}/${P}-g_thread_init.patch"
	# Fix crashes and linking failure with gtkhtml-4.4
	epatch "${FILESDIR}/${P}-gtkhtml-4.4.patch"
	eautoreconf

	gnome2_src_prepare
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "To change the default browser if you are not using GNOME, edit"
	elog "~/.local/share/applications/mimeapps.list so it includes the"
	elog "following content:"
	elog ""
	elog "[Default Applications]"
	elog "x-scheme-handler/http=firefox.desktop"
	elog "x-scheme-handler/https=firefox.desktop"
	elog ""
	elog "(replace firefox.desktop with the name of the appropriate .desktop"
	elog "file from /usr/share/applications if you use a different browser)."
	elog ""
	elog "Junk filters are now a run-time choice. You will get a choice of"
	elog "bogofilter or spamassassin based on which you have installed"
	elog ""
	elog "You have to install one of these for the spam filtering to actually work"
}