[gentoo-commits] gentoo-x86 commit in media-libs/libechonest: libechonest-2.3.0.ebuild ChangeLog

[Johannes Huber (johu)]

johu        15/01/29 22:10:39

  Modified:             ChangeLog
  Added:                libechonest-2.3.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.31                 media-libs/libechonest/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libechonest/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libechonest/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libechonest/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libechonest/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	8 Apr 2014 16:19:15 -0000	1.30
+++ ChangeLog	29 Jan 2015 22:10:39 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libechonest
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libechonest/ChangeLog,v 1.30 2014/04/08 16:19:15 ssuominen Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libechonest/ChangeLog,v 1.31 2015/01/29 22:10:39 johu Exp $
+
+*libechonest-2.3.0 (29 Jan 2015)
+
+  29 Jan 2015; Johannes Huber <johu@g.o> +libechonest-2.3.0.ebuild:
+  Version bump.
 
   08 Apr 2014; Samuli Suominen <ssuominen@g.o>
   libechonest-2.2.0-r1.ebuild:



1.1                  media-libs/libechonest/libechonest-2.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libechonest/libechonest-2.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libechonest/libechonest-2.3.0.ebuild?rev=1.1&content-type=text/plain

Index: libechonest-2.3.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libechonest/libechonest-2.3.0.ebuild,v 1.1 2015/01/29 22:10:39 johu Exp $

EAPI=5
inherit cmake-utils multibuild

DESCRIPTION="A library for communicating with The Echo Nest"
HOMEPAGE="http://projects.kde.org/projects/playground/libs/libechonest"
SRC_URI="http://files.lfranchi.com/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0/2.3"
KEYWORDS="~amd64 ~x86"
IUSE="+qt4 qt5"

RESTRICT="test" # Networking required

RDEPEND="
	qt4? (
		dev-libs/qjson[qt4(+)]
		dev-qt/qtcore:4
	)
	qt5? (
		dev-qt/qtcore:5
		dev-qt/qtnetwork:5
	)
"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( AUTHORS README TODO )

pkg_setup() {
	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
}

src_configure() {
	myconfigure() {
		local mycmakeargs=(
			-DECHONEST_BUILD_TESTS=OFF
		)

		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
			mycmakeargs+=(-DBUILD_WITH_QT4=ON)
		fi

		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
			mycmakeargs+=(-DBUILD_WITH_QT4=OFF)
		fi

		cmake-utils_src_configure
	}

	multibuild_foreach_variant myconfigure
}

src_compile() {
	multibuild_foreach_variant cmake-utils_src_compile
}

src_test() {
	multibuild_foreach_variant cmake-utils_src_test
}

src_install() {
	multibuild_foreach_variant cmake-utils_src_install
}