[gentoo-commits] gentoo-x86 commit in dev-libs/mpfr: ChangeLog mpfr-2.4.1_p1.ebuild

[Mike Frysinger (vapier)]

vapier      09/03/03 00:26:33

  Modified:             ChangeLog
  Added:                mpfr-2.4.1_p1.ebuild
  Log:
  Add patch from upstream.
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.95                 dev-libs/mpfr/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/mpfr/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/mpfr/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/mpfr/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/mpfr/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	27 Feb 2009 14:46:52 -0000	1.94
+++ ChangeLog	3 Mar 2009 00:26:33 -0000	1.95
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/mpfr
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/mpfr/ChangeLog,v 1.94 2009/02/27 14:46:52 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mpfr/ChangeLog,v 1.95 2009/03/03 00:26:33 vapier Exp $
+
+*mpfr-2.4.1_p1 (03 Mar 2009)
+
+  03 Mar 2009; Mike Frysinger <vapier@g.o> +files/2.4.1/patch01,
+  +mpfr-2.4.1_p1.ebuild:
+  Add patch from upstream.
 
   27 Feb 2009; Brent Baude <ranger@g.o> mpfr-2.3.2.ebuild:
   stable ppc64, bug 255195



1.1                  dev-libs/mpfr/mpfr-2.4.1_p1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/mpfr/mpfr-2.4.1_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/mpfr/mpfr-2.4.1_p1.ebuild?rev=1.1&content-type=text/plain

Index: mpfr-2.4.1_p1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/mpfr/mpfr-2.4.1_p1.ebuild,v 1.1 2009/03/03 00:26:33 vapier Exp $

# NOTE: we cannot depend on autotools here starting with gcc-4.3.x
inherit eutils

MY_PV=${PV/_p*}
MY_P=${PN}-${MY_PV}
PLEVEL=${PV/*p}
DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
HOMEPAGE="http://www.mpfr.org/"
SRC_URI="http://www.mpfr.org/mpfr-current/${MY_P}.tar.lzma"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""

RDEPEND=">=dev-libs/gmp-4.1.4-r2"
DEPEND="${RDEPEND}
	app-arch/lzma-utils"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	[[ -d ${FILESDIR}/${PV} ]] && epatch "${FILESDIR}"/${PV}/*.patch
	[[ ${PLEVEL} == ${PV} ]] && return 0
	for ((i=1; i<=PLEVEL; ++i)) ; do
		patch=patch$(printf '%02d' ${i})
		if [[ -f ${FILESDIR}/${MY_PV}/${patch} ]] ; then
			epatch "${FILESDIR}"/${MY_PV}/${patch}
		elif [[ -f ${DISTDIR}/${PN}-${MY_PV}_p${i} ]] ; then
			epatch "${DISTDIR}"/${PN}-${MY_PV}_p${i}
		else
			ewarn "${DISTDIR}/${PN}-${MY_PV}_p${i}"
			die "patch ${i} missing - please report to bugs.gentoo.org"
		fi
	done
	find . -type f -print0 | xargs -0 touch -r configure
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc AUTHORS BUGS ChangeLog NEWS README TODO
	dohtml *.html
}