[gentoo-commits] gentoo-x86 commit in dev-libs/gjs: gjs-1.40.1-r1.ebuild ChangeLog gjs-1.36.1.ebuild

[Pacho Ramos (pacho)]

pacho       14/09/26 10:39:22

  Modified:             ChangeLog
  Added:                gjs-1.40.1-r1.ebuild
  Removed:              gjs-1.36.1.ebuild
  Log:
  Apply some upstream fixes that also prevent gjs crashes, bug #523608 by Serge Gavrilov
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.52                 dev-libs/gjs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/gjs/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	15 Sep 2014 08:18:18 -0000	1.51
+++ ChangeLog	26 Sep 2014 10:39:22 -0000	1.52
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/gjs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/ChangeLog,v 1.51 2014/09/15 08:18:18 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/ChangeLog,v 1.52 2014/09/26 10:39:22 pacho Exp $
+
+*gjs-1.40.1-r1 (26 Sep 2014)
+
+  26 Sep 2014; Pacho Ramos <pacho@g.o>
+  +files/gjs-1.40.1-ownership-transfer.patch,
+  +files/gjs-1.40.1-ratelimit-rss.patch, +gjs-1.40.1-r1.ebuild,
+  -gjs-1.36.1.ebuild:
+  Apply some upstream fixes that also prevent gjs crashes, bug #523608 by Serge
+  Gavrilov
 
   15 Sep 2014; Agostino Sarubbo <ago@g.o> gjs-1.40.1.ebuild:
   Stable for sparc, wrt bug #512012



1.1                  dev-libs/gjs/gjs-1.40.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/gjs-1.40.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/gjs/gjs-1.40.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: gjs-1.40.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/gjs-1.40.1-r1.ebuild,v 1.1 2014/09/26 10:39:22 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit eutils gnome2 pax-utils virtualx

DESCRIPTION="Javascript bindings for GNOME"
HOMEPAGE="https://wiki.gnome.org/Projects/Gjs"

LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
SLOT="0"
IUSE="+cairo examples gtk test"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

RDEPEND="
	>=dev-libs/glib-2.36:2
	>=dev-libs/gobject-introspection-1.39.3

	sys-libs/readline:0
	dev-lang/spidermonkey:24
	virtual/libffi
	cairo? ( x11-libs/cairo )
	gtk? ( x11-libs/gtk+:3 )
"
DEPEND="${RDEPEND}
	gnome-base/gnome-common
	sys-devel/gettext
	virtual/pkgconfig
	test? ( sys-apps/dbus )
"

# Large amount of tests are broken even in master.
RESTRICT="test"

src_prepare() {
	# Prevent gjs crashes, bug #523608 (from 'master')
	epatch "${FILESDIR}/${PN}-1.40.1-ownership-transfer.patch"

	# Ratelimit RSS-triggered GCs (from 'master')
	epatch "${FILESDIR}/${PN}-1.40.1-ratelimit-rss.patch"

	gnome2_src_prepare
}

src_configure() {
	# FIXME: add systemtap/dtrace support, like in glib:2
	# FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
	# XXX: Do NOT enable coverage, completely useless for portage installs
	gnome2_src_configure \
		--disable-systemtap \
		--disable-dtrace \
		--disable-coverage \
		$(use_with cairo cairo) \
		$(use_with gtk)
}

src_test() {
	Xemake check
}

src_install() {
	# installation sometimes fails in parallel
	gnome2_src_install -j1

	if use examples; then
		insinto /usr/share/doc/"${PF}"/examples
		doins "${S}"/examples/*
	fi

	# Required for gjs-console to run correctly on PaX systems
	pax-mark mr "${ED}/usr/bin/gjs-console"
}