[gentoo-commits] gentoo-x86 commit in kde-misc/kanyremote: kanyremote-6.3.5.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in kde-misc/kanyremote: kanyremote-6.3.5.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    15/03/04 10:25:51

  Modified:             ChangeLog
  Added:                kanyremote-6.3.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.50                 kde-misc/kanyremote/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-misc/kanyremote/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-misc/kanyremote/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-misc/kanyremote/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-misc/kanyremote/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	4 Mar 2015 10:23:15 -0000	1.49
+++ ChangeLog	4 Mar 2015 10:25:51 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for kde-misc/kanyremote
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-misc/kanyremote/ChangeLog,v 1.49 2015/03/04 10:23:15 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/kanyremote/ChangeLog,v 1.50 2015/03/04 10:25:51 kensington Exp $
+
+*kanyremote-6.3.5 (04 Mar 2015)
+
+  04 Mar 2015; Michael Palimaka <kensington@gentoo.org>
+  +kanyremote-6.3.5.ebuild:
+  Version bump.
 
   04 Mar 2015; Michael Palimaka <kensington@gentoo.org> metadata.xml:
   Add upstream metadata.



1.1                  kde-misc/kanyremote/kanyremote-6.3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-misc/kanyremote/kanyremote-6.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-misc/kanyremote/kanyremote-6.3.5.ebuild?rev=1.1&content-type=text/plain

Index: kanyremote-6.3.5.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-misc/kanyremote/kanyremote-6.3.5.ebuild,v 1.1 2015/03/04 10:25:51 kensington Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
inherit autotools python-r1

DESCRIPTION="KDE frontend to Anyremote"
HOMEPAGE="http://anyremote.sourceforge.net/"
SRC_URI="mirror://sourceforge/anyremote/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~amd64 ~x86"
IUSE="bluetooth"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}
	>=app-mobilephone/anyremote-6.5[bluetooth?]
	dev-python/PyQt4[X,${PYTHON_USEDEP}]
	kde-base/pykde4:4[${PYTHON_USEDEP}]
	bluetooth? ( dev-python/pybluez[${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}
	sys-devel/gettext
"

src_prepare() {
	# using gettextize no-interactive example from dev-util/bless package
	cp $(type -p gettextize) "${T}"/ || die
	sed -i -e 's:read dummy < /dev/tty::' "${T}/gettextize" || die
	"${T}"/gettextize -f --no-changelog > /dev/null || die

	# remove deprecated entry
	sed -e "/Encoding=UTF-8/d" \
		-i kanyremote.desktop || die "fixing .desktop file failed"

	# fix documentation directory wrt bug #316087
	sed -i "s/doc\/${PN}/doc\/${PF}/g" Makefile.am || die
	eautoreconf

	# disable bluetooth check to avoid errors
	if ! use bluetooth ; then
		sed -e "s/usepybluez    = True/usepybluez    = False/" -i kanyremote || die
	fi
}

src_install() {
	default

	python_replicate_script "${D}"/usr/bin/kanyremote
}