[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: ChangeLog alsa-utils-1.0.14-r1.ebuild

[Christian Heim (phreak)]

phreak      07/09/17 16:46:49

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.14-r1.ebuild
  Log:
  Add a patch from upstream, removing a debug print (http://hg-mirror.alsa-project.org/alsa-utils/rev/b230fef1ea76 - #184716 thanks to Mario Bachmann <grafgrimm77 at gmx.de>).
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.214                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.214&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.214&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.213&r2=1.214

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.213
retrieving revision 1.214
diff -u -r1.213 -r1.214
--- ChangeLog	10 Sep 2007 14:10:12 -0000	1.213
+++ ChangeLog	17 Sep 2007 16:46:49 -0000	1.214
@@ -1,6 +1,15 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.213 2007/09/10 14:10:12 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.214 2007/09/17 16:46:49 phreak Exp $
+
+*alsa-utils-1.0.14-r1 (17 Sep 2007)
+
+  17 Sep 2007; Christian Heim <phreak@g.o>
+  +files/alsa-utils-1.0.14-remove-debug-printing.patch,
+  +alsa-utils-1.0.14-r1.ebuild:
+  Add a patch from upstream, removing a debug print
+  (http://hg-mirror.alsa-project.org/alsa-utils/rev/b230fef1ea76 - #184716
+  thanks to Mario Bachmann <grafgrimm77 at gmx.de>).
 
   10 Sep 2007; Jeroen Roovers <jer@g.o> alsa-utils-1.0.14.ebuild:
   Stable for HPPA (bug #189155).



1.1                  media-sound/alsa-utils/alsa-utils-1.0.14-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.14-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.14-r1.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.14-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.14-r1.ebuild,v 1.1 2007/09/17 16:46:49 phreak Exp $

WANT_AUTOMAKE="latest"
WANT_AUTOCONF="latest"

inherit eutils autotools

MY_P="${P/_rc/rc}"

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="nls midi"

DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-1.0.14"
RDEPEND="${DEPEND}
	virtual/modutils
	sys-apps/pciutils"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if use midi && ! built_with_use --missing true media-libs/alsa-lib midi; then
		eerror ""
		eerror "To be able to build alsa-utils with midi support you need"
		eerror "to have built media-libs/alsa-lib with midi USE flag."
		die "Missing midi USE flag on media-libs/alsa-lib"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${PN}-1.0.11_rc2-nls.patch"
	epatch "${FILESDIR}/${PN}-1.0.11_rc5-alsaconf-redirect.patch"
	epatch "${FILESDIR}/${P}-seq.patch"
	epatch "${FILESDIR}/${P}-remove-debug-printing.patch"

	AT_M4DIR="m4" eautoreconf
}

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable midi sequencer) \
		|| die "configure failed"

	emake || die "make failed"
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "Installation Failed"

	dodoc ${ALSA_UTILS_DOCS}
	newdoc alsamixer/README README.alsamixer

	newinitd "${FILESDIR}/alsasound.initd" alsasound
	newconfd "${FILESDIR}/alsasound.confd" alsasound
	insinto /etc/modules.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "loading and unloading the ALSA sound drivers as well as"
	elog "storing and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
}



-- 
gentoo-commits@g.o mailing list