[gentoo-commits] gentoo-x86 commit in mail-client/balsa: balsa-2.4.14.ebuild ChangeLog balsa-2.4.12.ebuild

[Pacho Ramos (pacho)]

pacho       14/06/22 15:42:14

  Modified:             ChangeLog
  Added:                balsa-2.4.14.ebuild
  Removed:              balsa-2.4.12.ebuild
  Log:
  Version bump, drop support for gtkhtml slot that is unmaintained for ages and will be removed soon, drop old.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.127                mail-client/balsa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/balsa/ChangeLog?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/balsa/ChangeLog?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/balsa/ChangeLog?r1=1.126&r2=1.127

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- ChangeLog	1 Apr 2013 18:24:59 -0000	1.126
+++ ChangeLog	22 Jun 2014 15:42:14 -0000	1.127
@@ -1,6 +1,13 @@
 # ChangeLog for mail-client/balsa
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.126 2013/04/01 18:24:59 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.127 2014/06/22 15:42:14 pacho Exp $
+
+*balsa-2.4.14 (22 Jun 2014)
+
+  22 Jun 2014; Pacho Ramos <pacho@g.o> +balsa-2.4.14.ebuild,
+  -balsa-2.4.12.ebuild:
+  Version bump, drop support for gtkhtml slot that is unmaintained for ages and
+  will be removed soon, drop old.
 
   01 Apr 2013; Agostino Sarubbo <ago@g.o> balsa-2.4.13.ebuild:
   Stable for sparc, wrt bug #458984



1.1                  mail-client/balsa/balsa-2.4.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/balsa/balsa-2.4.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/balsa/balsa-2.4.14.ebuild?rev=1.1&content-type=text/plain

Index: balsa-2.4.14.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.4.14.ebuild,v 1.1 2014/06/22 15:42:14 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit eutils gnome2

DESCRIPTION="Email client for GNOME"
HOMEPAGE="http://pawsa.fedorapeople.org/balsa/"
SRC_URI="http://pawsa.fedorapeople.org/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
# Doesn't currently build with -gnome
IUSE="crypt gnome +gtkspell kerberos ldap libnotify networkmanager rubrica sqlite ssl webkit xface"

# TODO: esmtp can be optional
RDEPEND="
	>=dev-libs/glib-2.16:2
	>=x11-libs/gtk+-2.18:2
	dev-libs/gmime:2.6
	dev-libs/libunique:1
	>=net-libs/libesmtp-1.0.3:=
	net-mail/mailbase
	media-libs/libcanberra:=[gtk]
	x11-themes/hicolor-icon-theme
	crypt? ( >=app-crypt/gpgme-1.0:= )
	gnome? (
		>=gnome-base/orbit-2
		>=gnome-base/libbonobo-2.0
		>=gnome-base/libgnome-2.0
		>=gnome-base/libgnomeui-2.0
		>=gnome-base/gconf-2.0:2
		>=gnome-base/gnome-keyring-2.20
		>=x11-libs/gtksourceview-2.10:2.0 )
	sqlite? ( >=dev-db/sqlite-2.8:= )
	libnotify? ( >=x11-libs/libnotify-0.7:= )
	gtkspell? (
		app-text/gtkspell:2
		app-text/enchant )
	!gtkspell? ( app-text/aspell )
	kerberos? ( app-crypt/mit-krb5 )
	ldap? ( net-nds/openldap )
	networkmanager? ( >=net-misc/networkmanager-0.7 )
	rubrica? ( dev-libs/libxml2:2 )
	ssl? ( dev-libs/openssl:= )
	webkit? ( >=net-libs/webkit-gtk-1.5.1:2 )
	xface? ( >=media-libs/compface-1.5.1:= )
"
DEPEND="${RDEPEND}
	dev-util/intltool
	virtual/pkgconfig
	sys-devel/gettext
	>=app-text/scrollkeeper-0.1.4
	app-text/gnome-doc-utils
"

src_prepare() {
	# Fix documentation
	epatch "${FILESDIR}/${PN}-2.4.11-doc-fixes.patch"
	gnome2_src_prepare
}

src_configure() {
	local myconf
	DOCS="AUTHORS ChangeLog HACKING NEWS README TODO docs/*"

	if use crypt ; then
		myconf+=" --with-gpgme=gpgme-config"
	else
		myconf+=" --without-gpgme"
	fi

	if use webkit; then
		myconf+=" --with-html-widget=webkit"
	else
		myconf+=" --with-html-widget=no"
	fi

	gnome2_src_configure \
		--disable-pcre \
		--enable-gregex \
		--enable-threads \
		--with-gmime=2.6 \
		--with-unique \
		--with-canberra \
		$(use_with gnome) \
		$(use_with gnome gtksourceview) \
		$(use_with gtkspell) \
		$(use_with kerberos gss) \
		$(use_with ldap) \
		$(use_with libnotify) \
		$(use_with networkmanager nm) \
		$(use_with rubrica) \
		$(use_with sqlite) \
		$(use_with ssl) \
		$(use_with xface compface) \
		${myconf}
}