[gentoo-commits] gentoo-x86 commit in sys-apps/hwids: hwids-20150107.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/hwids: hwids-20150107.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    15/01/07 20:11:04

  Modified:             ChangeLog
  Added:                hwids-20150107.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 1CD13C8AD4301342)

Revision  Changes    Path
1.157                sys-apps/hwids/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?rev=1.157&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?rev=1.157&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?r1=1.156&r2=1.157

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v
retrieving revision 1.156
retrieving revision 1.157
diff -u -r1.156 -r1.157
--- ChangeLog	14 Dec 2014 05:17:21 -0000	1.156
+++ ChangeLog	7 Jan 2015 20:11:04 -0000	1.157
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/hwids
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v 1.156 2014/12/14 05:17:21 floppym Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v 1.157 2015/01/07 20:11:04 flameeyes Exp $
+
+*hwids-20150107 (07 Jan 2015)
+
+  07 Jan 2015; Diego E. Pettenò <flameeyes@gentoo.org> +hwids-20150107.ebuild:
+  Version bump.
 
 *hwids-20141214 (14 Dec 2014)
 



1.1                  sys-apps/hwids/hwids-20150107.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-20150107.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-20150107.ebuild?rev=1.1&content-type=text/plain

Index: hwids-20150107.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/hwids-20150107.ebuild,v 1.1 2015/01/07 20:11:04 flameeyes Exp $

EAPI=5
inherit udev eutils

DESCRIPTION="Hardware (PCI, USB, OUI, IAB) IDs databases"
HOMEPAGE="https://github.com/gentoo/hwids"
if [[ ${PV} == "99999999" ]]; then
	EGIT_REPO_URI="${HOMEPAGE}.git"
	inherit git-2
else
	SRC_URI="${HOMEPAGE}/archive/${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~arm-linux ~x86-linux"
fi

LICENSE="|| ( GPL-2 BSD ) public-domain"
SLOT="0"
IUSE="+net +pci +udev +usb"

DEPEND="udev? (
	dev-lang/perl
	>=virtual/udev-206
)"
[[ ${PV} == "99999999" ]] && DEPEND+=" udev? ( net-misc/curl )"
RDEPEND="!<sys-apps/pciutils-3.1.9-r2
	!<sys-apps/usbutils-005-r1"

S=${WORKDIR}/hwids-${P}

src_prepare() {
	[[ ${PV} == "99999999" ]] && emake fetch

	sed -i -e '/udevadm hwdb/d' Makefile || die
}

_emake() {
	emake \
		NET=$(usex net) \
		PCI=$(usex pci) \
		UDEV=$(usex udev) \
		USB=$(usex usb) \
		"$@"
}

src_compile() {
	_emake
}

src_install() {
	_emake install \
		DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
		MISCDIR="${EPREFIX}/usr/share/misc" \
		HWDBDIR="${EPREFIX}$(get_udevdir)/hwdb.d" \
		DESTDIR="${D}"
}

pkg_postinst() {
	if use udev; then
		udevadm hwdb --update --root="${ROOT%/}"
		# http://cgit.freedesktop.org/systemd/systemd/commit/?id=1fab57c209035f7e66198343074e9cee06718bda
		[ "${ROOT:-/}" = "/" ] && udevadm control --reload
	fi
}