From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: net-libs/pjproject/
Date: Tue, 29 Apr 2025 19:05:00 +0000 (UTC) [thread overview]
Message-ID: <1745953367.1e0a5ae70d5a1995b7761f946c0ac0f95e64d3b5.sam@gentoo> (raw)
commit: 1e0a5ae70d5a1995b7761f946c0ac0f95e64d3b5
Author: Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Tue Apr 29 18:34:45 2025 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Apr 29 19:02:47 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e0a5ae7
net-libs/pjproject: unvendor libyuv
Dropped keywords ppc, ppc64, sparc
Bug: https://bugs.gentoo.org/955077
Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/41849
Signed-off-by: Sam James <sam <AT> gentoo.org>
net-libs/pjproject/pjproject-2.15.1-r1.ebuild | 133 ++++++++++++++++++++++++++
1 file changed, 133 insertions(+)
diff --git a/net-libs/pjproject/pjproject-2.15.1-r1.ebuild b/net-libs/pjproject/pjproject-2.15.1-r1.ebuild
new file mode 100644
index 000000000000..2e43c11664de
--- /dev/null
+++ b/net-libs/pjproject/pjproject-2.15.1-r1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+# TODO: Figure out a way to disable SRTP from pjproject entirely.
+EAPI=8
+
+inherit autotools flag-o-matic toolchain-funcs
+
+DESCRIPTION="Open source SIP, Media, and NAT Traversal Library"
+HOMEPAGE="https://github.com/pjsip/pjproject https://www.pjsip.org/"
+SRC_URI="https://github.com/pjsip/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+# g729 not included due to special bcg729 handling.
+CODEC_FLAGS="g711 g722 g7221 gsm ilbc speex l16"
+VIDEO_FLAGS="sdl ffmpeg v4l2 openh264 libyuv vpx"
+SOUND_FLAGS="alsa portaudio"
+IUSE="amr debug epoll examples opus resample silk srtp ssl static-libs webrtc
+ ${CODEC_FLAGS} g729
+ ${VIDEO_FLAGS}
+ ${SOUND_FLAGS}"
+
+RDEPEND="
+ alsa? ( media-libs/alsa-lib )
+ amr? ( media-libs/opencore-amr )
+ ffmpeg? ( media-video/ffmpeg:= )
+ g729? ( media-libs/bcg729 )
+ gsm? ( media-sound/gsm )
+ ilbc? ( media-libs/libilbc )
+ libyuv? ( media-libs/libyuv:= )
+ openh264? ( media-libs/openh264 )
+ opus? ( media-libs/opus )
+ portaudio? ( media-libs/portaudio )
+ resample? ( media-libs/libsamplerate )
+ sdl? ( media-libs/libsdl2 )
+ speex? (
+ media-libs/speex
+ media-libs/speexdsp
+ )
+ srtp? ( >=net-libs/libsrtp-2.3.0:= )
+ ssl? ( dev-libs/openssl:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+ default
+ rm configure || die "Unable to remove unwanted wrapper"
+ mv aconfigure.ac configure.ac || die "Unable to rename configure script source"
+ eautoreconf
+
+ cp "${FILESDIR}/pjproject-2.13.1-r1-config_site.h" "${S}/pjlib/include/pj/config_site.h" \
+ || die "Unable to create config_site.h"
+}
+
+_pj_enable() {
+ usex "$1" '' "--disable-${2:-$1}"
+}
+
+_pj_get_define() {
+ local r="$(sed -nre "s/^#define[[:space:]]+$1[[:space:]]+//p" "${S}/pjlib/include/pj/config_site.h")"
+ [[ -z "${r}" ]] && die "Unable to fine #define $1 in config_site.h"
+ echo "$r"
+}
+
+_pj_set_define() {
+ local c=$(_pj_get_define "$1")
+ [[ "$c" = "$2" ]] && return 0
+ sed -re "s/^#define[[:space:]]+$1[[:space:]].*/#define $1 $2/" -i "${S}/pjlib/include/pj/config_site.h" \
+ || die "sed failed updating $1 to $2."
+ [[ "$(_pj_get_define "$1")" != "$2" ]] && die "sed failed to perform update for $1 to $2."
+}
+
+_pj_use_set_define() {
+ _pj_set_define "$2" $(usex "$1" 1 0)
+}
+
+src_configure() {
+ local myconf=()
+ local videnable="--disable-video"
+ local t
+
+ use debug || append-cflags -DNDEBUG=1
+
+ for t in ${CODEC_FLAGS}; do
+ myconf+=( $(_pj_enable ${t} ${t}-codec) )
+ done
+ myconf+=( $(_pj_enable g729 bcg729) )
+
+ for t in ${VIDEO_FLAGS}; do
+ myconf+=( $(_pj_enable ${t}) )
+ use "${t}" && videnable="--enable-video"
+ done
+
+ [ "${videnable}" = "--enable-video" ] && _pj_set_define PJMEDIA_HAS_VIDEO 1 || _pj_set_define PJMEDIA_HAS_VIDEO 0
+
+ LD="$(tc-getCXX)" econf \
+ --enable-shared \
+ ${videnable} \
+ $(_pj_enable alsa sound) \
+ $(_pj_enable amr opencore-amr) \
+ $(_pj_enable epoll) \
+ $(_pj_enable opus) \
+ $(_pj_enable portaudio ext-sound) \
+ $(_pj_enable resample libsamplerate) \
+ $(_pj_enable resample resample-dll) \
+ $(_pj_enable resample) \
+ $(_pj_enable silk) \
+ $(_pj_enable speex speex-aec) \
+ $(_pj_enable ssl) \
+ $(_pj_enable webrtc libwebrtc) \
+ $(use_with gsm external-gsm) \
+ $(use_with portaudio external-pa) \
+ $(use_with speex external-speex) \
+ $(usex srtp --with-external-srtp --disable-libsrtp) \
+ --with-external-yuv \
+ "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ newbin pjsip-apps/bin/pjsua-${CHOST} pjsua
+ newbin pjsip-apps/bin/pjsystest-${CHOST} pjsystest
+
+ if use examples; then
+ insinto "/usr/share/doc/${PF}/examples"
+ doins -r pjsip-apps/src/samples
+ fi
+
+ use static-libs || rm "${ED}/usr/$(get_libdir)"/*.a || die "Error removing static archives"
+}
next reply other threads:[~2025-04-29 19:05 UTC|newest]
Thread overview: 54+ messages / expand[flat|nested] mbox.gz Atom feed top
2025-04-29 19:05 Sam James [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-05-01 1:26 [gentoo-commits] repo/gentoo:master commit in: net-libs/pjproject/ Sam James
2025-04-29 19:05 Sam James
2025-04-29 19:05 Sam James
2025-04-28 6:02 Sam James
2025-01-21 13:13 Joonas Niilola
2025-01-21 13:13 Joonas Niilola
2024-09-17 16:00 Sam James
2024-09-17 16:00 Sam James
2024-01-12 8:30 Arthur Zamarin
2023-11-22 7:20 Joonas Niilola
2023-11-22 7:20 Joonas Niilola
2023-05-18 5:07 John Helmert III
2023-05-18 5:00 John Helmert III
2023-05-18 5:00 John Helmert III
2023-05-16 6:16 Joonas Niilola
2023-05-10 9:40 Sam James
2023-04-20 21:52 Sam James
2023-04-20 21:52 Sam James
2022-12-13 5:27 Sam James
2022-12-13 5:27 Sam James
2022-10-30 2:58 John Helmert III
2022-10-27 8:00 Joonas Niilola
2022-10-25 17:55 Sam James
2022-08-19 3:46 Sam James
2022-08-04 6:37 Joonas Niilola
2022-06-15 13:32 Joonas Niilola
2021-07-24 7:58 Agostino Sarubbo
2021-07-24 7:57 Agostino Sarubbo
2021-05-02 10:56 Mikle Kolyada
2021-03-15 19:20 John Helmert III
2021-03-14 1:29 Sam James
2021-03-12 18:32 Sam James
2021-02-19 16:14 Sam James
2021-02-12 14:15 Sam James
2020-12-29 20:45 Sam James
2020-10-06 21:45 Sam James
2020-09-12 1:49 Sam James
2020-07-20 12:24 Sam James
2020-07-20 9:01 Joonas Niilola
2020-07-16 17:45 Sam James
2020-05-06 6:48 Sergei Trofimovich
2020-04-26 11:00 David Seifert
2020-04-14 12:32 Agostino Sarubbo
2020-03-31 8:25 Mikle Kolyada
2020-01-08 17:54 Joonas Niilola
2019-11-30 7:50 Joonas Niilola
2019-03-18 22:53 Patrice Clement
2018-10-06 18:40 Sergei Trofimovich
2018-10-06 18:40 Sergei Trofimovich
2018-08-31 17:13 Tony Vroon
2018-03-12 10:51 Agostino Sarubbo
2018-02-07 9:17 Tony Vroon
2017-09-18 23:43 Tony Vroon
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1745953367.1e0a5ae70d5a1995b7761f946c0ac0f95e64d3b5.sam@gentoo \
--to=sam@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox