[gentoo-commits] gentoo-x86 commit in sys-cluster/ceph: metadata.xml ChangeLog ceph-0.23.1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-cluster/ceph: metadata.xml ChangeLog ceph-0.23.1.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      10/12/07 18:25:28

  Added:                metadata.xml ChangeLog ceph-0.23.1.ebuild
  Log:
  [sys-cluster/ceph] Initial import per bug #338008
  
  (Portage version: 2.2.0_alpha7_p1/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-cluster/ceph/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>cluster</herd>
<longdescription>
Ceph is a distributed network file system designed to provide excellent performance, reliability, and scalability.
</longdescription>
<use>
	<flag name='fuse'>Build fuse client</flag>
	<flag name='libatomic'>Use libatomic instead of builtin atomic operations</flag>
	<flag name='radosgw'>Add radosgw support</flag>
</use>
</pkgmetadata>



1.1                  sys-cluster/ceph/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/ceph
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ChangeLog,v 1.1 2010/12/07 18:25:28 alexxy Exp $

*ceph-0.23.1 (07 Dec 2010)

  07 Dec 2010; Alexey Shvetsov <alexxy@gentoo.org> +ceph-0.23.1.ebuild,
  +files/ceph.confd, +files/ceph.initd, +metadata.xml:
  Initial import per bug #338008




1.1                  sys-cluster/ceph/ceph-0.23.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-0.23.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/ceph/ceph-0.23.1.ebuild?rev=1.1&content-type=text/plain

Index: ceph-0.23.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/ceph/ceph-0.23.1.ebuild,v 1.1 2010/12/07 18:25:28 alexxy Exp $

EAPI="3"

inherit autotools eutils multilib

DESCRIPTION="Ceph distributed filesystem"
HOMEPAGE="http://ceph.newdream.net/"
SRC_URI="http://ceph.newdream.net/download/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug fuse libatomic radosgw static-libs"

CDEPEND="dev-libs/boost
	dev-libs/libedit
	dev-libs/openssl
	libatomic? ( dev-libs/libatomic_ops )
	fuse? ( sys-fs/fuse )
	radosgw? ( dev-libs/fcgi dev-libs/expat )"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"
RDEPEND="${CDEPEND}
	sys-fs/btrfs-progs"

src_prepare() {
	sed -e 's:invoke-rc\.d.*:/etc/init.d/ceph reload >/dev/null:' \
		-i src/logrotate.conf || die
	sed -i "/^docdir =/d" src/Makefile.am || die #fix doc path
	eautoreconf
}

src_configure() {
	econf \
		--without-hadoop \
		--docdir=/usr/share/doc/${PF} \
		$(use_with debug) \
		$(use_with fuse) \
		$(use_with libatomic libatomic-ops) \
		$(use_with radosgw) \
		$(use_enable static-libs static)
}

src_install() {
	emake DESTDIR="${D}" install || die
	find "${D}" -type f -name "*.la" -exec rm -f {} \;

	rmdir "${D}/usr/sbin"

	exeinto /usr/$(get_libdir)/ceph || die
	newexe src/init-ceph ceph_init.sh || die

	insinto /etc/logrotate.d/ || die
	newins src/logrotate.conf ${PN} || die

	chmod 644 "${D}"/usr/share/doc/${PF}/sample.* || die

	keepdir /var/lib/${PN} || die
	keepdir /var/lib/${PN}/tmp || die
	keepdir /var/log/${PN}/stat || die
	keepdir /var/run/${PN} || die

	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die
	newconfd "${FILESDIR}/${PN}.confd" ${PN} || die
}