[gentoo-commits] gentoo-x86 commit in app-portage/gentoolkit: gentoolkit-0.2.4.6-r1.ebuild ChangeLog

[Paul Varner (fuzzyray)]

fuzzyray    10/03/01 19:58:05

  Modified:             ChangeLog
  Added:                gentoolkit-0.2.4.6-r1.ebuild
  Log:
  Revision bump to add patch to fully fix Bug 143498
  (Portage version: 2.2_rc63/cvs/Linux i686)

Revision  Changes    Path
1.180                app-portage/gentoolkit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.180&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.180&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/ChangeLog?r1=1.179&r2=1.180

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v
retrieving revision 1.179
retrieving revision 1.180
diff -u -r1.179 -r1.180
--- ChangeLog	18 Feb 2010 19:58:12 -0000	1.179
+++ ChangeLog	1 Mar 2010 19:58:04 -0000	1.180
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/gentoolkit
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.179 2010/02/18 19:58:12 fuzzyray Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.180 2010/03/01 19:58:04 fuzzyray Exp $
+
+*gentoolkit-0.2.4.6-r1 (01 Mar 2010)
+
+  01 Mar 2010; Paul Varner <fuzzyray@g.o>
+  +gentoolkit-0.2.4.6-r1.ebuild, +files/revdep-rebuild.143498.patch:
+  Revision bump to add patch to fully fix Bug 143498
 
 *gentoolkit-0.3.0_rc9 (18 Feb 2010)
 *gentoolkit-0.2.4.6 (18 Feb 2010)



1.1                  app-portage/gentoolkit/gentoolkit-0.2.4.6-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: gentoolkit-0.2.4.6-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.6-r1.ebuild,v 1.1 2010/03/01 19:58:04 fuzzyray Exp $

EAPI=2

inherit eutils python

DESCRIPTION="Collection of administration scripts for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~fuzzyray/distfiles/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE=""

# Drop ~m68k ~s390 ~sh ~sparc-fbsd ~x86-fbsd due to app-misc/realpath dependency
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"

DEPEND="sys-apps/portage
	dev-lang/python[xml]
	dev-lang/perl
	sys-apps/grep"
RDEPEND="${DEPEND}
	 app-misc/realpath"
RESTRICT="test"

src_prepare() {
	epatch "${FILESDIR}/revdep-rebuild.143498.patch"
}

src_install() {
	emake DESTDIR="${D}" install-gentoolkit || die "install-gentoolkit failed"

	# Create cache directory for revdep-rebuild
	dodir /var/cache/revdep-rebuild
	keepdir /var/cache/revdep-rebuild
	fowners root:root /var/cache/revdep-rebuild
	fperms 0700 /var/cache/revdep-rebuild
}

pkg_postinst() {
	# Make sure that our ownership and permissions stuck
	chown root:root "${ROOT}/var/cache/revdep-rebuild"
	chmod 0700 "${ROOT}/var/cache/revdep-rebuild"

	python_mod_optimize /usr/lib/gentoolkit

	einfo
	elog "The default location for revdep-rebuild files has been moved"
	elog "to /var/cache/revdep-rebuild when run as root."
	einfo
	einfo "Another alternative to equery is app-portage/portage-utils"
	einfo
	einfo "For further information on gentoolkit, please read the gentoolkit"
	einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
	einfo
}

pkg_postrm() {
	python_mod_cleanup /usr/lib/gentoolkit
}