[gentoo-commits] gentoo-x86 commit in net-irc/epic5/files: epic5-1.1.2-libarchive-automagic.patch epic5-1.1.2-ruby-automagic-as-needed.patch epic5-1.1.2-tcl-automagic-as-needed.patch epic5-1.1.2-perl-automagic-as-needed.patch

[Nathan Phillip Brink (binki)]

binki       11/06/01 14:45:08

  Added:                epic5-1.1.2-libarchive-automagic.patch
                        epic5-1.1.2-ruby-automagic-as-needed.patch
                        epic5-1.1.2-tcl-automagic-as-needed.patch
                        epic5-1.1.2-perl-automagic-as-needed.patch
  Log:
  Bump to epic5-1.1.2 for bug #258144. Includes patches for a lot of automagic problems and LDFLAGS abuses (which were breaking LDFLAGS=-Wl,--as-needed) and adds new archive and valgrind useflags.
  
  (Portage version: 2.2.0_alpha34-r1/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-irc/epic5/files/epic5-1.1.2-libarchive-automagic.patch

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-libarchive-automagic.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-libarchive-automagic.patch?rev=1.1&content-type=text/plain

Index: epic5-1.1.2-libarchive-automagic.patch
===================================================================
From: Nathan Phillip Brink <binki@g.o>
Subject: Prevent libarchive check from being automagic.

--- a/configure.in
+++ b/configure.in
@@ -231,22 +231,28 @@
 dnl XXX I don't understand why this is even necessary.
-have_libarchive=""
-orig_LIBS="$LIBS"
-AC_CHECK_LIB(archive, archive_read_new, [LIBS="$LIBS -larchive"])
-AC_MSG_CHECKING(whether libarchive works the way I expect)
-AC_TRY_LINK([#include <archive.h>], [
-	struct archive *x; 
-	const char *s = "bogus.zip";
-	x = archive_read_new();
-	archive_read_support_format_all(x);
-	archive_read_open_file(x, s, 10240);
-], have_libarchive="yes")
-if test "x$have_libarchive" = "x"; then
-	LIBS="$orig_LIBS"
-	AC_MSG_RESULT(no)
-else
-	AC_MSG_RESULT(yes)
-	AC_DEFINE(HAVE_LIBARCHIVE)
-fi
+AC_ARG_WITH([libarchive], [AS_HELP_STRING([--without-libarchive], [Disable libarchive support.])],
+	[], [with_libarchive=maybe])
+AS_IF([test "x$with_libarchive" != "xno"],
+	[
+	have_libarchive=""
+	orig_LIBS="$LIBS"
+	AC_CHECK_LIB(archive, archive_read_new, [LIBS="$LIBS -larchive"])
+	AC_MSG_CHECKING(whether libarchive works the way I expect)
+	AC_TRY_LINK([#include <archive.h>], [
+		struct archive *x; 
+		const char *s = "bogus.zip";
+		x = archive_read_new();
+		archive_read_support_format_all(x);
+		archive_read_open_file(x, s, 10240);
+	], have_libarchive="yes")
+	if test "x$have_libarchive" = "x"; then
+		LIBS="$orig_LIBS"
+		AC_MSG_RESULT(no)
+		AS_IF([test "x$with_libarchive" = "xyes"],
+			[AC_MSG_ERROR([--with-libarchive was specified but libarchive could not be found. Please do not specify --with-libarchive or install libarchive.])])
+	else
+		AC_MSG_RESULT(yes)
+		AC_DEFINE(HAVE_LIBARCHIVE)
+	fi])
 
 dnl -----
 AC_ARG_WITH(ssl,




1.1                  net-irc/epic5/files/epic5-1.1.2-ruby-automagic-as-needed.patch

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-ruby-automagic-as-needed.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-ruby-automagic-as-needed.patch?rev=1.1&content-type=text/plain

Index: epic5-1.1.2-ruby-automagic-as-needed.patch
===================================================================
From: Nathan Phillip Brink <binki@g.o>
Subject: Fix up linking against libruby when using
	LDFLAGS=-Wl,--as-needed. Also allow ruby to be a non-automagic
	dependency.

--- a/configure.in
+++ b/configure.in
@@ -1191,34 +1191,32 @@
 dnl
 dnl Ruby support?
 dnl
-AC_ARG_WITH(ruby,
-[  --with-ruby[=PATH_TO_RUBY_EXE]       Compile with ruby support.],
-[ 
-	rubyexe=$withval
-],
-	rubyexe=yes
-)
-
-if test "x$rubyexe" = "xyes"; then
-	rubyexe=ruby
-fi
+AC_ARG_WITH([ruby],
+	[AS_HELP_STRING([--with-ruby[=PATH_TO_RUBY_EXE]], [Compile with ruby support.])],
+	[], [with_ruby=maybe])
 
+with_ruby_errormsg="--with-ruby was specified but I could not locate ruby. Please try specifying --with-ruby=/path/to/ruby or --without-ruby."
+AC_MSG_CHECKING([whether to support Ruby])
+if test "x$with_ruby" = "xno" ; then
-if test "x$rubyexe" = "xno"; then
-	AC_MSG_CHECKING(whether to support Ruby)
 	AC_MSG_RESULT(no)
 else
+	AC_MSG_RESULT(yes)
+	AS_IF([test "x$with_ruby" = "xyes" -o "x$with_ruby" = "xmaybe"],
+		[rubyexe=ruby],
+		[rubyexe="$with_ruby"])
+	dnl Support --with-ruby being passed a full path instead of just an executable name.
+	AS_IF([test -x "$rubyexe"],
+		[RUBYPROG=yes],
+		[AC_CHECK_PROG([RUBYPROG], [$rubyexe], [yes], [no])])
+	if test "x$RUBYPROG" = xno ; then
+		AS_IF([test "x$with_ruby" != "xmaybe"],
+			[AC_MSG_ERROR([$with_ruby_errormsg])])
-	AC_CHECK_PROG(RUBYPROG, $rubyexe, "yes", "no")
-	AC_MSG_CHECKING(whether to support Ruby)
-	if test $RUBYPROG != "yes" ; then 
-	    AC_MSG_RESULT(no)
 	else
-	    AC_MSG_RESULT(yes)
-
 	    incdir=`$rubyexe -rrbconfig -e 'puts Config::CONFIG[["archdir"]]'`
 	    rubylibs=`$rubyexe -rrbconfig -e 'puts Config::CONFIG[["LIBRUBYARG"]]'`
 	    extralibs=`$rubyexe -rrbconfig -e 'puts Config::CONFIG[["LIBS"]]'`
 	    RUBYCFLAGS="-I$incdir"
-	    RUBYLDFLAGS="$rubylibs $extralibs"
+	    RUBYLIBS="$rubylibs $extralibs"
 	    RUBYDOTOH="ruby.o"
 
 	    AC_MSG_CHECKING(whether embedded ruby works the way I expect)
@@ -1226,7 +1220,7 @@
 	    old_CFLAGS="$CFLAGS"
-	    old_LDFLAGS="$LDFLAGS"
+	    old_LIBS="$LIBS"
 	    CFLAGS="$CFLAGS $RUBYCFLAGS"
-	    LDFLAGS="$LDFLAGS $RUBYLDFLAGS"
+	    LIBS="$LDFLAGS $RUBYLIBS"
 	    AC_TRY_LINK([
 #include <ruby.h>
     VALUE epic_echo (VALUE module, VALUE string)
@@ -1251,9 +1245,9 @@
 		AC_MSG_RESULT(no)
 		AC_MSG_CHECKING(whether ruby requires -pthread to link)
 		RUBYCFLAGS="$RUBYCFLAGS -pthread"
-		RUBYLDFLAGS="$RUBYLDFLAGS -pthread"
+		RUBYLIBS="$RUBYLIBS -pthread"
-		CFLAGS="$CFLAGS $RUBYCFLAGS"
-		LDFLAGS="$LDFLAGS $RUBYLDFLAGS"
+		CFLAGS="$old_CFLAGS $RUBYCFLAGS"
+		LIBS="$old_LIBS $RUBYLIBS"
 
 	        AC_TRY_LINK([
 #include <ruby.h>
@@ -1279,16 +1273,18 @@
 
 	    CFLAGS="$old_CFLAGS"
-	    LDFLAGS="$old_LDFLAGS"
+	    LIBS="$old_LIBS"
 	    if test $have_embedded_ruby = "yes" ; then
 		AC_MSG_RESULT(yes)
 		AC_DEFINE(HAVE_RUBY)
 		AC_DEFINE(RUBYCFLAGS)
-		AC_DEFINE(RUBYLDFLAGS)
+		AC_DEFINE(RUBYLIBS)
 	    else
+		AS_IF([test "x$with_ruby" != "xmaybe"],
+			[AC_MSG_ERROR([$with_ruby_errormsg])])
 	        RUBYDOTOH=""
 		HAVE_RUBY=""
 		RUBYCFLAGS=""
-		RUBYLDFLAGS=""
+		RUBYLIBS=""
 		AC_MSG_RESULT(no, sorry)
 	    fi
 	fi
@@ -1386,7 +1380,7 @@
 AC_SUBST(LDFLAGS)
 AC_SUBST(RUBYDOTOH)
 AC_SUBST(RUBYCFLAGS)
-AC_SUBST(RUBYLDFLAGS)
+AC_SUBST(RUBYLIBS)
 AC_SUBST(TCLDOTOH)
 AC_SUBST(TCLCFLAGS)
 AC_SUBST(TCLLDFLAGS)

--- a/source/Makefile.in
+++ b/source/Makefile.in
@@ -38,7 +38,7 @@
 epic5: $(OBJECTS)
 	sh info.c.sh
 	$(CC) $(CFLAGS) $(INCLUDES) -c info.c
-	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLDFLAGS@ @TCLLDFLAGS@ @RUBYLDFLAGS@ $(LIBS)
+	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLDFLAGS@ @TCLLDFLAGS@ @RUBYLIBS@ $(LIBS)
 	$(RM) info.c info.o
 clean::
 	$(RM) epic5 $(OBJECTS)



1.1                  net-irc/epic5/files/epic5-1.1.2-tcl-automagic-as-needed.patch

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-tcl-automagic-as-needed.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-tcl-automagic-as-needed.patch?rev=1.1&content-type=text/plain

Index: epic5-1.1.2-tcl-automagic-as-needed.patch
===================================================================
From: Nathan Phillip Brink <binki@g.o>
Subject: Make dependence on TCL not be automagic (so that --with-tcl
	errors out if TCL can't be found and not specifying --with-tcl
	does the normal automagic behavior).  Support
	LDFLAGS=-Wl,--as-needed by using LIBS instead of LDFLAGS for
	-ltcl as appropriate.

--- a/configure.in
+++ b/configure.in
@@ -1122,43 +1122,41 @@
 dnl
 dnl Tcl support?
 dnl
-AC_ARG_WITH(tcl,
-[  --with-tcl[=PATH_TO_tclConfig.sh]      Compile with tcl support.],
-[
-	tclconfig=$withval
-],
-	tclconfig="yes"
-)
-
-if test "x$tclconfig" = "xyes" ; then
-	for i in /usr/lib /usr/local/lib /usr/local/lib/tcl8.4 ; do
-		if test -r $i/tclConfig.sh ; then
-			tclconfig=$i/tclConfig.sh
-			break;
-		fi
-	done
-fi
+AC_ARG_WITH([tcl], [AS_HELP_STRING([--with-tcl[=PATH_TO_tclConfig.sh]], [Compile with tcl support.])],
+	[], [with_tcl=maybe])
 
 AC_MSG_CHECKING(whether to support TCL)
-if test "x$tclconfig" = "xno"; then
+if test "x$with_tcl" = "xno"; then
 	AC_MSG_RESULT(no)
 else
-	if test ! -r $tclconfig ; then
+	with_tcl_errormsg="You specified --with-tcl=$with_tcl but I could not find TCL. Please specify --with-tcl=/path/to/tclConfig.sh or remove --with-tcl from ./configure's commandline."
+	if test "x$with_tcl" = "xmaybe" -o "x$with_tcl" = "xyes"; then
+		for i in /usr/lib /usr/local/lib /usr/local/lib/tcl8.4 ; do
+			if test -r "$i"/tclConfig.sh ; then
+				tclconfig="$i"/tclConfig.sh
+				break;
+			fi
+		done
+	else
+		tclconfig="$with_tcl"
+	fi
+	if test ! -r "$tclconfig" ; then
+		dnl Avoid being automagic unless if the user wants us to be.
+		AS_IF([test "x$with_tcl" != "xmaybe"],
+			[AC_MSG_ERROR([$with_tcl_errormsg])])
 		AC_MSG_RESULT(no)
 	else
 		AC_MSG_RESULT(yes)
-		TCLCFLAGS=`(. $tclconfig && echo $TCL_INCLUDE_SPEC)`
-		TCLLDFLAGS1=`(. $tclconfig && echo $TCL_LIB_SPEC)`
-		TCLLDFLAGS2=`(. $tclconfig && echo $TCL_LIBS)`
-		TCLLDFLAGS=$(eval echo "$TCLLDFLAGS1 $TCLLDFLAGS2")
+		TCLCFLAGS=`(. "$tclconfig" && echo $TCL_INCLUDE_SPEC)`
+		TCLLIBS=`(. "$tclconfig" && echo $TCL_LIB_SPEC $TCL_LIBS)`
 		TCLDOTOH="tcl.o"
 
 		AC_MSG_CHECKING(whether embedded tcl works the way I expect)
 		have_embedded_tcl="no"
 		old_CFLAGS="$CFLAGS"
-		old_LDFLAGS="$LDFLAGS"
+		old_LIBS="$LIBS"
 		CFLAGS="$CFLAGS $TCLCFLAGS"
-		LDFLAGS="$LDFLAGS $TCLLDFLAGS"
+		LIBS="$LIBS $TCLLIBS"
 		AC_TRY_LINK([
 #include <tcl.h>
 	   Tcl_Interp *my_tcl;
@@ -1175,14 +1173,16 @@
 ], have_embedded_tcl="yes")
 
 		CFLAGS="$old_CFLAGS"
-		LDFLAGS="$old_LDFLAGS"
+		LIBS="$old_LIBS"
 		if test $have_embedded_tcl = "yes" ; then
 		    AC_MSG_RESULT(yes)
 		    AC_DEFINE(HAVE_TCL)
 		    AC_DEFINE(TCLCFLAGS)
-		    AC_DEFINE(TCLLDFLAGS)
+		    AC_DEFINE(TCLLIBS)
 		else
-		    AC_MSG_RESULT(no, sorry)
+			AS_IF([test "$with_tcl" != "xmaybe"],
+				[AC_MSG_ERROR([$with_tcl_errormsg])])
+			AC_MSG_RESULT(no, sorry)
 		fi
 	fi
 fi
@@ -1383,7 +1383,7 @@
 AC_SUBST(RUBYLIBS)
 AC_SUBST(TCLDOTOH)
 AC_SUBST(TCLCFLAGS)
-AC_SUBST(TCLLDFLAGS)
+AC_SUBST(TCLLIBS)
 AC_SUBST(PERLDOTOH)
 AC_SUBST(PERLCFLAGS)
 AC_SUBST(PERLLDFLAGS)

--- a/source/Makefile.in
+++ b/source/Makefile.in
@@ -38,7 +38,7 @@
 epic5: $(OBJECTS)
 	sh info.c.sh
 	$(CC) $(CFLAGS) $(INCLUDES) -c info.c
-	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLDFLAGS@ @TCLLDFLAGS@ @RUBYLIBS@ $(LIBS)
+	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLDFLAGS@ @TCLLIBS@ @RUBYLIBS@ $(LIBS)
 	$(RM) info.c info.o
 clean::
 	$(RM) epic5 $(OBJECTS)



1.1                  net-irc/epic5/files/epic5-1.1.2-perl-automagic-as-needed.patch

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-perl-automagic-as-needed.patch?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/files/epic5-1.1.2-perl-automagic-as-needed.patch?rev=1.1&content-type=text/plain

Index: epic5-1.1.2-perl-automagic-as-needed.patch
===================================================================
From: Nathan Phillip Brink <binki@g.o>
Subject: Fix perl being automagic and to be safe with
	LDFLAGS=-Wl,--as-needed.

--- a/configure.in
+++ b/configure.in
@@ -1033,37 +1033,38 @@
 dnl
 dnl Perl support?
 dnl
-AC_ARG_WITH(perl,
-[  --with-perl[=PATH_TO_PERL_EXE]       Compile with perl support.],
-[ 
-	perlexe=$withval
-],
-	perlexe=yes
-)
-
-if test "x$perlexe" = "xyes"; then
-	perlexe=perl
-fi
-
-if test "x$perlexe" = "xno"; then
+AC_ARG_WITH([perl], [AS_HELP_STRING([--with-perl=[PATH_TO_PERL_EXE]], [Compile with perl support.])],
+	[], [with_perl=maybe])
+AS_IF([test "x$with_perl" = "xno"],
+	[
 	AC_MSG_CHECKING(whether to support Perl)
 	AC_MSG_RESULT(no)
-else
-	AC_CHECK_PROG(PERLPROG, $perlexe, "yes", "no")
-	AC_MSG_CHECKING(whether to support Perl)
-	if test $PERLPROG != "yes" ; then 
+	],
+	[
+	with_perl_errormsg="You specified --with-perl=$with_perl but I could not find a working perl. Please run ./configure with --without-perl or specify a path to a working perl executable."
+	AS_IF([test "x$with_perl" = "xyes" -o "x$with_perl" = "xmaybe"],
+		[perlexe=perl],
+		[perlexe="$with_perl"])
+	dnl Allow a full path to be specified in --with-perl
+	AS_IF([test -x "$perlexe"],
+		[PERLPROG=yes],
+		[AC_CHECK_PROG(PERLPROG, $perlexe, "yes", "no")])
+	AC_MSG_CHECKING([whether to support Perl])
+	if test $PERLPROG != "yes" ; then
+		AS_IF([test "x$with_perl" != "xmaybe"],
+			[AC_MSG_ERROR([$with_perl_errormsg])])
 		AC_MSG_RESULT(no)
 	else
 		AC_MSG_RESULT(yes)
 		PERLCFLAGS=`$perlexe -MExtUtils::Embed -e ccopts`
-		PERLLDFLAGS=`$perlexe -MExtUtils::Embed -e ldopts`
+		PERLLIBS=`$perlexe -MExtUtils::Embed -e ldopts`
 
 		AC_MSG_CHECKING(whether embedded perl works the way I expect)
 		have_embedded_perl="no"
 		old_CFLAGS="$CFLAGS"
-		old_LDFLAGS="$LDFLAGS"
+		old_LIBS="$LIBS"
 		CFLAGS="$CFLAGS $PERLCFLAGS"
-		LDFLAGS="$LDFLAGS $PERLLDFLAGS"
+		LIBS="$LIBS $PERLLIBS"
 		AC_TRY_RUN([
 #include <EXTERN.h>
 #include <perl.h>
@@ -1101,20 +1102,22 @@
 have_embedded_perl="no",:)
 
 		CFLAGS="$old_CFLAGS"
-		LDFLAGS="$old_LDFLAGS"
+		LIBS="$old_LIBS"
 		if test $have_embedded_perl = "yes" ; then
 			AC_MSG_RESULT(yes)
 			AC_DEFINE(HAVE_PERL)
 			AC_DEFINE(PERLCFLAGS)
-			AC_DEFINE(PERLLDFLAGS)
+			AC_DEFINE(PERLLIBS)
 			PERLDOTOH="perl.o"
 		else
+			AS_IF([test "x$with_perl" != "xmaybe"],
+				[AC_MSG_ERROR([$with_perl_errormsg])])
 			PERLCFLAGS=""
-			PERLLDFLAGS=""
+			PERLLIBS=""
 			AC_MSG_RESULT(no, sorry)
 			PERLCFLAGS=""
-			PERLLDFLAGS=""
+			PERLLIBS=""
 		fi
 	fi
-fi
+	])
 
@@ -1392,7 +1395,7 @@
 AC_SUBST(TCLLIBS)
 AC_SUBST(PERLDOTOH)
 AC_SUBST(PERLCFLAGS)
-AC_SUBST(PERLLDFLAGS)
+AC_SUBST(PERLLIBS)
 AC_SUBST(WSERV_BIN)
 AC_SUBST(WSERV_INSTALL)
 AC_SUBST(bindir)

--- a/source/Makefile.in
+++ b/source/Makefile.in
@@ -38,7 +38,7 @@
 epic5: $(OBJECTS)
 	sh info.c.sh
 	$(CC) $(CFLAGS) $(INCLUDES) -c info.c
-	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLDFLAGS@ @TCLLIBS@ @RUBYLIBS@ $(LIBS)
+	$(CC) $(CFLAGS) $(LDFLAGS) -o epic5 $(OBJECTS) info.o @PERLLIBS@ @TCLLIBS@ @RUBYLIBS@ $(LIBS)
 	$(RM) info.c info.o
 clean::
 	$(RM) epic5 $(OBJECTS)