Re: [OBORONA-SPAM] [gentoo-user-ru] vim

[Alex Efros]

Hi!

On Fri, May 13, 2005 at 07:46:58PM +0400, Ivanov Maxim wrote:
> Есть ли курс молодого бойца по vim? все говорят что жутко удобен, а я
> оттуда только выйти могу =)

Да, знакомая ситуация. Я когда-то себя с трудом заставил-таки с vim
разобраться... и не пожалел! Такая цаца!! :) BTW, я не пытаюсь начать
флейм Vim VS EMACS, я просто говорю что МНЕ нравится Vim, причём весьма! :)

Кстати, раз уж поднялась такая тема, может обменяемся инфой кто чего
интересного в Vim нарыл и настроил себе..? Новичкам тоже полезно будет.

Я использую плагины (вытянутые с vim.org):
    feraltogglecommentify   - (рас)комментирование текста
    foldutil		    - создание fold-ов вручную по regexp
    transvim		    - подключение англ-рус словаря
    vimspell		    - проверка правописания англ/рус
Некоторые плагины патчил сам, патчи авторам практически все отсылал, так
что не знаю, может уже на vim.org версии этих плагинов с моими патчами.
В любом случае, если кому мои патчи понадобятся - я их сюда могу
запостить отдельно.
Ещё весьма любопытный плагин - vimDebug, позволяет сделать из Vim что-то
очень напоминающее DOC-овский TurboDebugger, только для разных языков,
perl, например. :) Но его довести до ума пока руки не дошли.

Ну и самое главное - мой ~/.vimrc:
---cut---
" Summary:
"   * Разные настройки
"   * Проверка правописания
"   * MySQL-ные cловари
"   * За|Рас-комментирование			# <C-c> <M-3>
"   * Переключение между файлами		<Tab>, <S-Tab>
"   * Дописывание слов (INSERT)			<Tab>, <S-Tab>
"   * Сохранение				<F2>
"   * Вкл/Выкл вставку as-is			<F4>
"   * Перекодирование между KOI<->WIN<->DOS	<F6>
"   * Регулярные выражения perl (поиск)		<F7>, <S-F7>
"   * Проверка на ошибки perl-скрипта		<F8>, <F9>
"   * Выход (если файл записан)			<F10>
"   * Подсветка синтаксиса
"   * Подсветка синтаксиса для perl
"   * Почта
"   * Настройка типов файлов для подсветки
"   * Transparent editing of gpg encrypted files
"   * Аббревиатура: вставка даты/времени.
" TODO perldoc для модулей и функций по <F1>
" TODO Проверка правописания:
"	- пофиксить тормоза при вставке большого куска текста
"	- сделать одновременную поддержку и русского и английского
" TODO Выделение текста через Shift+Arrows в NORMAL и INSERT -режимах.
"	- Shift+ArrowLeft / Right	Select text, by character
"	- Shift+ArrowUp / Down		Select text, by line up / down
"	- Shift+Home / End		Select text, to beginning / end of line
"	- Shift+PageUp / PageDown	Select text, to top / bottom of screen
"	- Ctrl+Shift+ArrowLeft / Right	Select text, by word left / right
"	- Ctrl+Shift+ArrowUp / Down	Move to top / bottom of selection
"	- Ctrl+Shift+Home / End		Select text, to beginning / end of document
" TODO Ctrl+Up/Down скроллирование текста без смещения курсора.
" TODO Работа с tags по Alt+Arrows
" TODO Визуальный отладчик через perl -d

