[gentoo-commits] repo/gentoo:master commit in: kde-apps/kipi-plugins/

[Andreas Sturmlechner]

commit:     e696de800b107a93b11fd6f34b91667a7c110a3d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 16 19:15:45 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jul 17 08:23:48 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e696de80

kde-apps/kipi-plugins: Drop IUSE=flashexport, fix HOMEPAGE

Upstream commit 955fc31c6f60c50403e3d5a4bee3f21dee4ce93f

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kipi-plugins/kipi-plugins-21.04.3-r1.ebuild    | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/kde-apps/kipi-plugins/kipi-plugins-21.04.3-r1.ebuild b/kde-apps/kipi-plugins/kipi-plugins-21.04.3-r1.ebuild
new file mode 100644
index 00000000000..1d4039b5fde
--- /dev/null
+++ b/kde-apps/kipi-plugins/kipi-plugins-21.04.3-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Plugins for the KDE Image Plugin Interface"
+HOMEPAGE="https://apps.kde.org/kipi_plugins/ https://userbase.kde.org/KIPI"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="mediawiki +remotestorage"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-apps/libkipi-${PVCUT}:5=
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	mediawiki? ( net-libs/libmediawiki:5 )
+	remotestorage? ( >=kde-frameworks/kio-${KFMIN}:5 )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5Vkontakte=ON
+		$(cmake_use_find_package mediawiki KF5MediaWiki)
+		$(cmake_use_find_package remotestorage KF5KIO)
+	)
+	ecm_src_configure
+}