[gentoo-commits] gentoo-x86 commit in net-p2p/gtk-gnutella: gtk-gnutella-0.98.3.ebuild ChangeLog

[Hans de Graaff (graaff)]

graaff      12/06/05 05:56:16

  Modified:             ChangeLog
  Added:                gtk-gnutella-0.98.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.137                net-p2p/gtk-gnutella/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog?rev=1.137&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog?rev=1.137&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog?r1=1.136&r2=1.137

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog,v
retrieving revision 1.136
retrieving revision 1.137
diff -u -r1.136 -r1.137
--- ChangeLog	4 May 2012 06:33:34 -0000	1.136
+++ ChangeLog	5 Jun 2012 05:56:16 -0000	1.137
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/gtk-gnutella
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog,v 1.136 2012/05/04 06:33:34 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/gtk-gnutella/ChangeLog,v 1.137 2012/06/05 05:56:16 graaff Exp $
+
+*gtk-gnutella-0.98.3 (05 Jun 2012)
+
+  05 Jun 2012; Hans de Graaff <graaff@g.o> +gtk-gnutella-0.98.3.ebuild:
+  Version bump.
 
   04 May 2012; Jeff Horelick <jdhore@g.o> gtk-gnutella-0.98.2.ebuild,
   gtk-gnutella-0.98.2-r1.ebuild:



1.1                  net-p2p/gtk-gnutella/gtk-gnutella-0.98.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gtk-gnutella/gtk-gnutella-0.98.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/gtk-gnutella/gtk-gnutella-0.98.3.ebuild?rev=1.1&content-type=text/plain

Index: gtk-gnutella-0.98.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/gtk-gnutella/gtk-gnutella-0.98.3.ebuild,v 1.1 2012/06/05 05:56:16 graaff Exp $

EAPI=4

inherit eutils

IUSE="nls dbus ssl +gtk"

DESCRIPTION="A GTK+ Gnutella client"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
HOMEPAGE="http://gtk-gnutella.sourceforge.net/"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"

RDEPEND="
	dev-libs/glib:2
	sys-libs/zlib
	gtk? ( >=x11-libs/gtk+-2.2.1:2 )
	dbus? ( >=sys-apps/dbus-0.35.2 )
	ssl? ( >=net-libs/gnutls-2.2.5 )
	nls? ( >=sys-devel/gettext-0.11.5 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	strip-linguas -i po

	echo "# Gentoo-selected LINGUAS" > po/LINGUAS
	for ling in ${LINGUAS}; do
		echo $ling >> po/LINGUAS
	done
}

src_configure() {
	# There is no option to turn off optimization through the build.sh
	# script.
	sed -i -e "s/Configure -Oder/Configure -Oder -Doptimize=none/" build.sh || die

	# The build script does not support the equivalent --enable
	# options so we must construct the configuration by hand.

	local myconf

	if ! use nls; then
		myconf="${myconf} --disable-nls"
	fi

	if ! use dbus; then
		myconf="${myconf} --disable-dbus"
	fi

	if ! use ssl; then
		myconf="${myconf} --disable-gnutls"
	fi

	if use gtk; then
		myconf="${myconf} --gtk2"
	else
		myconf="${myconf} --topless"
	fi

	./build.sh \
		--configure-only \
		--prefix="/usr" \
		--cc=$(tc-getCC) \
		${myconf}
}

src_install() {
	dodir /usr/bin
	emake INSTALL_PREFIX="${D}" install || die "Install failed"
	dodoc AUTHORS ChangeLog README TODO

	# Touch the symbols file into the future to avoid warnings from
	# gtk-gnutella later on, since we will most likely strip the binary.
	touch --date="next minute" "${D}/usr/lib/gtk-gnutella/gtk-gnutella.nm" || die
}