[gentoo-commits] repo/gentoo:master commit in: media-libs/qtav/

[Johannes Huber]

commit:     ebf960412b7e4c2e148b0534f6dfe6d4e327c63b
Author:     Johannes Huber <johu <AT> gentoo <DOT> org>
AuthorDate: Sun Jan  5 13:08:48 2020 +0000
Commit:     Johannes Huber <johu <AT> gentoo <DOT> org>
CommitDate: Sun Jan  5 13:09:06 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ebf96041

media-libs/qtav: Migrate to cmake eclass

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Johannes Huber <johu <AT> gentoo.org>

 media-libs/qtav/qtav-1.12.0-r1.ebuild | 63 +++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

diff --git a/media-libs/qtav/qtav-1.12.0-r1.ebuild b/media-libs/qtav/qtav-1.12.0-r1.ebuild
new file mode 100644
index 00000000000..14df283f888
--- /dev/null
+++ b/media-libs/qtav/qtav-1.12.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="QtAV"
+CAPI_HASH="b43aa93"
+inherit cmake
+
+DESCRIPTION="Multimedia playback framework based on Qt + FFmpeg"
+HOMEPAGE="https://www.qtav.org"
+SRC_URI="https://github.com/wang-bin/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+https://dev.gentoo.org/~johu/distfiles/${P}-capi.h-${CAPI_HASH}.xz"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64"
+IUSE="gui libav opengl portaudio pulseaudio vaapi"
+REQUIRED_USE="gui? ( opengl )"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	gui? ( dev-qt/qtsql:5 )
+	libav? (
+		media-video/libav:=
+		x11-libs/libX11
+	)
+	!libav? ( media-video/ffmpeg:= )
+	opengl? ( dev-qt/qtopengl:5 )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-multilib.patch
+	"${FILESDIR}"/${P}-ffmpeg4-{1,2}.patch # bugs 660852, 670765
+)
+
+src_prepare() {
+	cmake_src_prepare
+	cp "${WORKDIR}/${P}-capi.h-${CAPI_HASH}" contrib/capi/capi.h \
+		|| die "Failed to add missing header"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=OFF
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_PLAYERS=$(usex gui)
+		-DBUILD_QT5OPENGL=$(usex opengl)
+		-DHAVE_PORTAUDIO=$(usex portaudio)
+		-DHAVE_PULSE=$(usex pulseaudio)
+		-DHAVE_VAAPI=$(usex vaapi)
+	)
+
+	cmake_src_configure
+}