[gentoo-commits] gentoo-x86 commit in app-admin/conserver: ChangeLog conserver-8.1.16.ebuild

[Ulrich Mueller (ulm)]

ulm         07/12/08 11:15:34

  Modified:             ChangeLog
  Added:                conserver-8.1.16.ebuild
  Log:
  Version bump. Replace call to docert by install_cert, bug #174759.
  (Portage version: 2.1.4_rc8)

Revision  Changes    Path
1.64                 app-admin/conserver/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/conserver/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/conserver/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/conserver/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/conserver/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	5 Sep 2007 17:51:20 -0000	1.63
+++ ChangeLog	8 Dec 2007 11:15:33 -0000	1.64
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/conserver
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/conserver/ChangeLog,v 1.63 2007/09/05 17:51:20 phreak Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/conserver/ChangeLog,v 1.64 2007/12/08 11:15:33 ulm Exp $
+
+*conserver-8.1.16 (08 Dec 2007)
+
+  08 Dec 2007; Ulrich Mueller <ulm@g.o> +conserver-8.1.16.ebuild:
+  Version bump. Replace call to docert by install_cert, bug #174759.
 
   05 Sep 2007; Christian Heim <phreak@g.o> metadata.xml:
   Removing weeve from metadata due to his retirement (see #181019 for reference).



1.1                  app-admin/conserver/conserver-8.1.16.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/conserver/conserver-8.1.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/conserver/conserver-8.1.16.ebuild?rev=1.1&content-type=text/plain

Index: conserver-8.1.16.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/conserver/conserver-8.1.16.ebuild,v 1.1 2007/12/08 11:15:33 ulm Exp $

inherit ssl-cert eutils pam

DESCRIPTION="Serial Console Manager"
HOMEPAGE="http://www.conserver.com/"
SRC_URI="ftp://ftp.conserver.com/conserver/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="pam ssl tcpd debug"

DEPEND="ssl? ( >=dev-libs/openssl-0.9.6g )
	pam? ( virtual/pam )
	tcpd? ( sys-apps/tcp-wrappers )
	debug? ( dev-libs/dmalloc )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Apply patch to prevent package from stripping binaries
	epatch "${FILESDIR}"/${PN}-prestrip.patch
}

src_compile() {
	econf \
		$(use_with ssl openssl) \
		$(use_with pam) \
		$(use_with tcpd libwrap) \
		$(use_with debug dmalloc) \
		--with-logfile=/var/log/conserver.log \
		--with-pidfile=/var/run/conserver.pid \
		--with-cffile=conserver/conserver.cf \
		--with-pwdfile=conserver/conserver.passwd \
		--with-master=localhost \
		--with-port=7782 || die "./configure failed"

	emake || die "compile failed"
}

src_install() {
	einstall exampledir="${D}"/usr/share/doc/${PF}/examples \
		|| die "problem with install"

	## create data directory
	dodir /var/consoles
	fowners daemon:daemon /var/consoles
	fperms 700 /var/consoles

	## add startup and sample config
	newinitd "${FILESDIR}"/conserver.initd conserver
	newconfd "${FILESDIR}"/conserver.confd conserver

	dodir /etc/conserver
	fperms 700 /etc/conserver
	insinto /etc/conserver
	newins "${S}"/conserver.cf/conserver.cf conserver.cf.sample
	newins "${S}"/conserver.cf/conserver.passwd conserver.passwd.sample

	## add docs
	dohtml conserver.html
	dodoc CHANGES FAQ PROTOCOL README TODO
	dodoc conserver/Sun-serial contrib/maketestcerts
	newdoc conserver.cf/conserver.cf conserver.cf.sample

	# Add pam config
	newpamd "${FILESDIR}"/conserver.pam-include.1 conserver
}

pkg_postinst() {
	# Add certs if SSL use flag is enabled
	if use ssl && [ ! -f "${ROOT}"/etc/ssl/conserver/conserver.key ]; then
		install_cert /etc/ssl/conserver/conserver
	fi
}



-- 
gentoo-commits@g.o mailing list