[gentoo-commits] repo/gentoo:master commit in: mate-extra/mate-screensaver/

[Adam Feldman]

commit:     4d2804f0e3191d55fb47db733cbcd24eb627dc86
Author:     Adam Feldman <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 10 13:54:50 2021 +0000
Commit:     Adam Feldman <np-hardass <AT> gentoo <DOT> org>
CommitDate: Wed Jun 30 22:41:47 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d2804f0

mate-extra/mate-screensaver: Bump to 1.24.2

Bug: https://bugs.gentoo.org/778857
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Adam Feldman <NP-Hardass <AT> gentoo.org>

 mate-extra/mate-screensaver/Manifest               |   1 +
 .../mate-screensaver-1.24.2.ebuild                 | 120 +++++++++++++++++++++
 2 files changed, 121 insertions(+)

diff --git a/mate-extra/mate-screensaver/Manifest b/mate-extra/mate-screensaver/Manifest
index 218079a06cb..f395785c894 100644
--- a/mate-extra/mate-screensaver/Manifest
+++ b/mate-extra/mate-screensaver/Manifest
@@ -1 +1,2 @@
 DIST mate-screensaver-1.24.1.tar.xz 5073836 BLAKE2B 501c8dffbb5e53b88414c799a6e4d25cf89dfe490e6a902901c339b142e2b687dc2e668f65349a2ff43b6eb44d7721658de771b1a698624f95d1828da2fbda67 SHA512 f7cab280da90623ad265beb84770e48431ae6685fbb1eabc7cd2ad07b0f8ed5da2426017243d83271b969d2e020b8afcc93a6135b4c8e42a29f454a4e826b277
+DIST mate-screensaver-1.24.2.tar.xz 5099224 BLAKE2B aec1d95ba23f983d592e93ef97ed446b3fb05888d3ad99cf366476b84bf4feff59c3f84696ec0cc525acde69433f4a335b9f1bd8df8f42e602f6c7188c707436 SHA512 4c41d25ee2345e3db0c9fd7b463f430a8a4a7dbe8a589670d2072719bc0812c32c2ff8f5dbcd88d712e4aca1c8c0c89262a58581f8b17ead036360dd37c72d9e

diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.24.2.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.24.2.ebuild
new file mode 100644
index 00000000000..5ea1141f975
--- /dev/null
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.24.2.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate readme.gentoo-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
+
+LICENSE="GPL-2+ HPND LGPL-2+"
+SLOT="0"
+IUSE="X debug elogind kernel_linux libnotify opengl pam systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.71:0
+	>=dev-libs/glib-2.50:2
+	gnome-base/dconf
+	>=mate-base/libmatekbd-1.17.0
+	>=mate-base/mate-desktop-1.17.0
+	>=mate-base/mate-menus-1.21.0
+	>=sys-apps/dbus-0.30
+	>=x11-libs/gdk-pixbuf-2.14:2
+	>=x11-libs/libX11-1
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/libXxf86vm
+	x11-libs/libxklavier
+	x11-libs/pango
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	opengl? ( virtual/opengl )
+	pam? ( gnome-base/gnome-keyring sys-libs/pam )
+	!pam? ( kernel_linux? ( sys-apps/shadow ) )
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd:= )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=mate-base/mate-session-manager-1.6
+	virtual/libintl
+	!!<gnome-extra/gnome-screensaver-3
+"
+
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8:*
+	x11-base/xorg-proto
+	virtual/pkgconfig:*
+"
+
+DOC_CONTENTS="
+	Information for converting screensavers is located in
+	/usr/share/doc/${PF}/xss-conversion.txt*
+"
+
+src_configure() {
+	local myconf=(
+		--enable-locking
+		--with-kbd-layout-indicator
+		--with-xf86gamma-ext
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		--without-console-kit
+		$(use_with X x)
+		$(use_with elogind)
+		$(use_with libnotify)
+		$(use_with opengl libgl)
+		$(use_with systemd)
+		$(use_enable debug)
+		$(use_enable pam)
+	)
+
+	mate_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	mate_src_install
+
+	# Install the conversion script in the documentation.
+	dodoc "${S}"/data/migrate-xscreensaver-config.sh
+	dodoc "${S}"/data/xscreensaver-config.xsl
+	dodoc "${FILESDIR}"/xss-conversion.txt
+
+	# Non PAM users will need this suid to read the password hashes.
+	# OpenPAM users will probably need this too when
+	# https://bugzilla.gnome.org/show_bug.cgi?id=370847
+	# is fixed.
+	if ! use pam ; then
+		fperms u+s /usr/libexec/mate-screensaver-dialog
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	mate_pkg_postinst
+
+	if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
+		ewarn "You have a too old xorg-server installation. This will cause"
+		ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
+		echo
+	fi
+
+	if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
+		ewarn "You have xscreensaver installed, you probably want to disable it."
+		ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
+		ewarn "build xscreensaver with -gnome in the USE flags."
+		ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
+		echo
+	fi
+
+	readme.gentoo_print_elog
+}