[gentoo-commits] gentoo-x86 commit in x11-misc/slim: ChangeLog slim-1.3.1-r1.ebuild slim-1.3.1.ebuild

[Jeremy Olexa (darkside)]

darkside    08/11/23 18:11:23

  Modified:             ChangeLog
  Added:                slim-1.3.1-r1.ebuild
  Removed:              slim-1.3.1.ebuild
  Log:
  on second though, the proper fix is to rev bump slim to lose the coreutils dep, bug #215661
  (Portage version: 2.2_rc14/cvs/Linux 2.6.27.6 x86_64)

Revision  Changes    Path
1.23                 x11-misc/slim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/slim/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/slim/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/slim/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	23 Nov 2008 18:07:24 -0000	1.22
+++ ChangeLog	23 Nov 2008 18:11:23 -0000	1.23
@@ -1,6 +1,13 @@
 # ChangeLog for x11-misc/slim
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v 1.22 2008/11/23 18:07:24 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/ChangeLog,v 1.23 2008/11/23 18:11:23 darkside Exp $
+
+*slim-1.3.1-r1 (23 Nov 2008)
+
+  23 Nov 2008; Jeremy Olexa <darkside@g.o> -slim-1.3.1.ebuild,
+  +slim-1.3.1-r1.ebuild:
+  on second though, the proper fix is to rev bump slim to lose the coreutils
+  dep, bug #215661
 
   23 Nov 2008; Jeremy Olexa <darkside@g.o> slim-1.3.1.ebuild:
   remove corefonts from explicit RDEPEND, not needed as seen in bug #215661



1.1                  x11-misc/slim/slim-1.3.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/slim/slim-1.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/slim/slim-1.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: slim-1.3.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/slim/slim-1.3.1-r1.ebuild,v 1.1 2008/11/23 18:11:23 darkside Exp $

inherit toolchain-funcs pam

DESCRIPTION="Simple Login Manager"
HOMEPAGE="http://slim.berlios.de"
SRC_URI="mirror://berlios/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~sparc ~x86"
IUSE="pam"

DEPEND="x11-proto/xproto
	x11-libs/libXmu
	x11-libs/libX11
	x11-libs/libXpm
	x11-libs/libXft
	media-libs/libpng
	media-libs/jpeg
	pam? ( virtual/pam )"
RDEPEND="${DEPEND}
	x11-apps/sessreg"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# respect C[XX]FLAGS, fix crosscompile,
	# fix linking order for --as-needed"
	sed -i -e "s:^CXX=.*:CXX=$(tc-getCXX) ${CXXFLAGS}:" \
		-e "s:^CC=.*:CC=$(tc-getCC) ${CFLAGS}:" \
		-e "s:^MANDIR=.*:MANDIR=/usr/share/man:" \
		-e "s:^\t\(.*\)\ \$(LDFLAGS)\ \(.*\):\t\1\ \2\ \$(LDFLAGS):g" \
		-r -e "s:^LDFLAGS=(.*):LDFLAGS=\1 ${LDFLAGS}:" \
		Makefile || die 'sed failed in Makefile'

	# Set slim to daemon mode as default to stop xdm runscript from throwing errors on stop
	# Set the default logfile to /dev/null to avoid cluttering up the harddisk
	# as slim puts a lot of garbage in its logfile
	# Make slim honor XSESSION in /etc/rc.conf by default.
	sed -i -e 's/# daemon/daemon/' \
		-e 's#/var/log/slim.log#/dev/null#g' \
		-e '/^login_cmd.*/s#exec /bin/bash.*#exec /bin/bash -login /etc/X11/xinit/xinitrc#' \
		slim.conf || die "sed failed in slim.conf"

		# This method of appending to the slim.conf file may change, but it
		# works for now.
		echo "# Needed so your login will show up in wtmp and utmp, etc" >> slim.conf || die
		echo "sessionstart_cmd        /usr/bin/sessreg -a -l $DISPLAY %user" >> slim.conf || die
		echo "sessionstop_cmd         /usr/bin/sessreg -d -l $DISPLAY %user" >> slim.conf || die
}

src_compile() {
	if use pam ; then
		emake USE_PAM=1 || die "emake failed."
	else
		emake || die "emake failed."
	fi
}

src_install() {
	if use pam ; then
		emake USE_PAM=1 DESTDIR="${D}" install || die "emake install failed."
		pamd_mimic_system slim auth account password session
	else
		emake DESTDIR="${D}" install || die "emake install failed."
	fi

	dodoc xinitrc.sample ChangeLog README TODO THEMES
}

pkg_postinst() {
	elog
	elog "The configuration file is located at /etc/slim.conf."
	elog
	elog "If you wish ${PN} to start automatically, set DISPLAYMANAGER=\"${PN}\" "
	elog "in /etc/conf.d/xdm and run \"rc-update add xdm default\"."
	elog "By default, ${PN} will use default XSESSION value set in /etc/rc.conf."
	elog
	elog "If you want to use .xinitrc in the user's home directory for session"
	elog "management instead, see README and xinitrc.sample in"
	elog "/usr/share/doc/${PF} and change your login_cmd in /etc/slim.conf"
	elog "accordingly."
	elog
	if ! use pam; then
		elog "You have merged ${PN} without USE=pam, this will cause ${PN} to fall back to"
		elog "the console when restarting your window manager. If this is not"
		elog "desired, then please remerge ${PN} with USE=pam"
	fi
}