[gentoo-commits] gentoo-x86 commit in sys-devel/distcc: ChangeLog distcc-3.0-r2.ebuild distcc-3.0-r1.ebuild

[Matsuu Takuto (matsuu)]

matsuu      08/10/25 06:39:17

  Modified:             ChangeLog
  Added:                distcc-3.0-r2.ebuild
  Removed:              distcc-3.0-r1.ebuild
  Log:
  Added xinetd USE flag. Removed '--install' function from gcc-config and Added doenvd to src_install. Fixed #216950.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64)

Revision  Changes    Path
1.177                sys-devel/distcc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/distcc/ChangeLog?rev=1.177&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/distcc/ChangeLog?rev=1.177&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/distcc/ChangeLog?r1=1.176&r2=1.177

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/distcc/ChangeLog,v
retrieving revision 1.176
retrieving revision 1.177
diff -u -r1.176 -r1.177
--- ChangeLog	19 Oct 2008 14:45:22 -0000	1.176
+++ ChangeLog	25 Oct 2008 06:39:17 -0000	1.177
@@ -1,6 +1,16 @@
 # ChangeLog for sys-devel/distcc
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/ChangeLog,v 1.176 2008/10/19 14:45:22 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/ChangeLog,v 1.177 2008/10/25 06:39:17 matsuu Exp $
+
+*distcc-3.0-r2 (25 Oct 2008)
+
+  25 Oct 2008; MATSUU Takuto <matsuu@g.o> files/3.0/distcc-config,
+  +files/3.0/xinetd, files/3.0/init, -distcc-3.0-r1.ebuild,
+  +distcc-3.0-r2.ebuild:
+  Added xinetd USE flag. Removed '--install' function from gcc-config and
+  Added doenvd to src_install.
+  Added --daemon to /etc/init.d/distcc, bug #216950.
+  Clean up ebuild.
 
 *distcc-3.0-r1 (19 Oct 2008)
 



1.1                  sys-devel/distcc/distcc-3.0-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/distcc/distcc-3.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/distcc/distcc-3.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: distcc-3.0-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/distcc/distcc-3.0-r2.ebuild,v 1.1 2008/10/25 06:39:17 matsuu Exp $

inherit eutils fdo-mime flag-o-matic multilib toolchain-funcs

DESCRIPTION="a program to distribute compilation of C code across several machines on a network"
HOMEPAGE="http://distcc.org/"
SRC_URI="http://distcc.googlecode.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="avahi gnome gtk ipv6 selinux xinetd"

RESTRICT="test"

RDEPEND=">=dev-lang/python-2.4
	dev-libs/popt
	avahi? ( >=net-dns/avahi-0.6 )
	gnome? (
		>=gnome-base/libgnome-2
		>=gnome-base/libgnomeui-2
		>=x11-libs/gtk+-2
		x11-libs/pango
	)
	gtk? (
		>=x11-libs/gtk+-2
	)"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"
RDEPEND="${RDEPEND}
	!net-misc/pump
	>=sys-devel/gcc-config-1.3.1
	selinux? ( sec-policy/selinux-distcc )
	xinetd? ( sys-apps/xinetd )"

pkg_setup() {
	enewuser distcc 240 -1 -1 daemon
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-gentoo.patch"
	epatch "${FILESDIR}/${P}-svn617.patch"
}

src_compile() {
	# More legacy stuff?
	[ "$(gcc-major-version)" = "2" ] && filter-lfs-flags

	# -O? is required
	[ "${CFLAGS/-O}" = "${CFLAGS}" ] && CFLAGS="${CFLAGS} -O2"

	econf \
		$(use_with avahi) \
		$(use_with gtk) \
		$(use_with gnome) \
		$(use_enable ipv6 rfc2553) \
		--with-docdir="/usr/share/doc/${PF}" || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die

	dobin "${FILESDIR}/${PV}/distcc-config"

	newinitd "${FILESDIR}/${PV}/init" distccd

	cp "${FILESDIR}/${PV}/conf" "${T}/distccd"
	if use avahi; then
		cat >> "${T}/distccd" <<-EOF
	
		# Enable zeroconf support in distccd
		DISTCCD_OPTS="\${DISTCCD_OPTS} --zeroconf"
		EOF
	fi
	doconfd "${T}/distccd"

	cat > "${T}/02distcc" <<-EOF
	# This file is managed by distcc-config; use it to change these settings.'
	DISTCC_LOG=""
	DCCC_PATH="/usr/$(get_libdir)/distcc/bin"
	DISTCC_VERBOSE="0"
	EOF
	doenvd "${T}/02distcc"

	# create the masquerade directory
	local DCCC_PATH="/usr/$(get_libdir)/distcc/bin/"
	dodir "${DCCC_PATH}"
	for f in cc c++ gcc g++; do
		dosym /usr/bin/distcc "${DCCC_PATH}${f}"
		if [ "${f}" != "cc" ]; then
			dosym /usr/bin/distcc "${DCCC_PATH}${CTARGET:-${CHOST}}-${f}"
		fi
	done

	# create the distccd pid directory
	keepdir /var/run/distccd
	fowners distcc:daemon /var/run/distccd

	if use gnome || use gtk; then
	  einfo "Renaming /usr/bin/distccmon-gnome to /usr/bin/distccmon-gui"
	  einfo "This is to have a little sensability in naming schemes between distccmon programs"
	  mv "${D}/usr/bin/distccmon-gnome" "${D}/usr/bin/distccmon-gui" || die
	  dosym distccmon-gui /usr/bin/distccmon-gnome
	fi

	if use xinetd; then
		insinto /etc/xinetd.d
		newins "${FILEDIR}/${PV}/xinetd"
	fi

	rm -rf "${D}/etc/default"
	rm -f "${D}/etc/distcc/clients.allow"
	rm -f "${D}/etc/distcc/commands.allow.sh"
	prepalldocs
}

pkg_postinst() {
	use gnome && fdo-mime_desktop_database_update

	elog
	elog "Tips on using distcc with Gentoo can be found at"
	elog "http://www.gentoo.org/doc/en/distcc.xml"
	elog
	elog "To use the distccmon programs with Gentoo you should use this command:"
	elog "# DISTCC_DIR=\"${DISTCC_DIR}\" distccmon-text 5"

	if use gnome || use gtk; then
		elog "Or:"
		elog "# DISTCC_DIR=\"${DISTCC_DIR}\" distccmon-gnome"
	fi

	elog
	elog "***SECURITY NOTICE***"
	elog "If you are upgrading distcc please make sure to run etc-update to"
	elog "update your /etc/conf.d/distccd and /etc/init.d/distccd files with"
	elog "added security precautions (the --listen and --allow directives)"
	elog
}

pkg_postrm() {
	use gnome && fdo-mime_desktop_database_update
}