[gentoo-commits] gentoo-x86 commit in media-sound/rosegarden: ChangeLog rosegarden-1.6.1-r1.ebuild rosegarden-1.6.1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    08/01/06 19:06:59

  Modified:             ChangeLog
  Added:                rosegarden-1.6.1-r1.ebuild
  Removed:              rosegarden-1.6.1.ebuild
  Log:
  Fix handling of user-defined CXXFLAGS, revision bump to force rebuild. Fix bug #204013. I hate cmake.
  (Portage version: 2.1.4_rc14)

Revision  Changes    Path
1.49                 media-sound/rosegarden/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	23 Dec 2007 12:56:26 -0000	1.48
+++ ChangeLog	6 Jan 2008 19:06:58 -0000	1.49
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/rosegarden
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.48 2007/12/23 12:56:26 carlo Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/ChangeLog,v 1.49 2008/01/06 19:06:58 flameeyes Exp $
+
+*rosegarden-1.6.1-r1 (06 Jan 2008)
+
+  06 Jan 2008; Diego Pettenò <flameeyes@g.o>
+  +files/rosegarden-1.6.1-nojack.patch, -rosegarden-1.6.1.ebuild,
+  +rosegarden-1.6.1-r1.ebuild:
+  Fix handling of user-defined CXXFLAGS, revision bump to force rebuild. Fix
+  bug #204013. I hate cmake.
 
 *rosegarden-1.6.1 (23 Dec 2007)
 



1.1                  media-sound/rosegarden/rosegarden-1.6.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/rosegarden-1.6.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/rosegarden/rosegarden-1.6.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: rosegarden-1.6.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rosegarden/rosegarden-1.6.1-r1.ebuild,v 1.1 2008/01/06 19:06:58 flameeyes Exp $

inherit eutils kde-functions cmake-utils

MY_PV="${PV/_rc*/}"
#MY_PV="${MY_PV/4./}"
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="MIDI and audio sequencer and notation editor."
HOMEPAGE="http://www.rosegardenmusic.com/"
SRC_URI="mirror://sourceforge/rosegarden/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa debug jack dssi lirc"

RDEPEND="
	alsa? ( >=media-libs/alsa-lib-1.0
		jack? ( >=media-sound/jack-audio-connection-kit-0.77 )
	)
	>=media-libs/ladspa-sdk-1.0
	>=media-libs/ladspa-cmt-1.14
	dssi? ( >=media-libs/dssi-0.4 )
	lirc? ( >=app-misc/lirc-0.7 )
	>=media-libs/liblrdf-0.3
	>=sci-libs/fftw-3.0.0
	>=media-libs/liblo-0.7"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.15
	>=dev-util/cmake-2.4.2"

need-kde 3.5

pkg_setup() {
	if ! use alsa && use jack; then
		ewarn "If you want JACK support you also need to enable"
		ewarn "ALSA support, or the whole sound support will be"
		ewarn "disabled."
	fi

	if use alsa && ! built_with_use --missing true media-libs/alsa-lib midi; then
		eerror ""
		eerror "To be able to build Rose Garden with ALSA support you need"
		eerror "to have built media-libs/alsa-lib with midi USE flag."
		die "Missing midi USE flag on media-libs/alsa-lib"
	fi
}

src_unpack() {
	unpack ${A}

	cd "${S}"
	epatch "${FILESDIR}/rosegarden-1.6.1-asneeded.patch" \
		"${FILESDIR}/rosegarden-1.6.1.desktop.diff" \
		"${FILESDIR}/${P}-nojack.patch"
}

src_compile() {
	tc-export CC CXX LD

	# cmake is stupid, very very stupid.
	sed -i -e 's:CMAKE_CXX_FLAGS_\(RELEASE\|RELWITHDEBINFO\|DEBUG\).*".*"):CMAKE_CXX_FLAGS_\1 "'"${CXXFLAGS}"'"):' \
		CMakeLists.txt || die "unable to sanitise CXXFLAGS"

	mycmakeargs="$(cmake-utils_use_want alsa SOUND)
		$(cmake-utils_use_want jack JACK)
		$(cmake-utils_use_want dssi DSSI)
		$(cmake-utils_use_want lirc LIRC)"
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS README TRANSLATORS
}



-- 
gentoo-commits@l.g.o mailing list