"set t_ve=[?25h[?18;240;255c	    " white on black
"set t_ve=[?25h[?18;48;255c	    " white on red
"set t_ve=[?25h[?18;95;255c	    " black on green
"set t_ve=[?25h[?17;95;255c	    " black on green
""" Разные настройки (все переменные комментировать лень, так что - :help)
set nobackup
set shiftwidth=4
set tabstop=8
set softtabstop=4
set nohlsearch
set incsearch
set nowrap
set lcs=eol:$,extends:~
set sidescroll=1
set wildmenu
set langmap=йцукенгшщзхъфывапролджэячсмитьбюЙЦУКЕНГШЩЗХ ФЫВАПРОЛДЖЭЯЧСМИТЬБЮ;qwertyuiop[]asdfghjkl\;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>
set showcmd
set formatoptions=croql
set comments-=:%
" Есть два варианта indent-а: 'filetype' и 'smart', включать можно один из них
" filetype indent on
set smartindent
" Во избежание потенциальных проблем с безопасностью
set modelines=0
" Поиск tags везде где дотянусь!
set tags=tags,./tags,./.tmp/tags,./.lib/.tmp/tags,./../.tmp/tags,./../.lib/.tmp/tags,./../../.lib/.tmp/tags

""" Проверка правописания (нужен PLUGIN vimspell + мои патчи)
"let spell_auto_type = "mail,text,none,note"
let spell_auto_type = "mail"
let spell_executable = "aspell"
let spell_language_list = "english,russian"
let spell_markup_ft = ",html,php,xhtml,dtml,tex,mail,note,"
" эти переменные будут правильно работать только вместе с vimspell-enru.patch !
let spell_russian_iskeyword = "@,48-57,_,192-255,^a-z,^A-Z"
let spell_english_iskeyword = "@,48-57,_,192-255,^192-255"



""" MySQL-ные cловари (нужен PLUGIN transvim + мои патчи)
let g:trv_grep = "asdfDict"
let g:trv_grepOptions = " -t 'English->Russian' -t 'Russian->English' -- "
let g:trv_dictionary = ""



""" Настройка кнопок для plugin/feraltogglecommentify.vim
nmap #		<Plug>FtcTc
vmap #		<Plug>FtcTc
nmap 3	:CC<CR>j
vmap 3	:CC<CR>j
imap 3	<esc>:CC<CR>ji
"nmap <M-#>	:UC<CR>j
"vmap <M-#>	:UC<CR>j
"imap <M-#>	<esc>:UC<CR>ji
imap <C-c>	<esc><Plug>FtcDLAC i



