[gentoo-commits] gentoo-x86 commit in dev-python/lxml: lxml-2.3.6.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/09/29 21:49:29

  Modified:             ChangeLog
  Added:                lxml-2.3.6.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha133/cvs/Linux x86_64)

Revision  Changes    Path
1.134                dev-python/lxml/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.134&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.134&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/lxml/ChangeLog?r1=1.133&r2=1.134

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v
retrieving revision 1.133
retrieving revision 1.134
diff -u -r1.133 -r1.134
--- ChangeLog	21 Aug 2012 07:50:52 -0000	1.133
+++ ChangeLog	29 Sep 2012 21:49:29 -0000	1.134
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/lxml
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.133 2012/08/21 07:50:52 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.134 2012/09/29 21:49:29 radhermit Exp $
+
+*lxml-2.3.6 (29 Sep 2012)
+
+  29 Sep 2012; Tim Harder <radhermit@g.o> +lxml-2.3.6.ebuild:
+  Version bump.
 
 *lxml-2.3.5 (21 Aug 2012)
 



1.1                  dev-python/lxml/lxml-2.3.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/lxml/lxml-2.3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/lxml/lxml-2.3.6.ebuild?rev=1.1&content-type=text/plain

Index: lxml-2.3.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/lxml-2.3.6.ebuild,v 1.1 2012/09/29 21:49:29 radhermit Exp $

EAPI="4"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="*-jython 2.7-pypy-*"

inherit distutils

MY_P="${PN}-${PV/_/}"

DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
HOMEPAGE="http://codespeak.net/lxml/ http://pypi.python.org/pypi/lxml"
SRC_URI="http://codespeak.net/lxml/${MY_P}.tgz"
# SRC_URI="http://codespeak.net/lxml/dev/${MY_P}.tgz"

LICENSE="BSD ElementTree GPL-2 PSF-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc examples +threads"

RDEPEND=">=dev-libs/libxml2-2.7.2
	>=dev-libs/libxslt-1.1.15
	>=dev-python/beautifulsoup-3.0.8"
DEPEND="${RDEPEND}
	dev-python/setuptools"
# lxml tarball contains files pregenerated by Cython.

S="${WORKDIR}/${MY_P}"

PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")

# Compiler warnings are suppressed without --warnings option.
DISTUTILS_GLOBAL_OPTIONS=("*-cpython --warnings")

src_compile() {
	distutils_src_compile $(use threads || echo --without-threading)
}

src_test() {
	testing() {
		# Tests broken with Python 3.
		[[ "${PYTHON_ABI}" == 3.* ]] && return

		local module
		for module in lxml/etree lxml/objectify; do
			ln -fs "../../$(ls -d build-${PYTHON_ABI}/lib.*)/${module}.so" "src/${module}.so" || die "ln -fs src/${module} failed"
		done

		local exit_status="0" test
		for test in test.py selftest.py selftest2.py; do
			einfo "Running ${test}"
			if ! PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" "${test}"; then
				eerror "${test} failed with $(python_get_implementation) $(python_get_version)"
				exit_status="1"
			fi
		done

		return "${exit_status}"
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r doc/html/*
		dodoc *.txt
		docinto doc
		dodoc doc/*.txt
	fi

	if use examples; then
		docinto examples
		dodoc -r samples/*
		docompress -x /usr/share/doc/${PF}/examples
	fi
}