[gentoo-commits] repo/gentoo:master commit in: dev-vcs/subversion/

[Lars Wendler]

commit:     a008b507559a8a06e3ba06fb8e9b18ca54c1d3d5
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 28 19:52:29 2016 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Apr 28 19:53:32 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a008b507

dev-vcs/subversion: Security bump to versions 1.8.16 and 1.9.4 (bug #581448).

Package-Manager: portage-2.2.28
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-vcs/subversion/Manifest                 |   2 +
 dev-vcs/subversion/subversion-1.8.16.ebuild | 508 ++++++++++++++++++++++++++++
 dev-vcs/subversion/subversion-1.9.4.ebuild  | 501 +++++++++++++++++++++++++++
 3 files changed, 1011 insertions(+)

diff --git a/dev-vcs/subversion/Manifest b/dev-vcs/subversion/Manifest
index 43b1c8a..e1f9406 100644
--- a/dev-vcs/subversion/Manifest
+++ b/dev-vcs/subversion/Manifest
@@ -1,5 +1,7 @@
 DIST subversion-1.7.21.tar.bz2 5996788 SHA256 efeb349c5ba6d529ff8e9730a2abd9cb70f276b249238a6b7f27ba7da1190620 SHA512 d0ba3f0771c523b44efd2f12c1d101d720b7d834bc6bef12b8e47789a2fb76a2d399c041c1cdcd0e04411c29abfb9b2974ca9df6f2389f8a01d82e7738881975 WHIRLPOOL 0d12286ab0e5043f28622529ff5d2af5a1c8a61ef65227cc069cf93de35479bf79433fa201417456499fa16f11b03474127b66547b9c2e2a8c0d209fa2108e59
 DIST subversion-1.8.14.tar.bz2 6850562 SHA256 7f3883cdfcad4174e06dd94d6e3e8ec91856823268eebe60c924be76f5229a1f SHA512 95e1501494f5355f0c331fbe81422ca8f0b4d69e6d303125f4a5aac5f6fe946e958ca76fc96fe6b096cc0a530634ca103bf35622c12af90489ae17d0b9a9d987 WHIRLPOOL 0323746d40830109e081e002f499f1c73c15fe77acd4f1c9b790ae12440b3361d189f1d5212d49ba6f6c449297aec3513761375f748800686892607705310a56
 DIST subversion-1.8.15.tar.bz2 6917489 SHA256 cf98a1f7686cfd6a15cbcde8379f15730fd5e00a3573cdb035a6491dbcccc82c SHA512 f5a33b0b2c87eae48a3c21c41164786e92aa061e774e9cc951bc93c1936db58a5d901904ad9dc28e85926f38c7d75645f39bb7e8543333943d3883ee9718aeb0 WHIRLPOOL 101c00a059e350d4999c37977059a439c5253d7ef185664ff8133b152bccdf386a8556f6d47390246ac742a4b4b77c89abd06e5cce76b6e276db6cc55f205374
+DIST subversion-1.8.16.tar.bz2 6919310 SHA256 f18f6e8309270982135aae54d96958f9ca6b93f8a4e746dd634b1b5b84edb346 SHA512 de8ce1aacd60516fd412f3f8b73e0e43c1a5e91d21d099937d3b02a1620aa947a330ec435d8662d5ad5372e23b1ebec1d8aea7d3ca4dd02eb3421924f6da88b1 WHIRLPOOL 01093eaf39173f4a789120ab8ed1b68dcb9b1bea5e9d396d23831b9a0733be412842a711ffe9b72e9d1bf26e835f47b1395b24f2a1301cc556e2520da6151f3e
 DIST subversion-1.9.2.tar.bz2 7910994 SHA256 023da881139b4514647b6f8a830a244071034efcaad8c8e98c6b92393122b4eb SHA512 debe1be153a7abd89d1c0c8d665725a9003e280a7fcde666c21818627bef0c47c30b27560aaa5a9a75251ba0d9c1490613cc79237704f4777a3cad0def52f08a WHIRLPOOL 3a5ff8067079d7e81f9414e3858afb98839cbdcb989b086d1696b4f0eac46ae2ed7c9933d3fa232431ad32578bf2fab986052a05dac7c528415bb5057fa5d213
 DIST subversion-1.9.3.tar.bz2 7909193 SHA256 8bbf6bb125003d88ee1c22935a36b7b1ab7d957e0c8b5fbfe5cb6310b6e86ae0 SHA512 2197c5076e688ac09e63c345e45f2a5ee2999426edb76a91c6b92d229fa8c87772d76e99003a4438035771b4c11c502de399d44f4f42c0d759dcbd01b628a4cb WHIRLPOOL d0b515c53384da558d0838a78f3be75e3bac643f5d95e536e65e0034e1814c91e0d2c218dd41bb5ee76447d47a0484105a25da1abef7851e7461a2a84c320a79
+DIST subversion-1.9.4.tar.bz2 7911473 SHA256 1267f9e2ab983f260623bee841e6c9cc458bf4bf776238ed5f100983f79e9299 SHA512 fa512d8315dd6a435dcc5a3c2ca3cd7cf932364dd3a82063be868aa3ebcc04caf87cd3ff732d3e3d8aec86f3f58848e2b55987451d4697479bb151d1269db07f WHIRLPOOL 0323e5258be08dfdacb0e450b413bdfd053c0026a290dd45cfe5a03437c727d9ad088baba5a42fdd98ff47af5bdc09a0bbeba70a1e4e4e19a8ebcba7e7b7ddd3

diff --git a/dev-vcs/subversion/subversion-1.8.16.ebuild b/dev-vcs/subversion/subversion-1.8.16.ebuild
new file mode 100644
index 0000000..58a0084
--- /dev/null
+++ b/dev-vcs/subversion/subversion-1.8.16.ebuild
@@ -0,0 +1,508 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+USE_RUBY="ruby22 ruby21 ruby20"
+DISTUTILS_OPTIONAL=1
+WANT_AUTOMAKE="none"
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools bash-completion-r1 db-use depend.apache distutils-r1 elisp-common eutils flag-o-matic java-pkg-opt-2 libtool multilib perl-module ruby-single
+
+MY_P="${P/_/-}"
+DESCRIPTION="Advanced version control system"
+HOMEPAGE="http://subversion.apache.org/"
+SRC_URI="mirror://apache/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Subversion GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="apache2 berkdb ctypes-python debug doc +dso extras gnome-keyring +http java kde nls perl python ruby sasl test vim-syntax"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.7.12
+	>=dev-libs/apr-1.3:1
+	>=dev-libs/apr-util-1.3:1
+	dev-libs/expat
+	sys-apps/file
+	sys-libs/zlib
+	app-arch/bzip2
+	berkdb? ( >=sys-libs/db-4.0.14:= )
+	ctypes-python? ( ${PYTHON_DEPS} )
+	gnome-keyring? ( dev-libs/glib:2 sys-apps/dbus gnome-base/libgnome-keyring )
+	kde? ( sys-apps/dbus dev-qt/qtcore:4 dev-qt/qtdbus:4 dev-qt/qtgui:4 >=kde-base/kdelibs-4:4 )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( ${RUBY_DEPS} )
+	sasl? ( dev-libs/cyrus-sasl )
+	http? ( >=net-libs/serf-1.2.1 )"
+RDEPEND="${COMMON_DEPEND}
+	apache2? ( www-servers/apache[apache2_modules_dav] )
+	java? ( >=virtual/jre-1.5 )
+	kde? ( kde-apps/kwalletd:4 )
+	nls? ( virtual/libintl )
+	perl? ( dev-perl/URI )"
+# Note: ctypesgen doesn't need PYTHON_USEDEP, it's used once
+DEPEND="${COMMON_DEPEND}
+	!!<sys-apps/sandbox-1.6
+	ctypes-python? ( dev-python/ctypesgen )
+	doc? ( app-doc/doxygen )
+	gnome-keyring? ( virtual/pkgconfig )
+	http? ( virtual/pkgconfig )
+	java? ( >=virtual/jdk-1.5 )
+	kde? ( virtual/pkgconfig )
+	nls? ( sys-devel/gettext )
+	test? ( ${PYTHON_DEPS} )"
+
+REQUIRED_USE="
+	ctypes-python? ( ${PYTHON_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? (
+		${PYTHON_REQUIRED_USE}
+		!dso
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.4-interix.patch
+	"${FILESDIR}"/${PN}-1.5.6-aix-dso.patch
+	"${FILESDIR}"/${PN}-1.8.0-hpux-dso.patch
+	"${FILESDIR}"/${PN}-fix-parallel-build-support-for-perl-bindings.patch
+	"${FILESDIR}"/${PN}-1.8.1-revert_bdb6check.patch
+)
+
+want_apache
+
+pkg_setup() {
+	if use berkdb ; then
+		local apu_bdb_version="$(${EPREFIX}/usr/bin/apu-1-config --includes \
+			| grep -Eoe '-I${EPREFIX}/usr/include/db[[:digit:]]\.[[:digit:]]' \
+			| sed 's:.*b::')"
+		einfo
+		if [[ -z "${SVN_BDB_VERSION}" ]] ; then
+			if [[ -n "${apu_bdb_version}" ]] ; then
+				SVN_BDB_VERSION="${apu_bdb_version}"
+				einfo "Matching db version to apr-util"
+			else
+				SVN_BDB_VERSION="$(db_ver_to_slot "$(db_findver sys-libs/db 2>/dev/null)")"
+				einfo "SVN_BDB_VERSION variable isn't set. You can set it to enforce using of specific version of Berkeley DB."
+			fi
+		fi
+		einfo "Using: Berkeley DB ${SVN_BDB_VERSION}"
+		einfo
+
+		if [[ -n "${apu_bdb_version}" && "${SVN_BDB_VERSION}" != "${apu_bdb_version}" ]]; then
+			eerror "APR-Util is linked against Berkeley DB ${apu_bdb_version}, but you are trying"
+			eerror "to build Subversion with support for Berkeley DB ${SVN_BDB_VERSION}."
+			eerror "Rebuild dev-libs/apr-util or set SVN_BDB_VERSION=\"${apu_bdb_version}\"."
+			eerror "Aborting to avoid possible run-time crashes."
+			die "Berkeley DB version mismatch"
+		fi
+	fi
+
+	depend.apache_pkg_setup
+
+	java-pkg-opt-2_pkg_setup
+
+	if ! use http ; then
+		ewarn "WebDAV support is disabled. You need WebDAV to"
+		ewarn "access repositories through the HTTP protocol."
+		ewarn "Consider enabling \"http\" USE flag"
+		echo -ne "\a"
+	fi
+
+	if use debug ; then
+		append-cppflags -DSVN_DEBUG -DAP_DEBUG
+	fi
+
+	# http://mail-archives.apache.org/mod_mbox/subversion-dev/201306.mbox/%3C51C42014.3060700@××××××××.com%3E
+	[[ ${CHOST} == *-solaris2* ]] && append-cppflags -D__EXTENSIONS__
+
+	# Allow for custom repository locations.
+	SVN_REPOS_LOC="${SVN_REPOS_LOC:-${EPREFIX}/var/svn}"
+
+	if use ruby ; then
+		local rbslot
+		RB_VER=""
+		for rbslot in $(sed 's@\([[:digit:]]\+\)\([[:digit:]]\)@\1.\2@g' <<< ${USE_RUBY//ruby}) ; do
+			if has_version dev-lang/ruby:${rbslot} ;  then
+				RB_VER="${rbslot/.}"
+				break
+			fi
+		done
+		[[ -z "${RB_VER}" ]] && die "No useable ruby version found"
+	fi
+}
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+
+	fperms +x build/transform_libtool_scripts.sh
+
+	sed -i \
+		-e "s/\(BUILD_RULES=.*\) bdb-test\(.*\)/\1\2/g" \
+		-e "s/\(BUILD_RULES=.*\) test\(.*\)/\1\2/g" configure.ac
+
+	# this bites us in particular on Solaris
+	sed -i -e '1c\#!/usr/bin/env sh' build/transform_libtool_scripts.sh || \
+		die "/bin/sh is not POSIX shell!"
+
+	eautoconf
+	elibtoolize
+
+	sed -e 's/\(libsvn_swig_py\)-\(1\.la\)/\1-$(EPYTHON)-\2/g' \
+		-i build-outputs.mk || die "sed failed"
+
+	if use python ; then
+		if [[ ${CHOST} == *-darwin* ]] ; then
+			# http://mail-archives.apache.org/mod_mbox/subversion-dev/201306.mbox/%3C20130614113003.GA19257@××××××.local2%3E
+			# in short, we don't have gnome-keyring stuff here, patch
+			# borrowed from MacPorts
+			epatch "${FILESDIR}"/${PN}-1.8.5-swig-python-no-gnome-keyring.patch
+		fi
+
+		# XXX: make python_copy_sources accept path
+		S=${S}/subversion/bindings/swig/python python_copy_sources
+		rm -r "${S}"/subversion/bindings/swig/python || die
+	fi
+}
+
+src_configure() {
+	local myconf=()
+
+	if use python || use perl || use ruby; then
+		myconf+=( --with-swig )
+	else
+		myconf+=( --without-swig )
+	fi
+
+	if use java ; then
+		myconf+=( --without-junit )
+	fi
+
+	case ${CHOST} in
+		*-aix*)
+			# avoid recording immediate path to sharedlibs into executables
+			append-ldflags -Wl,-bnoipath
+		;;
+		*-interix*)
+			# loader crashes on the LD_PRELOADs...
+			myconf+=( --disable-local-library-preloading )
+		;;
+		*-solaris*)
+			# need -lintl to link
+			use nls && append-libs intl
+			# this breaks installation, on x64 echo replacement is 32-bits
+			myconf+=( --disable-local-library-preloading )
+		;;
+		*-mint*)
+			myconf+=( --enable-all-static --disable-local-library-preloading )
+		;;
+		*)
+			# inject LD_PRELOAD entries for easy in-tree development
+			myconf+=( --enable-local-library-preloading )
+		;;
+	esac
+
+	#version 1.7.7 again tries to link against the older installed version and fails, when trying to
+	#compile for x86 on amd64, so workaround this issue again
+	#check newer versions, if this is still/again needed
+	myconf+=( --disable-disallowing-of-undefined-references )
+
+	# for build-time scripts
+	if use ctypes-python || use python || use test; then
+		python_setup
+	fi
+
+	if use python && [[ ${CHOST} == *-darwin* ]] ; then
+		export ac_cv_python_link="$(tc-getCC) "'$(PYTHON_CFLAGS) -bundle -undefined dynamic_lookup $(PYTHON_LIBS)'
+		export ac_cv_python_libs='$(PYTHON_CFLAGS) -bundle -undefined dynamic_lookup $(PYTHON_LIBS)'
+		export ac_cv_python_compile="$(tc-getCC)"
+	fi
+
+	# allow overriding Python include directory
+	ac_cv_path_RUBY=$(usex ruby "${EPREFIX}/usr/bin/ruby${RB_VER}" "none") \
+	ac_cv_path_RDOC=$(usex ruby "${EPREFIX}/usr/bin/rdoc${RB_VER}" "none") \
+	ac_cv_python_includes='-I$(PYTHON_INCLUDEDIR)' \
+	econf --libdir="${EPREFIX}/usr/$(get_libdir)" \
+		$(use_with apache2 apache-libexecdir) \
+		$(use_with apache2 apxs "${APXS}") \
+		$(use_with berkdb berkeley-db "db.h:${EPREFIX}/usr/include/db${SVN_BDB_VERSION}::db-${SVN_BDB_VERSION}") \
+		$(use_with ctypes-python ctypesgen "${EPREFIX}/usr") \
+		$(use_enable dso runtime-module-search) \
+		$(use_with gnome-keyring) \
+		$(use_enable java javahl) \
+		$(use_with java jdk "${JAVA_HOME}") \
+		$(use_with kde kwallet) \
+		$(use_enable nls) \
+		$(use_with sasl) \
+		$(use_with http serf) \
+		${myconf[@]} \
+		--with-apr="${EPREFIX}/usr/bin/apr-1-config" \
+		--with-apr-util="${EPREFIX}/usr/bin/apu-1-config" \
+		--disable-experimental-libtool \
+		--without-jikes \
+		--disable-mod-activation \
+		--disable-static
+}
+
+src_compile() {
+	emake local-all
+
+	if use ctypes-python ; then
+		# pre-generate .py files
+		use ctypes-python && emake ctypes-python
+
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_compile
+		popd >/dev/null || die
+	fi
+
+	if use python ; then
+		swig_py_compile() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			python_export PYTHON_INCLUDEDIR
+			emake swig-py \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn"
+		}
+
+		# this will give us proper BUILD_DIR for symlinking
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_compile
+	fi
+
+	if use perl ; then
+		emake swig-pl
+	fi
+
+	if use ruby ; then
+		emake swig-rb
+	fi
+
+	if use java ; then
+		emake -j1 JAVAC_FLAGS="$(java-pkg_javac-args) -encoding iso8859-1" javahl
+	fi
+
+	if use extras ; then
+		emake tools
+	fi
+
+	if use doc ; then
+		doxygen doc/doxygen.conf || die "Building of Subversion HTML documentation failed"
+
+		if use java; then
+			emake doc-javahl
+		fi
+	fi
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P} ; then
+		default
+
+		if use ctypes-python ; then
+			python_test() {
+				"${PYTHON}" subversion/bindings/ctypes-python/test/run_all.py \
+					|| die "ctypes-python tests fail with ${EPYTHON}"
+			}
+
+			distutils-r1_src_test
+		fi
+
+		if use python ; then
+			swig_py_test() {
+				pushd "${BUILD_DIR}" >/dev/null || die
+				"${PYTHON}" tests/run_all.py || die "swig-py tests fail with ${EPYTHON}"
+				popd >/dev/null || die
+			}
+
+			BUILD_DIR=subversion/bindings/swig/python \
+			python_foreach_impl swig_py_test
+		fi
+	else
+		ewarn "The test suite shows errors when there is an older version of"
+		ewarn "${CATEGORY}/${PN} installed. Please install =${CATEGORY}/${P}*"
+		ewarn "before running the test suite."
+		ewarn "Test suite skipped."
+	fi
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" local-install
+
+	if use ctypes-python ; then
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_install
+		popd >/dev/null || die
+	fi
+
+	if use python ; then
+		swig_py_install() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			emake \
+				DESTDIR="${D}" \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn" \
+				install-swig-py
+		}
+
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_install
+	fi
+
+	if use perl ; then
+		emake DESTDIR="${D}" INSTALLDIRS="vendor" install-swig-pl
+		perl_delete_localpod
+		find "${ED}" "(" -name .packlist -o -name "*.bs" ")" -delete
+	fi
+
+	if use ruby ; then
+		emake DESTDIR="${D}" install-swig-rb
+	fi
+
+	if use java ; then
+		emake DESTDIR="${D}" install-javahl
+		java-pkg_regso "${ED}"usr/$(get_libdir)/libsvnjavahl*$(get_libname)
+		java-pkg_dojar "${ED}"usr/$(get_libdir)/svn-javahl/svn-javahl.jar
+		rm -fr "${ED}"usr/$(get_libdir)/svn-javahl/*.jar
+	fi
+
+	# Install Apache module configuration.
+	if use apache2 ; then
+		keepdir "${APACHE_MODULES_CONFDIR}"
+		insinto "${APACHE_MODULES_CONFDIR}"
+		doins "${FILESDIR}/47_mod_dav_svn.conf"
+	fi
+
+	# Install Bash Completion, bug 43179.
+	newbashcomp tools/client-side/bash_completion svn
+	bashcomp_alias svn svn{admin,dumpfilter,look,sync,version}
+	rm -f tools/client-side/bash_completion
+
+	# Install hot backup script, bug 54304.
+	newbin tools/backup/hot-backup.py svn-hot-backup
+	rm -fr tools/backup
+
+	# Install svnserve init-script and xinet.d snippet, bug 43245.
+	newinitd "${FILESDIR}"/svnserve.initd3 svnserve
+	newconfd "${FILESDIR}"/svnserve.confd svnserve
+	insinto /etc/xinetd.d
+	newins "${FILESDIR}"/svnserve.xinetd svnserve
+
+	#adjust default user and group with disabled apache2 USE flag, bug 381385
+	use apache2 || sed -e "s\USER:-apache\USER:-svn\g" \
+			-e "s\GROUP:-apache\GROUP:-svnusers\g" \
+			-i "${ED}"etc/init.d/svnserve || die
+	use apache2 || sed -e "0,/apache/s//svn/" \
+			-e "s:apache:svnusers:" \
+			-i "${ED}"etc/xinetd.d/svnserve || die
+
+	# Install documentation.
+	dodoc CHANGES COMMITTERS README
+	dodoc tools/xslt/svnindex.{css,xsl}
+	rm -fr tools/xslt
+
+	# Install extra files.
+	if use extras ; then
+		cat << EOF > 80subversion-extras
+PATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+ROOTPATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+EOF
+		doenvd 80subversion-extras
+
+		emake DESTDIR="${D}" toolsdir="/usr/$(get_libdir)/subversion/bin" install-tools
+
+		find tools "(" -name "*.bat" -o -name "*.in" -o -name ".libs" ")" -print0 | xargs -0 rm -fr
+		rm -fr tools/client-side/svnmucc
+		rm -fr tools/server-side/{svn-populate-node-origins-index,svnauthz-validate}*
+		rm -fr tools/{buildbot,dev,diff,po}
+
+		insinto /usr/share/${PN}
+		find tools -name '*.py' -exec sed -i -e '1s:python:&2:' {} + || die
+		doins -r tools
+	fi
+
+	if use doc ; then
+		docinto html
+		dodoc -r doc/doxygen/html/*
+
+		if use java ; then
+			java-pkg_dojavadoc doc/javadoc
+		fi
+	fi
+
+	prune_libtool_files --all
+
+	cd "${ED}"usr/share/locale
+	for i in * ; do
+		[[ ${i} == *$LINGUAS* ]] || { rm -r ${i} || die ; }
+	done
+}
+
+pkg_preinst() {
+	# Compare versions of Berkeley DB, bug 122877.
+	if use berkdb && [[ -f "${EROOT}usr/bin/svn" ]] ; then
+		OLD_BDB_VERSION="$(scanelf -nq "${EROOT}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		NEW_BDB_VERSION="$(scanelf -nq "${ED}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		if [[ "${OLD_BDB_VERSION}" != "${NEW_BDB_VERSION}" ]] ; then
+			CHANGED_BDB_VERSION="1"
+		fi
+	fi
+}
+
+pkg_postinst() {
+	if [[ -n "${CHANGED_BDB_VERSION}" ]] ; then
+		ewarn "You upgraded from an older version of Berkeley DB and may experience"
+		ewarn "problems with your repository. Run the following commands as root to fix it:"
+		ewarn "    db4_recover -h ${SVN_REPOS_LOC}/repos"
+		ewarn "    chown -Rf apache:apache ${SVN_REPOS_LOC}/repos"
+	fi
+
+	ewarn "If you run subversion as a daemon, you will need to restart it to avoid module mismatches."
+}
+
+pkg_postrm() {
+	:
+}
+
+pkg_config() {
+	# Remember: Don't use ${EROOT}${SVN_REPOS_LOC} since ${SVN_REPOS_LOC}
+	# already has EPREFIX in it
+	einfo "Initializing the database in ${SVN_REPOS_LOC}..."
+	if [[ -e "${SVN_REPOS_LOC}/repos" ]] ; then
+		echo "A Subversion repository already exists and I will not overwrite it."
+		echo "Delete \"${SVN_REPOS_LOC}/repos\" first if you're sure you want to have a clean version."
+	else
+		mkdir -p "${SVN_REPOS_LOC}/conf"
+
+		einfo "Populating repository directory..."
+		# Create initial repository.
+		"${EROOT}usr/bin/svnadmin" create "${SVN_REPOS_LOC}/repos"
+
+		einfo "Setting repository permissions..."
+		SVNSERVE_USER="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_USER}")"
+		SVNSERVE_GROUP="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_GROUP}")"
+		if use apache2 ; then
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="apache"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="apache"
+		else
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="svn"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="svnusers"
+		fi
+		chmod -Rf go-rwx "${SVN_REPOS_LOC}/conf"
+		chmod -Rf o-rwx "${SVN_REPOS_LOC}/repos"
+		echo "Please create \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Afterwards please create \"${SVNSERVE_USER}\" user with homedir \"${SVN_REPOS_LOC}\""
+		echo "and as part of the \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Finally, execute \"chown -Rf ${SVNSERVE_USER}:${SVNSERVE_GROUP} ${SVN_REPOS_LOC}/repos\""
+		echo "to finish the configuration."
+	fi
+}

diff --git a/dev-vcs/subversion/subversion-1.9.4.ebuild b/dev-vcs/subversion/subversion-1.9.4.ebuild
new file mode 100644
index 0000000..3ac7edd
--- /dev/null
+++ b/dev-vcs/subversion/subversion-1.9.4.ebuild
@@ -0,0 +1,501 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+USE_RUBY="ruby23 ruby22 ruby21 ruby20"
+DISTUTILS_OPTIONAL=1
+WANT_AUTOMAKE="none"
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools bash-completion-r1 db-use depend.apache distutils-r1 elisp-common eutils flag-o-matic java-pkg-opt-2 libtool multilib perl-module ruby-single
+
+MY_P="${P/_/-}"
+DESCRIPTION="Advanced version control system"
+HOMEPAGE="http://subversion.apache.org/"
+SRC_URI="mirror://apache/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Subversion GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="apache2 berkdb ctypes-python debug doc +dso extras gnome-keyring +http java kde nls perl python ruby sasl test vim-syntax"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.7.12
+	>=dev-libs/apr-1.3:1
+	>=dev-libs/apr-util-1.3:1
+	dev-libs/expat
+	sys-apps/file
+	sys-libs/zlib
+	app-arch/bzip2
+	berkdb? ( >=sys-libs/db-4.0.14:= )
+	ctypes-python? ( ${PYTHON_DEPS} )
+	gnome-keyring? ( dev-libs/glib:2 sys-apps/dbus gnome-base/libgnome-keyring )
+	kde? ( sys-apps/dbus dev-qt/qtcore:4 dev-qt/qtdbus:4 dev-qt/qtgui:4 >=kde-base/kdelibs-4:4 )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( ${RUBY_DEPS} )
+	sasl? ( dev-libs/cyrus-sasl )
+	http? ( >=net-libs/serf-1.3.4 )"
+RDEPEND="${COMMON_DEPEND}
+	apache2? ( www-servers/apache[apache2_modules_dav] )
+	java? ( >=virtual/jre-1.5 )
+	kde? ( kde-apps/kwalletd:4 )
+	nls? ( virtual/libintl )
+	perl? ( dev-perl/URI )"
+# Note: ctypesgen doesn't need PYTHON_USEDEP, it's used once
+DEPEND="${COMMON_DEPEND}
+	!!<sys-apps/sandbox-1.6
+	ctypes-python? ( dev-python/ctypesgen )
+	doc? ( app-doc/doxygen )
+	gnome-keyring? ( virtual/pkgconfig )
+	http? ( virtual/pkgconfig )
+	java? ( >=virtual/jdk-1.5 )
+	kde? ( virtual/pkgconfig )
+	nls? ( sys-devel/gettext )
+	test? ( ${PYTHON_DEPS} )"
+
+REQUIRED_USE="
+	ctypes-python? ( ${PYTHON_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? (
+		${PYTHON_REQUIRED_USE}
+		!dso
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.4-interix.patch
+	"${FILESDIR}"/${PN}-1.5.6-aix-dso.patch
+	"${FILESDIR}"/${PN}-1.8.0-hpux-dso.patch
+	"${FILESDIR}"/${PN}-fix-parallel-build-support-for-perl-bindings.patch
+	"${FILESDIR}"/${PN}-1.8.1-revert_bdb6check.patch
+)
+
+want_apache
+
+pkg_setup() {
+	if use berkdb ; then
+		local apu_bdb_version="$(${EPREFIX}/usr/bin/apu-1-config --includes \
+			| grep -Eoe '-I${EPREFIX}/usr/include/db[[:digit:]]\.[[:digit:]]' \
+			| sed 's:.*b::')"
+		einfo
+		if [[ -z "${SVN_BDB_VERSION}" ]] ; then
+			if [[ -n "${apu_bdb_version}" ]] ; then
+				SVN_BDB_VERSION="${apu_bdb_version}"
+				einfo "Matching db version to apr-util"
+			else
+				SVN_BDB_VERSION="$(db_ver_to_slot "$(db_findver sys-libs/db 2>/dev/null)")"
+				einfo "SVN_BDB_VERSION variable isn't set. You can set it to enforce using of specific version of Berkeley DB."
+			fi
+		fi
+		einfo "Using: Berkeley DB ${SVN_BDB_VERSION}"
+		einfo
+
+		if [[ -n "${apu_bdb_version}" && "${SVN_BDB_VERSION}" != "${apu_bdb_version}" ]]; then
+			eerror "APR-Util is linked against Berkeley DB ${apu_bdb_version}, but you are trying"
+			eerror "to build Subversion with support for Berkeley DB ${SVN_BDB_VERSION}."
+			eerror "Rebuild dev-libs/apr-util or set SVN_BDB_VERSION=\"${apu_bdb_version}\"."
+			eerror "Aborting to avoid possible run-time crashes."
+			die "Berkeley DB version mismatch"
+		fi
+	fi
+
+	depend.apache_pkg_setup
+
+	java-pkg-opt-2_pkg_setup
+
+	if ! use http ; then
+		ewarn "WebDAV support is disabled. You need WebDAV to"
+		ewarn "access repositories through the HTTP protocol."
+		ewarn "Consider enabling \"http\" USE flag"
+		echo -ne "\a"
+	fi
+
+	if use debug ; then
+		append-cppflags -DSVN_DEBUG -DAP_DEBUG
+	fi
+
+	# http://mail-archives.apache.org/mod_mbox/subversion-dev/201306.mbox/%3C51C42014.3060700@××××××××.com%3E
+	[[ ${CHOST} == *-solaris2* ]] && append-cppflags -D__EXTENSIONS__
+
+	# Allow for custom repository locations.
+	SVN_REPOS_LOC="${SVN_REPOS_LOC:-${EPREFIX}/var/svn}"
+
+	if use ruby ; then
+		local rbslot
+		RB_VER=""
+		for rbslot in $(sed 's@\([[:digit:]]\+\)\([[:digit:]]\)@\1.\2@g' <<< ${USE_RUBY//ruby}) ; do
+			if has_version dev-lang/ruby:${rbslot} ;  then
+				RB_VER="${rbslot/.}"
+				break
+			fi
+		done
+		[[ -z "${RB_VER}" ]] && die "No useable ruby version found"
+	fi
+}
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+
+	fperms +x build/transform_libtool_scripts.sh
+
+	sed -i \
+		-e "s/\(BUILD_RULES=.*\) bdb-test\(.*\)/\1\2/g" \
+		-e "s/\(BUILD_RULES=.*\) test\(.*\)/\1\2/g" configure.ac
+
+	# this bites us in particular on Solaris
+	sed -i -e '1c\#!/usr/bin/env sh' build/transform_libtool_scripts.sh || \
+		die "/bin/sh is not POSIX shell!"
+
+	eautoconf
+	elibtoolize
+
+	sed -e 's/\(libsvn_swig_py\)-\(1\.la\)/\1-$(EPYTHON)-\2/g' \
+		-i build-outputs.mk || die "sed failed"
+
+	if use python ; then
+		# XXX: make python_copy_sources accept path
+		S=${S}/subversion/bindings/swig/python python_copy_sources
+		rm -r "${S}"/subversion/bindings/swig/python || die
+	fi
+}
+
+src_configure() {
+	local myconf=()
+
+	if use python || use perl || use ruby; then
+		myconf+=( --with-swig )
+	else
+		myconf+=( --without-swig )
+	fi
+
+	if use java ; then
+		myconf+=( --without-junit )
+	fi
+
+	case ${CHOST} in
+		*-aix*)
+			# avoid recording immediate path to sharedlibs into executables
+			append-ldflags -Wl,-bnoipath
+		;;
+		*-interix*)
+			# loader crashes on the LD_PRELOADs...
+			myconf+=( --disable-local-library-preloading )
+		;;
+		*-solaris*)
+			# need -lintl to link
+			use nls && append-libs intl
+			# this breaks installation, on x64 echo replacement is 32-bits
+			myconf+=( --disable-local-library-preloading )
+		;;
+		*-mint*)
+			myconf+=( --enable-all-static --disable-local-library-preloading )
+		;;
+		*)
+			# inject LD_PRELOAD entries for easy in-tree development
+			myconf+=( --enable-local-library-preloading )
+		;;
+	esac
+
+	#version 1.7.7 again tries to link against the older installed version and fails, when trying to
+	#compile for x86 on amd64, so workaround this issue again
+	#check newer versions, if this is still/again needed
+	myconf+=( --disable-disallowing-of-undefined-references )
+
+	# for build-time scripts
+	if use ctypes-python || use python || use test; then
+		python_setup
+	fi
+
+	if use python && [[ ${CHOST} == *-darwin* ]] ; then
+		export ac_cv_python_link="$(tc-getCC) "'$(PYTHON_CFLAGS) -bundle -undefined dynamic_lookup $(PYTHON_LIBS)'
+		export ac_cv_python_libs='$(PYTHON_CFLAGS) -bundle -undefined dynamic_lookup $(PYTHON_LIBS)'
+		export ac_cv_python_compile="$(tc-getCC)"
+	fi
+
+	# allow overriding Python include directory
+	ac_cv_path_RUBY=$(usex ruby "${EPREFIX}/usr/bin/ruby${RB_VER}" "none") \
+	ac_cv_path_RDOC=$(usex ruby "${EPREFIX}/usr/bin/rdoc${RB_VER}" "none") \
+	ac_cv_python_includes='-I$(PYTHON_INCLUDEDIR)' \
+	econf --libdir="${EPREFIX}/usr/$(get_libdir)" \
+		$(use_with apache2 apache-libexecdir) \
+		$(use_with apache2 apxs "${APXS}") \
+		$(use_with berkdb berkeley-db "db.h:${EPREFIX}/usr/include/db${SVN_BDB_VERSION}::db-${SVN_BDB_VERSION}") \
+		$(use_with ctypes-python ctypesgen "${EPREFIX}/usr") \
+		$(use_enable dso runtime-module-search) \
+		$(use_with gnome-keyring) \
+		$(use_enable java javahl) \
+		$(use_with java jdk "${JAVA_HOME}") \
+		$(use_with kde kwallet) \
+		$(use_enable nls) \
+		$(use_with sasl) \
+		$(use_with http serf) \
+		${myconf[@]} \
+		--with-apr="${EPREFIX}/usr/bin/apr-1-config" \
+		--with-apr-util="${EPREFIX}/usr/bin/apu-1-config" \
+		--disable-experimental-libtool \
+		--without-jikes \
+		--disable-mod-activation \
+		--disable-static
+}
+
+src_compile() {
+	emake local-all
+
+	if use ctypes-python ; then
+		# pre-generate .py files
+		use ctypes-python && emake ctypes-python
+
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_compile
+		popd >/dev/null || die
+	fi
+
+	if use python ; then
+		swig_py_compile() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			python_export PYTHON_INCLUDEDIR
+			emake swig-py \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn"
+		}
+
+		# this will give us proper BUILD_DIR for symlinking
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_compile
+	fi
+
+	if use perl ; then
+		emake swig-pl
+	fi
+
+	if use ruby ; then
+		emake swig-rb
+	fi
+
+	if use java ; then
+		emake -j1 JAVAC_FLAGS="$(java-pkg_javac-args) -encoding iso8859-1" javahl
+	fi
+
+	if use extras ; then
+		emake tools
+	fi
+
+	if use doc ; then
+		doxygen doc/doxygen.conf || die "Building of Subversion HTML documentation failed"
+
+		if use java; then
+			emake doc-javahl
+		fi
+	fi
+}
+
+src_test() {
+	if has_version ~${CATEGORY}/${P} ; then
+		default
+
+		if use ctypes-python ; then
+			python_test() {
+				"${PYTHON}" subversion/bindings/ctypes-python/test/run_all.py \
+					|| die "ctypes-python tests fail with ${EPYTHON}"
+			}
+
+			distutils-r1_src_test
+		fi
+
+		if use python ; then
+			swig_py_test() {
+				pushd "${BUILD_DIR}" >/dev/null || die
+				"${PYTHON}" tests/run_all.py || die "swig-py tests fail with ${EPYTHON}"
+				popd >/dev/null || die
+			}
+
+			BUILD_DIR=subversion/bindings/swig/python \
+			python_foreach_impl swig_py_test
+		fi
+	else
+		ewarn "The test suite shows errors when there is an older version of"
+		ewarn "${CATEGORY}/${PN} installed. Please install =${CATEGORY}/${P}*"
+		ewarn "before running the test suite."
+		ewarn "Test suite skipped."
+	fi
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" local-install
+
+	if use ctypes-python ; then
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_install
+		popd >/dev/null || die
+	fi
+
+	if use python ; then
+		swig_py_install() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			emake \
+				DESTDIR="${D}" \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn" \
+				install-swig-py
+		}
+
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_install
+	fi
+
+	if use perl ; then
+		emake DESTDIR="${D}" INSTALLDIRS="vendor" install-swig-pl
+		perl_delete_localpod
+		find "${ED}" "(" -name .packlist -o -name "*.bs" ")" -delete
+	fi
+
+	if use ruby ; then
+		emake DESTDIR="${D}" install-swig-rb
+	fi
+
+	if use java ; then
+		emake DESTDIR="${D}" install-javahl
+		java-pkg_regso "${ED}"usr/$(get_libdir)/libsvnjavahl*$(get_libname)
+		java-pkg_dojar "${ED}"usr/$(get_libdir)/svn-javahl/svn-javahl.jar
+		rm -fr "${ED}"usr/$(get_libdir)/svn-javahl/*.jar
+	fi
+
+	# Install Apache module configuration.
+	if use apache2 ; then
+		keepdir "${APACHE_MODULES_CONFDIR}"
+		insinto "${APACHE_MODULES_CONFDIR}"
+		doins "${FILESDIR}/47_mod_dav_svn.conf"
+	fi
+
+	# Install Bash Completion, bug 43179.
+	newbashcomp tools/client-side/bash_completion svn
+	bashcomp_alias svn svn{admin,dumpfilter,look,sync,version}
+	rm -f tools/client-side/bash_completion
+
+	# Install hot backup script, bug 54304.
+	newbin tools/backup/hot-backup.py svn-hot-backup
+	rm -fr tools/backup
+
+	# Install svnserve init-script and xinet.d snippet, bug 43245.
+	newinitd "${FILESDIR}"/svnserve.initd3 svnserve
+	newconfd "${FILESDIR}"/svnserve.confd svnserve
+	insinto /etc/xinetd.d
+	newins "${FILESDIR}"/svnserve.xinetd svnserve
+
+	#adjust default user and group with disabled apache2 USE flag, bug 381385
+	use apache2 || sed -e "s\USER:-apache\USER:-svn\g" \
+			-e "s\GROUP:-apache\GROUP:-svnusers\g" \
+			-i "${ED}"etc/init.d/svnserve || die
+	use apache2 || sed -e "0,/apache/s//svn/" \
+			-e "s:apache:svnusers:" \
+			-i "${ED}"etc/xinetd.d/svnserve || die
+
+	# Install documentation.
+	dodoc CHANGES COMMITTERS README
+	dodoc tools/xslt/svnindex.{css,xsl}
+	rm -fr tools/xslt
+
+	# Install extra files.
+	if use extras ; then
+		cat << EOF > 80subversion-extras
+PATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+ROOTPATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+EOF
+		doenvd 80subversion-extras
+
+		emake DESTDIR="${D}" toolsdir="/usr/$(get_libdir)/subversion/bin" install-tools
+
+		find tools "(" -name "*.bat" -o -name "*.in" -o -name ".libs" ")" -print0 | xargs -0 rm -fr
+		rm -fr tools/client-side/svnmucc
+		rm -fr tools/server-side/{svn-populate-node-origins-index,svnauthz-validate}*
+		rm -fr tools/{buildbot,dev,diff,po}
+
+		insinto /usr/share/${PN}
+		find tools -name '*.py' -exec sed -i -e '1s:python:&2:' {} + || die
+		doins -r tools
+	fi
+
+	if use doc ; then
+		docinto html
+		dodoc -r doc/doxygen/html/*
+
+		if use java ; then
+			java-pkg_dojavadoc doc/javadoc
+		fi
+	fi
+
+	prune_libtool_files --all
+
+	cd "${ED}"usr/share/locale
+	for i in * ; do
+		[[ ${i} == *$LINGUAS* ]] || { rm -r ${i} || die ; }
+	done
+}
+
+pkg_preinst() {
+	# Compare versions of Berkeley DB, bug 122877.
+	if use berkdb && [[ -f "${EROOT}usr/bin/svn" ]] ; then
+		OLD_BDB_VERSION="$(scanelf -nq "${EROOT}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		NEW_BDB_VERSION="$(scanelf -nq "${ED}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		if [[ "${OLD_BDB_VERSION}" != "${NEW_BDB_VERSION}" ]] ; then
+			CHANGED_BDB_VERSION="1"
+		fi
+	fi
+}
+
+pkg_postinst() {
+	if [[ -n "${CHANGED_BDB_VERSION}" ]] ; then
+		ewarn "You upgraded from an older version of Berkeley DB and may experience"
+		ewarn "problems with your repository. Run the following commands as root to fix it:"
+		ewarn "    db4_recover -h ${SVN_REPOS_LOC}/repos"
+		ewarn "    chown -Rf apache:apache ${SVN_REPOS_LOC}/repos"
+	fi
+
+	ewarn "If you run subversion as a daemon, you will need to restart it to avoid module mismatches."
+}
+
+pkg_postrm() {
+	:
+}
+
+pkg_config() {
+	# Remember: Don't use ${EROOT}${SVN_REPOS_LOC} since ${SVN_REPOS_LOC}
+	# already has EPREFIX in it
+	einfo "Initializing the database in ${SVN_REPOS_LOC}..."
+	if [[ -e "${SVN_REPOS_LOC}/repos" ]] ; then
+		echo "A Subversion repository already exists and I will not overwrite it."
+		echo "Delete \"${SVN_REPOS_LOC}/repos\" first if you're sure you want to have a clean version."
+	else
+		mkdir -p "${SVN_REPOS_LOC}/conf"
+
+		einfo "Populating repository directory..."
+		# Create initial repository.
+		"${EROOT}usr/bin/svnadmin" create "${SVN_REPOS_LOC}/repos"
+
+		einfo "Setting repository permissions..."
+		SVNSERVE_USER="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_USER}")"
+		SVNSERVE_GROUP="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_GROUP}")"
+		if use apache2 ; then
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="apache"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="apache"
+		else
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="svn"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="svnusers"
+		fi
+		chmod -Rf go-rwx "${SVN_REPOS_LOC}/conf"
+		chmod -Rf o-rwx "${SVN_REPOS_LOC}/repos"
+		echo "Please create \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Afterwards please create \"${SVNSERVE_USER}\" user with homedir \"${SVN_REPOS_LOC}\""
+		echo "and as part of the \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Finally, execute \"chown -Rf ${SVNSERVE_USER}:${SVNSERVE_GROUP} ${SVN_REPOS_LOC}/repos\""
+		echo "to finish the configuration."
+	fi
+}