[gentoo-commits] gentoo-x86 commit in www-client/uzbl: ChangeLog uzbl-2010.02.02.ebuild

[Alex Alexander (wired)]

wired       10/02/03 09:35:13

  Modified:             ChangeLog
  Added:                uzbl-2010.02.02.ebuild
  Log:
  uzbl-2010.02.02 version bump
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 www-client/uzbl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/uzbl/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/uzbl/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/uzbl/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/uzbl/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	27 Jan 2010 15:33:08 -0000	1.18
+++ ChangeLog	3 Feb 2010 09:35:13 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/uzbl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/uzbl/ChangeLog,v 1.18 2010/01/27 15:33:08 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/uzbl/ChangeLog,v 1.19 2010/02/03 09:35:13 wired Exp $
+
+*uzbl-2010.02.02 (03 Feb 2010)
+
+  03 Feb 2010; Alex Alexander <wired@g.o> +uzbl-2010.02.02.ebuild,
+  +files/uzbl-2010.02.02-makefile-cleanup.patch:
+  uzbl-2010.02.02 version bump
 
   27 Jan 2010; Alex Alexander <wired@g.o> uzbl-9999.ebuild,
   files/uzbl-9999-makefile-cleanup.patch:



1.1                  www-client/uzbl/uzbl-2010.02.02.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/uzbl/uzbl-2010.02.02.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/uzbl/uzbl-2010.02.02.ebuild?rev=1.1&content-type=text/plain

Index: uzbl-2010.02.02.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/uzbl/uzbl-2010.02.02.ebuild,v 1.1 2010/02/03 09:35:13 wired Exp $

EAPI="2"

inherit base

DESCRIPTION="A keyboard controlled (modal vim-like bindings, or with modifierkeys) browser based on Webkit."
HOMEPAGE="http://www.uzbl.org"
SRC_URI="http://github.com/Dieterbe/${PN}/tarball/${PV} -> ${P}.tar.gz"

LICENSE="LGPL-2.1 MPL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+browser helpers +tabbed"

COMMON_DEPEND="
	>=dev-libs/icu-4.0.1
	>=net-libs/libsoup-2.24
	>=net-libs/webkit-gtk-1.1.15
	>=x11-libs/gtk+-2.14
"

DEPEND="
	>=dev-util/pkgconfig-0.19
	${COMMON_DEPEND}
"

RDEPEND="
	${COMMON_DEPEND}
	x11-misc/xdg-utils
	browser? (
		x11-misc/xclip
	)
	helpers? (
		dev-lang/perl
		dev-perl/gtk2-perl
		dev-python/pygtk
		dev-python/pygobject
		gnome-extra/zenity
		net-misc/socat
		x11-libs/pango
		x11-misc/dmenu
		x11-misc/xclip
	)
"

pkg_setup() {
	if ! use helpers; then
		elog "uzbl's extra scripts use various optional applications:"
		elog
		elog "   dev-lang/perl"
		elog "   dev-perl/gtk2-perl"
		elog "   dev-python/pygtk"
		elog "   dev-python/pygobject"
		elog "   gnome-extra/zenity"
		elog "   net-misc/socat"
		elog "   x11-libs/pango"
		elog "   x11-misc/dmenu"
		elog "   x11-misc/xclip"
		elog
		elog "Make sure you emerge the ones you need manually."
		elog "You may also activate the *helpers* USE flag to"
		elog "install all of them automatically."
	else
		einfo "You have enabled the *helpers* USE flag that installs"
		einfo "various optional applications used by uzbl's extra scripts."
	fi

	if use tabbed && ! use browser; then
		ewarn
		ewarn "You enabled the *tabbed* USE flag but not *browser*."
		ewarn "*tabbed* depends on *browser*, so it will be disabled."
		ewarn
		ebeep 3
	fi
}

src_prepare() {
	cd "${WORKDIR}"/Dieterbe-uzbl-*
	S=$(pwd)

	# patch Makefile to make it more sane
	epatch "${FILESDIR}"/"${P}"-makefile-cleanup.patch

	# adjust path in default config file to /usr/share
	sed -i "s:/usr/local/share/uzbl:/usr/share/uzbl:g" \
		examples/config/config ||
		die "config path sed failed"
}

src_compile() {
	emake || die "compile failed"
}

src_install() {
	local targets="install-uzbl-core"
	use browser && targets="${targets} install-uzbl-browser"
	use browser && use tabbed && targets="${targets} install-uzbl-tabbed"

	emake DESTDIR="${D}" PREFIX="/usr" ${targets} || die "Installation failed"

	# Install the docs in /usr/share/doc.
	dodoc AUTHORS README docs/* || die "docs install failed"
}