[gentoo-commits] gentoo-x86 commit in net-p2p/ktorrent: ktorrent-4.3.1-r1.ebuild ChangeLog

[Michael Palimaka (kensington)]

kensington    14/01/29 13:06:11

  Modified:             ChangeLog
  Added:                ktorrent-4.3.1-r1.ebuild
  Log:
  Backport patch from upstream fixing issue with IP filter lists, wrt bug #499602.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.200                net-p2p/ktorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/ktorrent/ChangeLog?rev=1.200&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/ktorrent/ChangeLog?rev=1.200&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/ktorrent/ChangeLog?r1=1.199&r2=1.200

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v
retrieving revision 1.199
retrieving revision 1.200
diff -u -r1.199 -r1.200
--- ChangeLog	10 May 2013 09:33:28 -0000	1.199
+++ ChangeLog	29 Jan 2014 13:06:11 -0000	1.200
@@ -1,6 +1,13 @@
 # ChangeLog for net-p2p/ktorrent
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v 1.199 2013/05/10 09:33:28 abcd Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v 1.200 2014/01/29 13:06:11 kensington Exp $
+
+*ktorrent-4.3.1-r1 (29 Jan 2014)
+
+  29 Jan 2014; Michael Palimaka <kensington@g.o>
+  +files/ktorrent-4.3.1-ipfilter.patch, +ktorrent-4.3.1-r1.ebuild:
+  Backport patch from upstream fixing issue with IP filter lists, wrt bug
+  #499602.
 
   10 May 2013; Jonathan Callen <abcd@g.o> ktorrent-4.3.1.ebuild:
   Remove unused kde-base/solid dependency



1.1                  net-p2p/ktorrent/ktorrent-4.3.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/ktorrent/ktorrent-4.3.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/ktorrent/ktorrent-4.3.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: ktorrent-4.3.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ktorrent-4.3.1-r1.ebuild,v 1.1 2014/01/29 13:06:10 kensington Exp $

EAPI=5

KDE_SCM="git"
LIBKT_VERSION_MIN="${PV}"
LIBKT_VERSION_MAX="99999999"
if [[ ${PV} != 9999* ]]; then
	inherit versionator
	# upstream likes to skip that _ in beta releases
	MY_PV="${PV/_/}"
	LIBKT_VERSION_MIN=$(($(get_major_version)-3)).$(get_version_component_range 2-3 ${PV})
	LIBKT_VERSION_MAX=$(($(get_major_version)-3)).$(($(get_version_component_range 2)+1))
	MY_P="${PN}-${MY_PV}"
	KDE_HANDBOOK="optional"
	KDE_DOC_DIRS="doc"

	KDE_LINGUAS="ar ast be bg bs ca ca@valencia cs da de el en_GB eo es et eu
		fi fr ga gl hi hne hr hu is it ja km ku lt lv mai ms nb nds nl nn oc
		pl pt pt_BR ro ru se si sk sl sq sr sr@ijekavian sr@ijekavianlatin
		sr@latin sv tr ug uk zh_CN zh_TW"
	SRC_URI="http://ktorrent.org/downloads/${MY_PV}/${MY_P}.tar.bz2"
	S="${WORKDIR}"/"${MY_P}"

	KEYWORDS="~amd64 ~ppc ~x86"
else
	LIBKT_VERSION_MIN="${PV}"
	LIBKT_VERSION_MAX="99999999"
	KEYWORDS=""
fi

inherit kde4-base

DESCRIPTION="A BitTorrent program for KDE."
HOMEPAGE="http://ktorrent.org/"

LICENSE="GPL-2"
SLOT="4"
IUSE="+bwscheduler debug +downloadorder +infowidget +ipfilter +kross +logviewer
+magnetgenerator +mediaplayer plasma rss +scanfolder +search +shutdown +stats
+upnp webinterface +zeroconf"

COMMONDEPEND="
	<net-libs/libktorrent-${LIBKT_VERSION_MAX}
	>=net-libs/libktorrent-${LIBKT_VERSION_MIN}
	infowidget? ( dev-libs/geoip )
	mediaplayer? ( >=media-libs/taglib-1.5 )
	plasma? ( $(add_kdebase_dep libtaskmanager) )
	rss? ( $(add_kdebase_dep kdepimlibs) )
	shutdown? ( $(add_kdebase_dep libkworkspace) )
"
DEPEND="${COMMONDEPEND}
	dev-libs/boost
	sys-devel/gettext
"
RDEPEND="${COMMONDEPEND}
	ipfilter? (
		app-arch/bzip2
		app-arch/unzip
		$(add_kdebase_dep kdebase-kioslaves)
	)
	kross? ( $(add_kdebase_dep krosspython) )
"

PATCHES=(
	"${FILESDIR}/${P}-ipfilter.patch"
	"${FILESDIR}/${P}-underlinking.patch"
)

src_prepare() {
	if ! use plasma; then
		sed -i \
			-e "s:add_subdirectory(plasma):#nada:g" \
			CMakeLists.txt || die "Failed to make plasmoid optional"
	fi

	kde4-base_src_prepare
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use_enable bwscheduler BWSCHEDULER_PLUGIN)
		$(cmake-utils_use_enable downloadorder DOWNLOADORDER_PLUGIN)
		$(cmake-utils_use_enable infowidget INFOWIDGET_PLUGIN)
		$(cmake-utils_use_with infowidget SYSTEM_GEOIP)
		$(cmake-utils_use_enable ipfilter IPFILTER_PLUGIN)
		$(cmake-utils_use_enable kross SCRIPTING_PLUGIN)
		$(cmake-utils_use_enable logviewer LOGVIEWER_PLUGIN)
		$(cmake-utils_use_enable magnetgenerator MAGNETGENERATOR_PLUGIN)
		$(cmake-utils_use_enable mediaplayer MEDIAPLAYER_PLUGIN)
		$(cmake-utils_use_enable rss SYNDICATION_PLUGIN)
		$(cmake-utils_use_enable scanfolder SCANFOLDER_PLUGIN)
		$(cmake-utils_use_enable search SEARCH_PLUGIN)
		$(cmake-utils_use_enable shutdown SHUTDOWN_PLUGIN)
		$(cmake-utils_use_enable stats STATS_PLUGIN)
		$(cmake-utils_use_enable upnp UPNP_PLUGIN)
		$(cmake-utils_use_enable webinterface WEBINTERFACE_PLUGIN)
		$(cmake-utils_use_enable zeroconf ZEROCONF_PLUGIN)
	)
	kde4-base_src_configure
}