[gentoo-commits] repo/gentoo:master commit in: sci-libs/indilib/, sci-libs/indilib/files/

[Andreas Sturmlechner]

commit:     31f57fcf95df722dbe0263d5e41863cd3ad48d3b
Author:     Alexey Sokolov <sokolov <AT> google <DOT> com>
AuthorDate: Mon Jul  5 16:00:39 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jul 14 13:43:39 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31f57fcf

sci-libs/indilib: fix include

Closes: https://bugs.gentoo.org/800614
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Alexey Sokolov <alexey+gentoo <AT> asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/21538
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../indilib/files/indilib-1.9.1-fix-include.patch  | 26 +++++++++
 sci-libs/indilib/indilib-1.9.1-r1.ebuild           | 61 ++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/sci-libs/indilib/files/indilib-1.9.1-fix-include.patch b/sci-libs/indilib/files/indilib-1.9.1-fix-include.patch
new file mode 100644
index 00000000000..7e3e24880d4
--- /dev/null
+++ b/sci-libs/indilib/files/indilib-1.9.1-fix-include.patch
@@ -0,0 +1,26 @@
+From 907b3d81f27593e709af9e3f2cdc6dab05d6d80a Mon Sep 17 00:00:00 2001
+From: Paolo Stivanin <paolostivanin@××××××××××××××××××××.com>
+Date: Tue, 29 Jun 2021 08:52:04 +0200
+Subject: [PATCH] Fix indimacros include path on baseclient.h (#1503)
+
+---
+ libs/indibase/baseclient.h | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/libs/indibase/baseclient.h b/libs/indibase/baseclient.h
+index 6d5e49b9a..2656d7486 100644
+--- a/libs/indibase/baseclient.h
++++ b/libs/indibase/baseclient.h
+@@ -20,11 +20,11 @@
+ 
+ #include "indiapi.h"
+ #include "indibase.h"
++#include "indimacros.h"
+ 
+ #include <string>
+ #include <vector>
+ 
+-#include <indimacros.h>
+ #include <memory>
+ 
+ // #define MAXRBUF 2048 // #PS: defined in indibase.h

diff --git a/sci-libs/indilib/indilib-1.9.1-r1.ebuild b/sci-libs/indilib/indilib-1.9.1-r1.ebuild
new file mode 100644
index 00000000000..eb8784d3454
--- /dev/null
+++ b/sci-libs/indilib/indilib-1.9.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libusb:0
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+PATCHES=(
+	"${FILESDIR}"/indilib-1.9.1-fix-include.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+}