[gentoo-commits] gentoo-x86 commit in app-misc/g15daemon: ChangeLog g15daemon-1.9.3.ebuild

[Markus Ullmann (jokey)]

jokey       07/12/28 13:50:43

  Modified:             ChangeLog
  Added:                g15daemon-1.9.3.ebuild
  Log:
  Version bump, thanks to robbat2 for the notification
  (Portage version: 2.1.4_rc11)

Revision  Changes    Path
1.19                 app-misc/g15daemon/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	25 Dec 2007 14:54:13 -0000	1.18
+++ ChangeLog	28 Dec 2007 13:50:42 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/g15daemon
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v 1.18 2007/12/25 14:54:13 jokey Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v 1.19 2007/12/28 13:50:42 jokey Exp $
+
+*g15daemon-1.9.3 (28 Dec 2007)
+
+  28 Dec 2007; Markus Ullmann <jokey@g.o> +g15daemon-1.9.3.ebuild:
+  Version bump, thanks to robbat2 for the notification
 
 *g15daemon-1.9.2 (25 Dec 2007)
 



1.1                  app-misc/g15daemon/g15daemon-1.9.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.3.ebuild?rev=1.1&content-type=text/plain

Index: g15daemon-1.9.3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.3.ebuild,v 1.1 2007/12/28 13:50:42 jokey Exp $

inherit eutils linux-info perl-module python multilib

DESCRIPTION="G15daemon takes control of the G15 keyboard, through the linux kernel uinput device driver"
HOMEPAGE="http://g15daemon.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="perl python"

DEPEND="dev-libs/libusb
	>=dev-libs/libg15-1.2.4
	>=dev-libs/libg15render-1.2
	perl? ( >=dev-perl/Inline-0.4 )
	python? ( dev-lang/python )"

RDEPEND="${DEPEND}
	perl? ( dev-perl/GDGraph )"

uinput_check() {
	ebegin "Checking for uinput support"
	linux_chkconfig_present INPUT_UINPUT
	eend $?

	if [[ $? -ne 0 ]] ; then
		eerror "To use g15daemon, you need to compile your kernel with uinput support."
		eerror "Please enable uinput support in your kernel config, found at:"
		eerror
		eerror "Device Drivers -> Input Device ... -> Miscellaneous devices -> User level driver support."
		eerror
		eerror "Once enabled, you should have the /dev/input/uinput device."
		eerror "g15daemon will not work without the uinput device."
		die "INPUT_UINPUT support not detected!"
	fi
}

pkg_setup() {
	linux-info_pkg_setup
	uinput_check
}

src_unpack() {
	unpack ${A}
	if use perl; then
		unpack "./${P}/lang-bindings/perl-G15Daemon-0.2.tar.gz"
	fi
	if use python; then
		unpack "./${P}/lang-bindings/pyg15daemon-0.0.tar.bz2"
	fi
}

src_compile() {
	econf || die "configure failed"

	emake || die "make failed"

	if use perl; then
		cd "${WORKDIR}/G15Daemon-0.2"
		perl-module_src_compile
	fi
}

src_install() {
	emake DESTDIR="${D}" \
		docdir=/usr/share/doc/${PF} install || die "make install failed"

	# remove odd docs installed my make
	rm "${D}/usr/share/doc/${PF}/"{LICENSE,README.usage}

	insinto /usr/share/${PN}/contrib
	doins contrib/xmodmaprc
	doins contrib/xmodmap.sh
	if use perl; then
		doins contrib/testbindings.pl
	fi

	newconfd "${FILESDIR}/${PN}-1.2.7.confd" ${PN}
	newinitd "${FILESDIR}/${PN}-1.2.7-r2.initd" ${PN}

	if use perl; then
		ebegin "Installing Perl Bindings (G15Daemon.pm)"
		cd "${WORKDIR}/G15Daemon-0.2"
		docinto perl
		perl-module_src_install
	fi

	if use python; then
		ebegin "Installing Python Bindings (g15daemon.py)"
		cd "${WORKDIR}/pyg15daemon"
		python_version

		insinto /usr/$(get_libdir)/python${PYVER}/site-packages/g15daemon
		doins g15daemon.py

		docinto python
		dodoc AUTHORS
	fi

	prepalldocs
}

pkg_postinst() {
	if use python; then
		python_mod_optimize "${ROOT}/usr/$(get_libdir)/python*/site-packages/g15daemon"
		echo ""
	fi

	elog "To use g15daemon, you need to add g15daemon to the default runlevel."
	elog "This can be done with:"
	elog "# /sbin/rc-update add g15daemon default"
	elog "You can edit some g15daemon options at /etc/conf.d/g15daemon"
	elog ""
	elog "To have all new keys working in X11, you'll need create a "
	elog "specific xmodmap in your home directory or edit the existent one."
	elog ""
	elog "Create the xmodmap:"
	elog "cp /usr/share/g15daemon/contrib/xmodmaprc ~/.Xmodmap"
	elog ""
	elog "Adding keycodes to an existing xmodmap:"
	elog "cat /usr/share/g15daemon/contrib/xmodmaprc >> ~/.Xmodmap"
}

pkg_postrm() {
	if use python; then
		python_mod_cleanup "/usr/$(get_libdir)/python*/site-packages/g15daemon"
	fi
}



-- 
gentoo-commits@g.o mailing list