[gentoo-commits] repo/gentoo:master commit in: dev-python/pyro/

[Michał Górny]

commit:     4659a0635bbfc1ab33ab4775a707e53e6f8fe54f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 29 08:04:13 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun 29 08:15:36 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4659a063

dev-python/pyro: Bump to 4.76

Closes: https://bugs.gentoo.org/688910
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyro/Manifest         |  1 +
 dev-python/pyro/pyro-4.76.ebuild | 64 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-python/pyro/Manifest b/dev-python/pyro/Manifest
index 099ddcf1b9b..881caafea0c 100644
--- a/dev-python/pyro/Manifest
+++ b/dev-python/pyro/Manifest
@@ -1,3 +1,4 @@
 DIST Pyro-3.16.tar.gz 298769 BLAKE2B 8959e0f647b854fafaf1928601ba60921e9914bd85e2ebbca96a11b701cbfee733e73c1a2c6e5aa65bd45a6a1007a92bc51a78116ac385c5340896b4a684787a SHA512 d0e4ae93120a6566a2b06fa52b66e20daa972324a9d57d639ca68171e1e6e5c412250f7e6af3fc307631d2270be3731ea5898ad35819dc0369e6a2d8341d5965
 DIST Pyro4-4.41.tar.gz 502294 BLAKE2B 0df5e593551d9ea95d01e114cafd746dc0dd55e3157e167ac7337e316b19d2b7811d2ed4c9b3f44a45171bc63aef3d20124a8da8b149037bcbaf38be6562dd95 SHA512 01c3f16448b39cd7a83c845eec86013315ee183a3e50c6caee1d327308e67ff63732833b413b189ebcb77cdb3fc65bbd7417ecbfc8575775ff79550678bce020
 DIST Pyro4-4.56.tar.gz 455253 BLAKE2B 3c63963bc2e248706727324078898c3e2cc9b8b32d228c0f2b87aab776a0e3437f72096031b8658c756988814fd823fa2dc1c8df0b971cfd0174b437f25bd0aa SHA512 88805f5d7108432f98d38267a7a881e35fc1e34ae32cc7a1640f4b6e0d69718a86bf195fb4e4eecbd53075667521585b7006cd5c5736e5ff1ed39b5212b91bef
+DIST Pyro4-4.76.tar.gz 477132 BLAKE2B 49621974ecb485e1809366d9933ccb1027d62bfc827c3f800750095ebe3eb3a662e041a9ff97522ac866b93b22f9c1d5257e1503aaf4b6543d2d74a9a17713ff SHA512 48cc63bc74d483fff1b4bac2dd9ecf7576503bfd91e721512a5cea2b5a115ad6480ad0524218aee31e412a867261a9e838d85650dd0f7a87593a4a03cfc5cdc3

diff --git a/dev-python/pyro/pyro-4.76.ebuild b/dev-python/pyro/pyro-4.76.ebuild
new file mode 100644
index 00000000000..4df5e84f0a4
--- /dev/null
+++ b/dev-python/pyro/pyro-4.76.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="https://pypi.org/project/Pyro4/
+	https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-python/pyro:0
+	$(python_gen_cond_dep \
+		'dev-python/selectors34[${PYTHON_USEDEP}]' -2)
+	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable tests requiring network connection.
+	rm tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}