[gentoo-commits] gentoo-x86 commit in games-kids/gcompris: ChangeLog gcompris-8.4.12.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/05/31 07:11:55

  Modified:             ChangeLog
  Added:                gcompris-8.4.12.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.11/cvs/Linux i686)

Revision  Changes    Path
1.46                 games-kids/gcompris/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-kids/gcompris/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-kids/gcompris/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-kids/gcompris/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	19 Jan 2009 04:40:40 -0000	1.45
+++ ChangeLog	31 May 2009 07:11:55 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for games-kids/gcompris
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v 1.45 2009/01/19 04:40:40 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v 1.46 2009/05/31 07:11:55 mr_bones_ Exp $
+
+*gcompris-8.4.12 (31 May 2009)
+
+  31 May 2009; Michael Sterrett <mr_bones_@g.o>
+  +files/gcompris-8.4.12-build.patch, +gcompris-8.4.12.ebuild:
+  version bump
 
   19 Jan 2009; Michael Sterrett <mr_bones_@g.o>
   files/gcompris-8.4.8-build.patch, gcompris-8.4.8.ebuild:



1.1                  games-kids/gcompris/gcompris-8.4.12.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-kids/gcompris/gcompris-8.4.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-kids/gcompris/gcompris-8.4.12.ebuild?rev=1.1&content-type=text/plain

Index: gcompris-8.4.12.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/gcompris-8.4.12.ebuild,v 1.1 2009/05/31 07:11:55 mr_bones_ Exp $

EAPI=2
inherit autotools eutils python games

DESCRIPTION="full featured educational application for children from 2 to 10"
HOMEPAGE="http://gcompris.net/"
SRC_URI="mirror://sourceforge/gcompris/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug gnet python sqlite"

RDEPEND="x11-libs/gtk+:2
	media-libs/gstreamer:0.10
	media-libs/gst-plugins-good
	media-plugins/gst-plugins-ogg
	media-plugins/gst-plugins-vorbis
	media-libs/libart_lgpl
	>=gnome-base/libgnomecanvas-2.3.6
	media-libs/sdl-mixer
	media-libs/libsdl
	dev-libs/libxml2
	dev-libs/popt
	virtual/libintl
	games-board/gnuchess
	gnet? ( net-libs/gnet:2 )
	python? (
		dev-lang/python[threads]
		dev-python/pygtk
		sqlite? ( dev-python/pysqlite:2 )
	)
	sqlite? ( dev-db/sqlite:3 )"
DEPEND="${RDEPEND}
	dev-perl/XML-Parser
	sys-devel/gettext
	sys-apps/texinfo
	app-text/texi2html
	dev-util/pkgconfig"
RDEPEND="${RDEPEND}
	media-gfx/tuxpaint
	sci-electronics/gnucap"

src_prepare() {
	epatch "${FILESDIR}"/${P}-build.patch
	cp /usr/share/gettext/config.rpath .
	eautoreconf
}

src_configure() {
	python_version
	GNUCHESS="${GAMES_BINDIR}"/gnuchess \
	egamesconf \
		--disable-dependency-tracking \
		--datarootdir="${GAMES_DATADIR}" \
		--datadir="${GAMES_DATADIR}" \
		--localedir=/usr/share/locale \
		--infodir=/usr/share/info \
		--enable-xf86vidmode \
		$(use_with python python /usr/bin/python${PYVER}) \
		$(use_enable debug) \
		$(use_enable gnet) \
		$(use_enable sqlite)
}

src_compile() {
	emake -j1 || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
	prepgamesdirs
}