[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0.2.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.7.0.2.ebuild

[Alex Alexander (wired)]

wired       10/02/06 12:46:18

  Modified:             ChangeLog
  Added:                mc-4.7.0.2.ebuild
  Log:
  [app-misc/mc] version bump to 4.7.0.2
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.185                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.185&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.185&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?r1=1.184&r2=1.185

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.184
retrieving revision 1.185
diff -u -r1.184 -r1.185
--- ChangeLog	4 Feb 2010 21:18:45 -0000	1.184
+++ ChangeLog	6 Feb 2010 12:46:18 -0000	1.185
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.184 2010/02/04 21:18:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.185 2010/02/06 12:46:18 wired Exp $
+
+*mc-4.7.0.2 (06 Feb 2010)
+
+  06 Feb 2010; Alex Alexander <wired@gentoo.org> +mc-4.7.0.2.ebuild:
+  [app-misc/mc] version bump to 4.7.0.2
 
   04 Feb 2010; Jeroen Roovers <jer@gentoo.org> mc-4.7.0.1.ebuild:
   Stable for HPPA (bug #302733).



1.1                  app-misc/mc/mc-4.7.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.2.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.0.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0.2.ebuild,v 1.1 2010/02/06 12:46:18 wired Exp $

EAPI=2
MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="+edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_with samba) \
		--with-configdir=/etc/samba \
		--with-codepagedir=/var/lib/samba/codepages \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". /usr/libexec/mc/mc.sh"
}