[gentoo-commits] gentoo-x86 commit in app-editors/nano: ChangeLog nano-2.0.9.ebuild

[Mike Frysinger (vapier)]

vapier      08/09/07 06:07:33

  Modified:             ChangeLog
  Added:                nano-2.0.9.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc8/cvs/Linux 2.6.26.2 x86_64)

Revision  Changes    Path
1.205                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.205&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.205&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?r1=1.204&r2=1.205

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.204
retrieving revision 1.205
diff -u -r1.204 -r1.205
--- ChangeLog	5 Sep 2008 07:29:36 -0000	1.204
+++ ChangeLog	7 Sep 2008 06:07:32 -0000	1.205
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.204 2008/09/05 07:29:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.205 2008/09/07 06:07:32 vapier Exp $
+
+*nano-2.0.9 (07 Sep 2008)
+
+  07 Sep 2008; Mike Frysinger <vapier@g.o> +nano-2.0.9.ebuild:
+  Version bump.
 
 *nano-2.1.5 (05 Sep 2008)
 



1.1                  app-editors/nano/nano-2.0.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.0.9.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.0.9.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.0.9.ebuild,v 1.1 2008/09/07 06:07:32 vapier Exp $

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ECVS_SERVER="savannah.gnu.org:/cvsroot/nano"
	ECVS_MODULE="nano"
	ECVS_AUTH="pserver"
	ECVS_USER="anonymous"
	inherit cvs
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi
}

src_compile() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir=/bin \
		--enable-color \
		--enable-multibuffer \
		--enable-nanorc \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf} \
		|| die "configure failed"
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml *.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	insinto /usr/share/nano
	doins "${FILESDIR}"/*.nanorc || die
	echo $'\n''# include "/usr/share/nano/gentoo.nanorc"' >> "${D}"/etc/nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano
}

pkg_postinst() {
	elog "More helpful info about nano, visit the GDP page:"
	elog "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}