""" Одновременная работа с несколькими файлами (buffer-ы)
set hidden
nnoremap <Tab> :bnext<CR>
nnoremap <S-Tab> :bprevious<CR>



""" Дописывание текущего слова по <Tab> (<Shift>+<Tab> для перебора вариантов
""" в обратном порядке).
function! InsertTabWrapper(direction)
    let col = col('.') - 1
    if !col || getline('.')[col - 1] !~ '\k'
        return "\<tab>"
    elseif "backward" == a:direction
        return "\<c-p>"
    else
        return "\<c-n>"
    endif
endfunction

imap <Esc>[Z <S-Tab>
inoremap <Tab> <c-r>=InsertTabWrapper("backward")<cr>
inoremap <S-Tab> <c-r>=InsertTabWrapper("forward")<cr>



""" Сохранение <F2>
nmap <F2> :w<CR>
vmap <F2> <ESC>:w<CR>
imap <F2> <ESC>:w<CR>i<Right>
cmap <F2> <Esc><Esc>:w<CR>



""" Вкл/Выкл вставку as-is <F4>
set pastetoggle=<F4>



""" Перекодирование файла между русскими кодировками. Кодировки выбираются
""" через меню. Вызов меню по <F6>.
set wcm=<Tab>
menu Encoding.Win->Koi	:%!recode WIN KOI -<CR>
menu Encoding.Koi->Win	:%!recode KOI WIN -<CR>
menu Encoding.Dos->Koi  :%!recode DOS KOI -<CR>
menu Encoding.Koi->Dos	:%!recode KOI DOS -<CR>
menu Encoding.Win->Dos  :%!recode WIN DOS -<CR>
menu Encoding.Dos->Win	:%!recode DOS WIN -<CR>
map <F6> :emenu Encoding.<TAB>



""" Поиск в текущем окне по perl-овскому регулярному выражению.
""" Выражение вводится в виде /regexhere/si или !regexhere! и т.п.
""" В выражении можно использовать $t как сокращение для [^>]*>\s*
""" Для того, чтобы помимо установки курсора на начало совпадения текст
""" совпадения был выделен цветом нужно раскомментировать VIM::DoCommand()
""" и настроить цвет в строке 'hi perlre ...'
""" Для поиска от курсора нажать <F7>. Для повторного поиска <F7><Enter>.
hi perlre ctermbg=white ctermfg=blue
function! PerlSearch()
perl <<EOF
    sub getxy {
	(my $s=substr($_[0],0,$_[1]))=~/.*\n/s;
	(1+($s=~tr/\n//), $_[1]-$+[0])
    }
    sub re_start_end {
	my $buf=join("\n",$curbuf->Get(1..$curbuf->Count()));
	my($y,$x)=$curwin->Cursor();
	$y--; $x++;
	$buf=~/(?:.*\n){$y}.{$x}/g;
	return unless $buf=~/($_[0])/g;
	my ($s,$e)=($-[0],$+[0]-1);
	$e-- if substr($buf,$e,1) eq "\n";
	getxy($buf,$s), getxy($buf,$e)
    }
    $PerlSearch::regex = VIM::Eval('input("=~ ","'."\Q$PerlSearch::regex\E".'")');
  my $t = qr/[^>]*>\s*/;
    return VIM::Msg("No matches found","Error")
	unless my @c = re_start_end(eval 'qr'.$PerlSearch::regex);
    #VIM::DoCommand('match perlre /\%'.$c[0].'l\%'.($c[1]+1).'c\_.*'.
    #				 '\%'.$c[2].'l\%'.($c[3]+2).'c/');
    @PerlSearch::c = @c;
    $curwin->Cursor($c[0],$c[1]);
EOF
endfunction
nnoremap <F7> :call PerlSearch()<cr>

" Передвижение курсора между началом совпадения perl-овского регулярного
" выражения и концом совпадения (Shift+F7)
function! PerlSearchSE()
perl <<EOF
    @PerlSearch::c = @PerlSearch::c[2,3,0,1];
    $curwin->Cursor($PerlSearch::c[0],$PerlSearch::c[1]);
EOF
endfunction
nnoremap <S-F7> :call PerlSearchSE()<cr>



""" Проверка на ошибки perl-скрипта <F9> (все окна vi записываются на диск)
""" Переход к следующей ошибке <F8>
set makeprg=$VIMRUNTIME/tools/efm_perl.pl\ -c\ %\ $*
set errorformat=%f:%l:%m
set autowrite
nnoremap <F9>  :make<cr>
nnoremap <F8> :cnext<cr>



""" Выход (если файл записан) <F10>
nmap <F10>   :qa<CR>
vmap <F10>   <Esc>:qa<CR>
imap <F10>   <Esc>:qa<CR>
cmap <F10>   <Esc><Esc>:qa<CR>



""" Подсветка синтаксиса
hi Normal ctermbg=4 cterm=NONE ctermfg=7
" hi Comment ctermbg=NONE cterm=NONE ctermfg=6
hi Comment ctermbg=0 cterm=NONE ctermfg=6
hi Constant ctermbg=NONE cterm=bold ctermfg=3
hi Special ctermbg=NONE cterm=bold ctermfg=5
hi Identifier ctermbg=NONE cterm=bold ctermfg=2
hi Statement ctermbg=NONE cterm=bold ctermfg=7
hi PreProc ctermbg=0 cterm=bold ctermfg=5
" hi Type
" hi Ignore
" hi Error
" hi Todo
hi NonText ctermbg=NONE cterm=NONE ctermfg=6
hi Underlined cterm=NONE ctermfg=7



""" Подсветка синтаксиса для perl
" кавычки подсвечивать не как строку, а как if, while, ...
let perl_string_as_statement=1		
" подсвечивать имя пакета
let perl_want_scope_in_variables=1	
" @{ $qwe{asd}[123] }
let perl_extended_vars=1		
" метод подсвечивать как обычную функцию, а не как продолжение переменной
hi perlMethod	ctermfg=gray
" ключи хешей подсвечивать как переменные, а не как строки
hi! def link perlVarSimpleMemberName perlIdentifier
" имена пакетов более блеклые
hi perlType ctermfg=darkgreen



""" Почта
" при вводе письма перейти сразу на вторую пустую строку и в режим вставки
au BufRead	      /tmp/mutt*	/^$/|/^$/|set fo=tcrq|startinsert



""" Выбор типа подсветки для 'странных' файлов по имени или первой строчке
au BufNewFile,BufRead *.note		set ft=note
au BufNewFile,BufRead *.txt             set ft=note
au BufNewFile,BufRead *TODO*            set ft=note
au BufNewFile,BufRead *TechSpec*        set ft=note
au BufNewFile,BufRead *BUG*	        set ft=note
au BufNewFile,BufRead *.opera/cache*	set ft=html
au BufNewFile,BufRead *.htmlt           set ft=html
au BufNewFile,BufRead *.html-*          set ft=html
" для *.t можно сразу ставить ft=perl, но для примера все сделано сложнее :-)
au BufNewFile,BufRead *.t               call FTCheck_cf()
fun! FTCheck_cf()
    let line = getline(1)
    if line =~ '/perl'
        set ft=perl
    endif
endfun



" Transparent editing of gpg encrypted files.
" By Wouter Hanegraaff <wouter@××××.net>
" Folding permanence added by me.
augroup encrypted
    au!

    " First make sure nothing is written to ~/.viminfo while editing
    " an encrypted file.
    autocmd BufReadPre,FileReadPre      *.gpg set viminfo=
    " We don't want a swap file, as it writes unencrypted data to disk
    autocmd BufReadPre,FileReadPre      *.gpg set noswapfile
    " Switch to binary mode to read the encrypted file
    autocmd BufReadPre,FileReadPre      *.gpg set bin
    autocmd BufReadPre,FileReadPre      *.gpg let ch_save = &ch|set ch=2
    autocmd BufReadPost,FileReadPost    *.gpg '[,']!gpg --decrypt 2> /dev/null
    " Switch to normal mode for editing
    autocmd BufReadPost,FileReadPost    *.gpg set nobin
    autocmd BufReadPost,FileReadPost    *.gpg let &ch = ch_save|unlet ch_save
    autocmd BufReadPost,FileReadPost    *.gpg execute ":doautocmd BufReadPost " . expand("%:r")

    " Save&Restore folding
    autocmd BufReadPost,FileReadPost	*.gpg loadview
    autocmd BufWritePre,FileWritePre	*.gpg mkview

    " Convert all text to encrypted text before writing
    autocmd BufWritePre,FileWritePre    *.gpg '[,']!gpg --default-recipient-self -ae 2>/dev/null
    " Undo the encryption so we are back in the normal text, directly
    " after the file has been written.
    autocmd BufWritePost,FileWritePost  *.gpg u
    
    autocmd BufWritePost,FileWritePost	*.gpg loadview
augroup END



" Вставлять дату/время.
abbr DATE <c-r>=strftime("%d/%m/%y %H:%M:%S")<CR>
abbr DATEen <Esc>:let lc_time_=v:lc_time<CR>:language time C<CR>i<c-r>=strftime("%a %b %d %X %Z %Y")<CR><Esc>:execute "language time " . lc_time_<CR>:unlet lc_time_<CR>a
func Eatchar(pat)
    let c = nr2char(getchar())
    return (c =~ a:pat) ? '' : c
endfunc
au BufNewFile,BufRead *.html               call HTML_Abbr()
fun! HTML_Abbr()
    iabbr <buffer> <A    <A HREF=""></A><Left><Left><Left><Left><Left><Left><C-R>=Eatchar('\s')<CR>
endfun

""" Пример определения шаблона для нового файла
" au BufNewFile	      *.pl		0r ~/.skeleton.pl



"   эти настройки нужны для того, чтобы работало быстрое открывание
"   perl-модулей при нажатии чего-то на строке типа 'use POWER::lib;'
"   но это должно делаться как-то автоматом, может через filetype indent on ?

" include=\<\(use|require\)\s*
" includeexpr=substitute(substitute(v:fname,'::','/','g'),'$','.pm','')
" iskeyword=48-57,_,A-Z,a-z,:
" define=[^A-Za-z_]


" Пример использования perl:
" 
" First, a customizable word count
" :perl $count = 0
" :perldo $count += split /[;_<> ]/, $_ 
" :perl VIM::Msg($count)
" 
" Then, a special sorting routine, getting text from the editor's current
" buffer and writing back to it:
" :perl @lines = sort {$a <=> $b} $curbuf->Get(1 .. 15)
" :perl $curbuf->Set(1, @lines)
"
" Or, in short,
" :perl $curbuf->Set(1, sort {$a <=> $b} $curbuf->Get(1 .. 15))


" сворачивать perl-процедуры (подглюкивает на моих клозурах)
" let perl_fold=1
---cut---

Упоминающаяся в .vimrc прога "asdfDict" это мой скрипт для поиска слов в
агнл/рус базе MySQL, могу запостить если кому любопытно, но transvim
рассчитан на работу с любыми словарями - хоть через grep - RTFM, в общем.

-- 
			WBR, Alex.

-- 
gentoo-user-ru@g.o mailing list