[gentoo-commits] gentoo-x86 commit in xfce-base/xfce4-session: xfce4-session-4.11.0-r2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/07/08 13:58:39

  Modified:             ChangeLog
  Added:                xfce4-session-4.11.0-r2.ebuild
  Log:
  Use updated UPower 0.99.0 patch from http://bugzilla.xfce.org/show_bug.cgi?id=9952#c20
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.215                xfce-base/xfce4-session/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?rev=1.215&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?rev=1.215&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog	29 Jun 2014 18:58:12 -0000	1.214
+++ ChangeLog	8 Jul 2014 13:58:39 -0000	1.215
@@ -1,6 +1,14 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.214 2014/06/29 18:58:12 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.215 2014/07/08 13:58:39 ssuominen Exp $
+
+*xfce4-session-4.11.0-r2 (08 Jul 2014)
+
+  08 Jul 2014; Samuli Suominen <ssuominen@g.o>
+  +files/xfce4-session-4.11.0-upower-0.99.0.patch,
+  +xfce4-session-4.11.0-r2.ebuild:
+  Use updated UPower 0.99.0 patch from
+  http://bugzilla.xfce.org/show_bug.cgi?id=9952#c20
 
   29 Jun 2014; Markus Meier <maekke@g.o> xfce4-session-4.10.1-r2.ebuild:
   arm stable, bug #513930



1.1                  xfce-base/xfce4-session/xfce4-session-4.11.0-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.11.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.11.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: xfce4-session-4.11.0-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.11.0-r2.ebuild,v 1.1 2014/07/08 13:58:39 ssuominen Exp $

EAPI=5
EAUTORECONF=1
inherit xfconf

DESCRIPTION="A session manager for the Xfce desktop environment"
HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="debug nls systemd udev +xscreensaver"

COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
	x11-apps/iceauth
	x11-libs/libSM
	>=x11-libs/libwnck-2.30:1
	x11-libs/libX11
	>=xfce-base/libxfce4util-4.11
	>=xfce-base/libxfce4ui-4.11
	>=xfce-base/xfconf-4.10
	!xfce-base/xfce-utils
	udev? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )
	systemd? ( >=sys-auth/polkit-0.100 )"
RDEPEND="${COMMON_DEPEND}
	x11-apps/xrdb
	nls? ( x11-misc/xdg-user-dirs )
	!systemd? ( udev? ( sys-power/pm-utils ) )
	xscreensaver? ( || (
		>=x11-misc/xscreensaver-5.26
		gnome-extra/gnome-screensaver
		>=x11-misc/xlockmore-5.43
		x11-misc/slock
		x11-misc/alock[pam]
		) )"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	sys-devel/gettext
	virtual/pkgconfig"

pkg_setup() {
	PATCHES=(
		"${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch
		"${FILESDIR}"/${P}-upower-0.99.0.patch
		)

	XFCONF=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
		$(use_enable udev upower)
		$(use_enable systemd)
		--with-xsession-prefix="${EPREFIX}"/usr
		$(xfconf_use_debug)
		)

	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
}

src_install() {
	xfconf_src_install

	local sessiondir=/etc/X11/Sessions
	echo startxfce4 > "${T}"/Xfce4
	exeinto ${sessiondir}
	doexe "${T}"/Xfce4
	dosym Xfce4 ${sessiondir}/Xfce
}