[gentoo-commits] gentoo-x86 commit in sys-libs/pam: ChangeLog pam-0.99.9.0.ebuild pam-0.99.8.1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    07/10/19 20:21:34

  Modified:             ChangeLog
  Added:                pam-0.99.9.0.ebuild
  Removed:              pam-0.99.8.1.ebuild
  Log:
  Version bump, and remove old version non-stable-target.
  (Portage version: 2.1.3.15)

Revision  Changes    Path
1.169                sys-libs/pam/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/pam/ChangeLog?rev=1.169&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/pam/ChangeLog?rev=1.169&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/pam/ChangeLog?r1=1.168&r2=1.169

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/pam/ChangeLog,v
retrieving revision 1.168
retrieving revision 1.169
diff -u -r1.168 -r1.169
--- ChangeLog	18 Sep 2007 23:59:24 -0000	1.168
+++ ChangeLog	19 Oct 2007 20:21:33 -0000	1.169
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/pam
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/pam/ChangeLog,v 1.168 2007/09/18 23:59:24 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/pam/ChangeLog,v 1.169 2007/10/19 20:21:33 flameeyes Exp $
+
+*pam-0.99.9.0 (19 Oct 2007)
+
+  19 Oct 2007; Diego Pettenò <flameeyes@g.o> -pam-0.99.8.1.ebuild,
+  +pam-0.99.9.0.ebuild:
+  Version bump, and remove old version non-stable-target.
 
 *pam-0.99.8.1-r1 (18 Sep 2007)
 



1.1                  sys-libs/pam/pam-0.99.9.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/pam/pam-0.99.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/pam/pam-0.99.9.0.ebuild?rev=1.1&content-type=text/plain

Index: pam-0.99.9.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/pam/pam-0.99.9.0.ebuild,v 1.1 2007/10/19 20:21:33 flameeyes Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit libtool multilib eutils autotools pam toolchain-funcs

MY_PN="Linux-PAM"
MY_P="${MY_PN}-${PV}"

HOMEPAGE="http://www.kernel.org/pub/linux/libs/pam/"
DESCRIPTION="Linux-PAM (Pluggable Authentication Modules)"

SRC_URI="mirror://kernel/linux/libs/pam/pre/library/${MY_P}.tar.bz2"

LICENSE="PAM"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="cracklib nls elibc_FreeBSD selinux vim-syntax audit"

RDEPEND="nls? ( virtual/libintl )
	cracklib? ( >=sys-libs/cracklib-2.8.3 )
	audit? ( sys-process/audit )
	sys-libs/pwdb
	selinux? ( >=sys-libs/libselinux-1.28 )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"
PDEPEND="vim-syntax? ( app-vim/pam-syntax )"

S="${WORKDIR}/${MY_P}"

PROVIDE="virtual/pam"

check_old_modules() {
	local retval="0"

	if sed -e 's:#.*::' /etc/pam.d/* | fgrep -q pam_stack.so; then
		eerror ""
		eerror "Your current setup is using the pam_stack module."
		eerror "This module is deprecated and no more supported, and since version"
		eerror "0.99 is no more installed, nor provided by any other package."
		eerror "The package will be built (to allow binary package builds), but will"
		eerror "not be installed."
		eerror "Please replace pam_stack usage with proper include directive usage,"
		eerror "following the PAM Upgrade guide at the following URL"
		eerror "  http://www.gentoo.org/proj/en/base/pam/upgrade-0.99.xml"
		eerror ""
		ebeep 15

		retval=1
	fi

	if sed -e 's:#.*::' /etc/pam.d/* | egrep -q 'pam_(pwdb|radius|timestamp)'; then
		eerror ""
		eerror "Your current setup is using one or more of the following modules,"
		eerror "that are not built or supported anymore:"
		eerror "pam_pwdb, pam_radius, pam_timestamp"
		eerror "If you are in real need for these modules, please contact the maintainers"
		eerror "of PAM through http://bugs.gentoo.org/ providing information about its"
		eerror "use cases."
		ebeep 10

		retval=1
	fi

	# Produce the warnings only during upgrade, for the following two
	has_version '<sys-libs/pam-0.99' || return $retval

	# This works only for those modules that are moved to sys-auth/$module, or the
	# message will be wrong.
	for module in pam_chroot pam_console pam_userdb; do
		if sed -e 's:#.*::' /etc/pam.d/* | fgrep -q ${module}.so; then
			ewarn ""
			ewarn "Your current setup is using the ${module} module."
			ewarn "Since version 0.99, ${CATEGORY}/${PN} does not provide this module"
			ewarn "anymore; if you want to continue using this module, you should install"
			ewarn "sys-auth/${module}."
			ewarn ""
			ebeep 5
		fi
	done

	return $retval
}

pkg_setup() {
	check_old_modules
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	mkdir -p doc/txts
	for readme in modules/pam_*/README; do
		cp -f "${readme}" doc/txts/README.$(dirname "${readme}" | \
			sed -e 's|^modules/||')
	done

	epatch "${FILESDIR}/${MY_PN}-0.99.7.0-disable-regenerate-man.patch"

	AT_M4DIR="m4" eautoreconf

	elibtoolize
}

src_compile() {
	local myconf

	if use hppa || use elibc_FreeBSD; then
		myconf="${myconf} --disable-pie"
	fi

	econf \
		$(use_enable nls) \
		$(use_enable selinux) \
		$(use_enable cracklib) \
		$(use_enable audit) \
		--libdir=/usr/$(get_libdir) \
		--disable-db \
		--enable-securedir=/$(get_libdir)/security \
		--enable-isadir=/$(get_libdir)/security \
		--disable-dependency-tracking \
		--disable-prelude \
		--enable-docdir=/usr/share/doc/${PF} \
		--disable-regenerate-man \
		${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	# Need to be suid
	fperms u+s /sbin/unix_chkpwd

	dodir /$(get_libdir)
	mv "${D}/usr/$(get_libdir)/libpam.so"* "${D}/$(get_libdir)/"
	mv "${D}/usr/$(get_libdir)/libpamc.so"* "${D}/$(get_libdir)/"
	mv "${D}/usr/$(get_libdir)/libpam_misc.so"* "${D}/$(get_libdir)/"
	gen_usr_ldscript libpam.so libpamc.so libpam_misc.so

	# No, we don't really need .la files for PAM modules.
	rm -f "${D}/$(get_libdir)/security/"*.la

	dodoc CHANGELOG ChangeLog README AUTHORS Copyright
	docinto modules ; dodoc doc/txts/README.*

	newpamd "${FILESDIR}/system-auth.pamd.epam" system-auth
	newpamd "${FILESDIR}/other.pamd" other

	# Remove the wrongly installed manpages
	rm "${D}"/usr/share/man/man8/pam_userdb.8*
	use cracklib || rm "${D}"/usr/share/man/man8/pam_cracklib.8*
}

pkg_preinst() {
	check_old_modules || die "deprecated PAM modules still used"

	pam_epam_expand "${D}"/etc/pam.d/*
}

pkg_postinst() {
	if ! use cracklib; then
		ewarn "You chosen not to enable cracklib. Make sure you run etc-update or"
		ewarn "you won't be able to change users' passwords."
	fi
}



-- 
gentoo-commits@g.o mailing list