[gentoo-commits] gentoo-x86 commit in sys-cluster/open-mx: open-mx-1.5.2.ebuild ChangeLog open-mx-1.5.0.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      12/04/29 12:39:55

  Modified:             ChangeLog
  Added:                open-mx-1.5.2.ebuild
  Removed:              open-mx-1.5.0.ebuild
  Log:
  [sys-cluster/open-mx] Version bump, also fix bug #387809
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sys-cluster/open-mx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	25 Feb 2012 06:29:00 -0000	1.3
+++ ChangeLog	29 Apr 2012 12:39:54 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/open-mx
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/ChangeLog,v 1.3 2012/02/25 06:29:00 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/ChangeLog,v 1.4 2012/04/29 12:39:54 alexxy Exp $
+
+*open-mx-1.5.2 (29 Apr 2012)
+
+  29 Apr 2012; Alexey Shvetsov <alexxy@g.o> +open-mx-1.5.2.ebuild,
+  -open-mx-1.5.0.ebuild:
+  [sys-cluster/open-mx] Version bump, also fix bug #387809
 
   25 Feb 2012; Robin H. Johnson <robbat2@g.o> open-mx-1.5.0.ebuild:
   Bug #405687: Depend on virtual/modutils instead of sys-apps/module-init-tools.



1.1                  sys-cluster/open-mx/open-mx-1.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.2.ebuild?rev=1.1&content-type=text/plain

Index: open-mx-1.5.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/open-mx/open-mx-1.5.2.ebuild,v 1.1 2012/04/29 12:39:54 alexxy Exp $

EAPI=4

inherit autotools linux-mod multilib

DESCRIPTION="Open-MX - Myrinet Express over Generic Ethernet Hardware"
HOMEPAGE="http://open-mx.gforge.inria.fr/"
SRC_URI="http://gforge.inria.fr/frs/download.php/30245/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug modules static-libs"

DEPEND="
		sys-apps/hwloc
		virtual/linux-sources"
RDEPEND="
		sys-apps/hwloc
		virtual/modutils"

MODULE_NAMES="open-mx(misc:${S}/driver/linux)"
BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"

pkg_setup() {
	einfo "You can set desired mtu by setting OPEN_MX_MTU in make.conf"
	linux-mod_pkg_setup
}

src_prepare() {
	# We still want to configure driver but dont want to build it at all
	epatch "${FILESDIR}/open-mx-1.4.0-driver.patch"
	# We dont want tests
	sed -e 's:tests/mx::g' \
		-e 's:tests::g' \
		-i Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	econf \
		--with-mtu=${OPEN_MX_MTU:-9000} \
		--with-linux="${KERNEL_DIR}" \
		--with-linux-release=${KV_FULL} \
		$(use_enable static-libs static) \
		$(use_enable debug)
}

src_compile() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_compile || die "failed to build driver"
	fi
}

src_install() {
	default
	use static-libs || find "${ED}" -name '*.*a' -exec rm {} +
	# Drop init scripts
	rm -rf "${ED}/usr/sbin" || die
	rm "${ED}/usr/bin/omx_check"
	# install udev rules
	insinto /etc/udev/rules.d
	doins "${ED}/etc/open-mx/10-open-mx.rules"
	dodoc "${ED}/usr/share/open-mx/FAQ.html"
	# Drop misc stuff
	rm "${ED}/etc/open-mx/10-open-mx.rules" || die
	rm -rf "${ED}/usr/share/open-mx" || die
	newinitd "${FILESDIR}/omxoed.initd" omxoed
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_install || die "failed to install driver"
	fi
}