[gentoo-commits] repo/gentoo:master commit in: dev-python/httpx/

[Michał Górny]

commit:     ff774e220c82206ecbb983a94b90eae01d705d40
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 19 21:44:49 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 19 21:53:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff774e22

dev-python/httpx: Bump to 0.19.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/httpx/Manifest            |  1 +
 dev-python/httpx/httpx-0.19.0.ebuild | 59 ++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 31ae52b9c22..fb87c3c7508 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
 DIST httpx-0.18.2.tar.gz 1666756 BLAKE2B 3d1e25d503ae5306150c157bc83afdac9a475110d042e041b58de448a0dcfd75de3f4c15836b838dc799cd5f8b7e0d646e43bbe107ffad87d51ff016afe585cd SHA512 727974e5d5924fdd653987dd4f528d27bb2653085b01ef5efcdac39dc92ef2ed586f872c202349aa31105ad970cff914de4315c2d79338a6aa18bebb8126f392
+DIST httpx-0.19.0.tar.gz 1667455 BLAKE2B b8d4cb0b6e7f643b62b507930ccf1534d73d93261cab9281ef57d6392f00da325e897d5339aebacfa07aeae8278d3a81b78d6501a1587ffeaef68cc5087bfdaa SHA512 3b327f07d62cf0430672d4f1a4f884618e588496f049522de327f5c34f7260eb21739b7f1fbd6f43a21962bc8737547f3eddbc22751546647f56c9cd7212840a

diff --git a/dev-python/httpx/httpx-0.19.0.ebuild b/dev-python/httpx/httpx-0.19.0.ebuild
new file mode 100644
index 00000000000..72dc4fb1f17
--- /dev/null
+++ b/dev-python/httpx/httpx-0.19.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Docs builder mkdocs not keyworded on all these arches yet
+# DOCS_BUILDER="mkdocs"
+# DOCS_DEPEND="dev-python/mkdocs-material"
+# DOCS_AUTODOC=1
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 # docs
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="https://www.python-httpx.org/"
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/charset_normalizer[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	=dev-python/httpcore-0.13*[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.3[${PYTHON_USEDEP}]
+	<dev-python/rfc3986-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/hyper-h2[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# trio does not support py3.10
+	sed -i '/^import trio/d' tests/concurrency.py || die
+	sed -i '/pytest.param("trio", marks=pytest.mark.trio)/d' tests/conftest.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# Internet
+		tests/client/test_proxies.py::test_async_proxy_close
+		tests/client/test_proxies.py::test_sync_proxy_close
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}