[gentoo-commits] repo/gentoo:master commit in: sys-fs/squashfs-tools/

[Michał Górny]

commit:     bb2501af4e5ac01b9c2aa23aad1778473ef78faf
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  5 14:15:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Sep  5 17:43:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bb2501af

sys-fs/squashfs-tools: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 sys-fs/squashfs-tools/squashfs-tools-4.5.1.ebuild | 53 -----------------------
 1 file changed, 53 deletions(-)

diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.5.1.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.5.1.ebuild
deleted file mode 100644
index c8e5c9198e74..000000000000
--- a/sys-fs/squashfs-tools/squashfs-tools-4.5.1.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit flag-o-matic toolchain-funcs
-
-DESCRIPTION="tools to create and extract Squashfs filesystems"
-HOMEPAGE="https://github.com/plougher/squashfs-tools/"
-SRC_URI="
-	https://github.com/plougher/squashfs-tools/archive/${PV}.tar.gz
-		-> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="debug lz4 lzma lzo xattr zstd"
-
-RDEPEND="
-	sys-libs/zlib
-	lz4? ( app-arch/lz4 )
-	lzma? ( app-arch/xz-utils )
-	lzo? ( dev-libs/lzo )
-	xattr? ( sys-apps/attr )
-	zstd? ( app-arch/zstd )
-"
-DEPEND=${RDEPEND}
-
-use10() { usex "${1}" 1 0; }
-
-src_configure() {
-	# set up make command line variables in EMAKE_SQUASHFS_CONF
-	EMAKE_SQUASHFS_CONF=(
-		LZMA_XZ_SUPPORT=$(use10 lzma)
-		LZO_SUPPORT=$(use10 lzo)
-		LZ4_SUPPORT=$(use10 lz4)
-		XATTR_SUPPORT=$(use10 xattr)
-		XZ_SUPPORT=$(use10 lzma)
-		ZSTD_SUPPORT=$(use10 zstd)
-	)
-
-	tc-export CC
-	use debug && append-cppflags -DSQUASHFS_TRACE
-}
-
-src_compile() {
-	emake "${EMAKE_SQUASHFS_CONF[@]}" -C squashfs-tools
-}
-
-src_install() {
-	dobin squashfs-tools/{mksquashfs,unsquashfs}
-	dodoc ACKNOWLEDGEMENTS CHANGES README*
-	dodoc -r RELEASE-READMEs
-}