[gentoo-commits] gentoo-x86 commit in net-p2p/qbittorrent: ChangeLog qbittorrent-2.2.5.ebuild

[Ben de Groot (yngwin)]

yngwin      10/04/10 16:14:48

  Modified:             ChangeLog
  Added:                qbittorrent-2.2.5.ebuild
  Log:
  Version bump. Drop conf.pri hack, as the correct values are now detected from the arguments we pass to configure. Fixes bug #313811.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.79                 net-p2p/qbittorrent/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/qbittorrent/ChangeLog?rev=1.79&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/qbittorrent/ChangeLog?rev=1.79&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/qbittorrent/ChangeLog?r1=1.78&r2=1.79

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v
retrieving revision 1.78
retrieving revision 1.79
diff -u -r1.78 -r1.79
--- ChangeLog	8 Apr 2010 12:35:58 -0000	1.78
+++ ChangeLog	10 Apr 2010 16:14:48 -0000	1.79
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/qbittorrent
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.78 2010/04/08 12:35:58 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.79 2010/04/10 16:14:48 yngwin Exp $
+
+*qbittorrent-2.2.5 (10 Apr 2010)
+
+  10 Apr 2010; Ben de Groot <yngwin@g.o> +qbittorrent-2.2.5.ebuild:
+  Version bump. Drop conf.pri hack, as the correct values are now detected
+  from the arguments we pass to configure. Fixes bug #313811.
 
   08 Apr 2010; Christian Faulhammer <fauli@g.o>
   qbittorrent-2.2.2.ebuild:



1.1                  net-p2p/qbittorrent/qbittorrent-2.2.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.2.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.2.5.ebuild?rev=1.1&content-type=text/plain

Index: qbittorrent-2.2.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.2.5.ebuild,v 1.1 2010/04/10 16:14:48 yngwin Exp $

EAPI="2"
inherit confutils qt4-r2 versionator

DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="http://www.qbittorrent.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+X geoip libnotify"

# boost version so that we always have thread support
CDEPEND="net-libs/rb_libtorrent
	x11-libs/qt-core:4
	X? ( x11-libs/qt-gui:4
		libnotify? ( x11-libs/qt-gui:4[glib] ) )
	>=dev-libs/boost-1.34.1"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"
RDEPEND="${CDEPEND}
	>=dev-lang/python-2.3
	geoip? ( dev-libs/geoip )
	libnotify? ( x11-libs/libnotify )"

DOCS="AUTHORS Changelog NEWS README TODO"

pkg_setup() {
	confutils_use_depend_all libnotify X
}

src_prepare() {
	# Respect LDFLAGS
	sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
	qt4-r2_src_prepare
}

src_configure() {
	local myconf
	use X         || myconf+=" --disable-gui"
	use geoip     || myconf+=" --disable-geoip-database"
	use libnotify || myconf+=" --disable-libnotify"

	# slotted boost detection, bug #309415
	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
	myconf+=" --with-libboost-inc=/usr/include/boost-${BOOST_VER}"

	# econf fails, since this uses qconf
	./configure --prefix=/usr --qtdir=/usr ${myconf} || die "configure failed"
	eqmake4
}