[gentoo-commits] gentoo-x86 commit in games-arcade/lbreakout2: ChangeLog lbreakout2-2.6.2.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/10/06 19:05:50

  Modified:             ChangeLog
  Added:                lbreakout2-2.6.2.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.27                 games-arcade/lbreakout2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/lbreakout2/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/lbreakout2/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/lbreakout2/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	10 Feb 2010 04:39:35 -0000	1.26
+++ ChangeLog	6 Oct 2010 19:05:49 -0000	1.27
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/lbreakout2
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v 1.26 2010/02/10 04:39:35 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/ChangeLog,v 1.27 2010/10/06 19:05:49 mr_bones_ Exp $
+
+*lbreakout2-2.6.2 (06 Oct 2010)
+
+  06 Oct 2010; Michael Sterrett <mr_bones_@g.o>
+  +lbreakout2-2.6.2.ebuild, +files/lbreakout2-2.6.2-gentoo.patch:
+  version bump
 
   10 Feb 2010; Joseph Jezak <josejx@g.o> lbreakout2-2.6.1.ebuild:
   Marked ppc stable for bug #302842.



1.1                  games-arcade/lbreakout2/lbreakout2-2.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.2.ebuild?rev=1.1&content-type=text/plain

Index: lbreakout2-2.6.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/lbreakout2/lbreakout2-2.6.2.ebuild,v 1.1 2010/10/06 19:05:49 mr_bones_ Exp $

EAPI=2
inherit autotools flag-o-matic eutils games

levels_V=20100920
themes_V=20070514

DESCRIPTION="Breakout clone written with the SDL library"
HOMEPAGE="http://lgames.sourceforge.net/index.php?project=LBreakout2"
SRC_URI=" mirror://sourceforge/lgames/${P}.tar.gz
	mirror://sourceforge/lgames/${PN}-levelsets-${levels_V}.tar.gz
	themes? ( mirror://sourceforge/lgames/${PN}-themes-${themes_V}.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="nls themes"

RDEPEND="media-libs/libpng
	sys-libs/zlib
	media-libs/libsdl[audio,joystick,video]
	media-libs/sdl-net
	media-libs/sdl-mixer
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${P}.tar.gz

	cd "${S}/client/levels"
	unpack ${PN}-levelsets-${levels_V}.tar.gz

	if use themes ; then
		mkdir "${WORKDIR}/themes"
		cd "${WORKDIR}/themes"
		unpack ${PN}-themes-${themes_V}.tar.gz

		# Delete a few duplicate themes (already shipped with lbreakout2
		# tarball). Some of them have different case than built-in themes, so it
		# is harder to just compare if the filename is the same.
		rm -f absoluteB.zip oz.zip moiree.zip
		for f in *.zip; do
			unzip -q "$f"  &&  rm -f "$f"  ||  die "unpacking ${f}"
		done
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	eautoreconf
}

src_configure() {
	filter-flags -O?
	egamesconf \
		--disable-dependency-tracking \
		--enable-sdl-net \
		--localedir=/usr/share/locale \
		--with-docdir="/usr/share/doc/${PF}/html" \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS README TODO ChangeLog

	if use themes ; then
		insinto "${GAMES_DATADIR}/lbreakout2/gfx"
		doins -r "${WORKDIR}/themes/"*  || die
	fi

	newicon client/gfx/win_icon.png lbreakout2.png
	make_desktop_entry lbreakout2 LBreakout2

	prepgamesdirs
}