[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.41.7.ebuild

[Mike Frysinger (vapier)]

vapier      09/07/01 14:40:50

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.41.7.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.27                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	20 Jun 2009 11:58:44 -0000	1.26
+++ ChangeLog	1 Jul 2009 14:40:50 -0000	1.27
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.26 2009/06/20 11:58:44 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.27 2009/07/01 14:40:50 vapier Exp $
+
+*e2fsprogs-libs-1.41.7 (01 Jul 2009)
+
+  01 Jul 2009; Mike Frysinger <vapier@g.o>
+  +e2fsprogs-libs-1.41.7.ebuild:
+  Version bump.
 
   20 Jun 2009; Mike Frysinger <vapier@g.o>
   e2fsprogs-libs-1.41.3-r1.ebuild, e2fsprogs-libs-1.41.6.ebuild:



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.7.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.41.7.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.7.ebuild,v 1.1 2009/07/01 14:40:50 vapier Exp $

EAPI="2"

inherit flag-o-matic toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error, subsystem, uuid, block id)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="elibc_glibc? ( >=sys-libs/glibc-2.6 )
	!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41"
DEPEND="nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	sys-devel/bc"

src_prepare() {
	# stupid configure script clobbers CC for us
	sed -i '/if test -z "$CC" ; then CC=cc; fi/d' configure
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	ac_cv_path_LDCONFIG=: \
	econf \
		--enable-${libtype}-shlibs \
		$(use_enable !elibc_uclibc tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die

	set -- "${D}"/usr/$(get_libdir)/*.a
	set -- ${@/*\/lib}
	gen_usr_ldscript -a "${@/.a}"
}